Discussion :

[Stardust31]

Bonjour,
J'ai un tableau de plus de 200000 lignes ….
Dans la colonne C, j'ai des chaines alphanumériques, de différentes longueurs.
Le but est de supprimer la chaine de caractères "-A" quand elle est présente uniquement en fin de chaine.

Exemple :

FR-658497
EZ-8710236-C
RFZ-874591
RFE-A748954125-A
RT-5874932174-A
AZ-789451-B


Seuls les "-A" indiqués en rouge ici doivent être supprimés.

Merci par avance de l'aide

Bonne journée

[BENNASR]

Bonsoir
sans VBA et avec la fonction droite "=DROITE(A2;2)" et puis un filtre sur le -A et tu supprime

[Stardust31]

j'ai peut-être oublié de le dire
désolé
besoin du code en VBA
merci

[BENNASR]

Désolé ma réponse est fausse
Mais encore sans VBA et avec avec Ctrl + H et tu cherche -A et tu remplace par vide

[Menhir]

Compare le résultat de InStrRev à la longueur de la chaine et tu sauras sur ta suite est en fin de chaine.
https://msdn.microsoft.com/en-us/VBA...trrev-function

Si c'est le cas, il ne te restes plus qu'à la supprimer en utilisant un Left de longueur Len() - 2.

[Stardust31]

Merci BENNASR... mais non.

'-------------------

Merci Menhir

voici mon code (pas du tout optimisé à la vue de mes occurrences sur les 200000 lignes , car j'ai aussi à supprimer des "-B", "-C".... )

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
 
Sub SupCarac()
 
' supprime les 2 derniers caracteres "-A" de chaines decaractères de différentes longueurs
 
Dim Strg As String
Dim I, x, y, pos As Integer
Dim maDerLigne As Integer
 
 
    maDerLigne = 0
    maDerLigne = Range("A" & Rows.Count).End(xlUp).Row  'donne le n° de la dernière ligne
 
    For I = 2 To maDerLigne   ' balaie le tableau de la ligne 2 à la dernière ligne
        Strg = Cells(I, 3).Value
        x = InStrRev(Strg, "-A")    ' recherche la chaine de caractère "-A"
        y = Len(Strg)
        pos = y - x
        If pos = 1 Then
            Strg = Left(Strg, Len(Strg) - 2)   '  supprime les 2 derniers caractères
            Cells(I, 3).Value = Strg   'remplace la valeur de la cellule
        End If
    Next I
End Sub

voilà, c'est fini

encore merci

[patricktoulon]

re

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
for........
if cells(x,y).text like "*-A" then ' remarque l'etoile devant mais pas en fin ce qui indique que l'on cherche que les like a la fin 
next

et pour les A B ou C si je me trompe pas c'est "*-[A|B|C]" avec ou sans les "|" je sais plus

[Marc-L]

Bonjour !

A partir de la fonctionnalité de recherche d'Excel et telle qu'expliquée dans l'aide VBA interne de Range.Find
donc d'un niveau débutant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub Demo1()
           Dim Rg As Range
        Application.ScreenUpdating = False
    With Cells(1).CurrentRegion.Columns(3)
           Set Rg = .Find("*-A", , xlValues, xlWhole)
        If Not Rg Is Nothing Then
            Do
                 Rg.Value = Left(Rg.Value, Len(Rg.Value) - 2)
                   Set Rg = .FindNext(Rg)
            Loop Until Rg Is Nothing
        End If
    End With
        Application.ScreenUpdating = True
End Sub

Une autre voie :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub Demo2()
    Dim V, R&
        V = Cells(1).CurrentRegion.Columns(3).Value
        Application.ScreenUpdating = False
    For R = 1 To UBound(V)
        If V(R, 1) Like "*-A" Then Cells(R, 3).Value = Left(V(R, 1), Len(V(R, 1)) - 2)
    Next
        Application.ScreenUpdating = True
End Sub

___________________________________________________________________________________________________________

     Merci de cliquer sur en bas à droite de chaque message ayant aidé puis sur pour clore cette discussion …

___________________________________________________________________________________________________________

Je suis Paris, Egypte, Nigeria, New-York, Mogadicio, Barcelone, London, Manchester, Stockholm, Istanbul, Berlin, Nice, Bruxelles, Charlie, …

[Marc-L]

j'ai aussi à supprimer des "-B", "-C"...

Via la fonction de feuille de calculs EQUIV (Match en VBA) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub Demo3()
    Dim S$(), V, R&
        S = Split("-A -B -C")
        V = Cells(1).CurrentRegion.Columns(3).Value
        Application.ScreenUpdating = False
    For R = 1 To UBound(V)
        If IsNumeric(Application.Match(Right(V(R, 1), 2), S, 0)) Then Cells(R, 3).Value = Left(V(R, 1), Len(V(R, 1)) - 2)
    Next
        Application.ScreenUpdating = True
End Sub

___________________________________________________________________________________________________________

     Merci de cliquer sur en bas à droite de chaque message ayant aidé puis sur pour clore cette discussion …

[Pierre Fauconnier]

Salut.

Tu peux t'inspirer de ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Sub Test()
  Dim Cell As Range
 
  For Each Cell In Range("a1:a5")
    Cell.Value = IIf(Cell.Value Like "*-[A-C]", Left(Cell.Value, Len(Cell.Value) - 2), Cell.Value)
  Next
End Sub

[patricktoulon]

re
salut MarcL Ok allons y pour les raccourcis

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Sub test()
    With ActiveSheet.Range("$A$1:$A$6")
        .AutoFilter Field:=1, Criteria1:="=*-A"
        r = .Cells.Replace(what:="-A", Replacement:="")
    .AutoFilter
    End With
End Sub

[Marc-L]

Salut Pierre !

Oui c'est plus léger, j'aurais dû consulter l'aide de Like pour me rafraîchir les neurones !  


Salut Patrick !

Dommage !   Tu remplaces aussi le -A au milieu de la cellule se terminant par -A de son exemple …

[Stardust31]

wouah !!! tout ça !
mes neurones fument !!
je vais analyser tout cela

merci à tous

[patricktoulon]

a bon
chez moi ce qui l'on au milieu ne partent pas d'ailleurs si je ne me trompe pas le criterial indique bien que c'est que pour la fin avec l'etoile manquante a la fin non?

edit: a OK autant pour moi ,il y a les deux possibilités dans une meme cellule
il doit bien y avoir un moyen de changer le replace textuel par un replace contextuel

[Marc-L]

Le mieux pour plusieurs critères c'est via Like ou encore For Each + Find …

Stardust31, compares déjà sur tes 200 000 lignes mes deux premières démos pour voir si une est plus rapide que l'autre …

[patricktoulon]

n'ayant pas trouvé si c'est possible et si oui la formule d'un replace contextuel

je me suis rabattu sur un replace left -len(x)-2 apres les filtres A B ou C

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub test2()
    Dim BadFin, i,cel as range 
    BadFin = Array("-A", "-B", "-C")
    With ActiveSheet.Range("A1:A10")
        For i = 0 To UBound(BadFin)
            .AutoFilter Field:=1, Criteria1:="=*" & BadFin(i)
            For Each cel In .SpecialCells(xlVisible).Cells
                cel.Value = Left(cel.Text, Len(cel.Text) - 2)
            Next
            .AutoFilter
        Next
    End With
End Sub

je sais pas si c'est plus rapide faut verifier sur une plage importante en terme de lignes

[Marc-L]

SpecialCells étant une méthode des plus vicieuses car limitée en taille, donc à éviter avec une grande plage de données …

[Pierre Fauconnier]

Salut Pierre !

Oui c'est plus léger[...]

Salut Marc,

Bah, j'ai fait des regex aujourd'hui, alors ça a tilté... Cela dit, ma première solution n'est pas correcte pour les cellules qui contiendraient le pattern au milieu de la chaîne...

J'adapte ci-dessous ma réponse pour ne travailler qu'avec les fins de chaîne...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub Test()
  Dim cell As Range
  Dim regEx As Object
 
  Set regEx = CreateObject("VBscript.RegExp")
  regEx.Pattern = "(-[A-C])$"
  For Each cell In Range("a1:a3")
    cell.Value = regEx.Replace(cell.Value, "")
  Next cell
End Sub

[unparia]

Bonjour à tous et mille excuses à chacun (je suis fatigué et vais au plus court avant d'aller à un dodo indispensable)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
toto = "RFE-A748954125-A"
 toto = StrReverse(toto)
 If Left(toto, 2) = "A-" Then toto = Mid(toto, 3)
 MsgBox StrReverse(toto)

Pardonnez-moi

EDIT suis-je bête ! La fatigue n'excuse pas tout...
Un déclic en me couchant -->> ultra-simple --->>

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
toto = "RFE-A748954125-A"
 MsgBox Left(toto, Len(toto) - 3) & Replace(toto, "-A", "", Len(toto) - 2)

encore pardon...

[Stardust31]

Bonjour à tous,
j'ai pris cette solution
merci à Pierre
merci à tous

Salut Marc,

Bah, j'ai fait des regex aujourd'hui, alors ça a tilté... Cela dit, ma première solution n'est pas correcte pour les cellules qui contiendraient le pattern au milieu de la chaîne...

J'adapte ci-dessous ma réponse pour ne travailler qu'avec les fins de chaîne...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub Test()
  Dim cell As Range
  Dim regEx As Object
 
  Set regEx = CreateObject("VBscript.RegExp")
  regEx.Pattern = "(-[A-C])$"
  For Each cell In Range("a1:a3")
    cell.Value = regEx.Replace(cell.Value, "")
  Next cell
End Sub