Message d'erreur incompréhensible dans un USERFORM

**leblesois** · 05/12/2018, 19h00

Bonjour le Forum,

je vous explique mon problème. Je viens de créer un "super fichier" de suivi avec des tas de formulaires, ...

Dans un de ses formulaires, j'ai une listbox, qui se charge sans problème. J'ai également créé, entre autres, un combobox qui permet de filtrer la Listbox sur une de ses colonnes (="Catégorie").

Si je sélectionne une catégorie, tout fonctionne bien, le filtrage se fait parfaitement, sauf pour UNE des catégories !!!! (dans mon cas "Mobilier").
En effet, lorsque je sélectionne cette catégorie (et uniquement celle-ci, d'ou ma surprise), j'obtiens le message suivant :

Erreur d'exécution '-2147352571 (80020005)' : Impossible de définir la propriété List. Le type ne correspond pas.

En faisant 'jouer' le code via F8 ... F8, j'arrive à déterminer que le problème vient au niveau du code suivant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
For Each c In Application.index(Workbooks(ThisWorkbook.Name).Sheets("articles").[DONNEES_ARTICLES], , 1)
        If c.Offset(, 5) = Me.Cbb_Catégorie Then
            Me.ListBox_Articles.AddItem
            Me.ListBox_Articles.List(I, 0) = c.Value
            For N = 1 To NbCol
                Me.ListBox_Articles.List(I, N - 1) = c.Offset(, N - 1).Value
            Next N
            I = I + 1
        End If
    Next c

de la ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Me.ListBox_Articles.List(I, N - 1) = c.Offset(, N - 1).Value

et cela au moment où la valeur de la cellule sur lequel on travaille possède 3205 caractères.

Ma question est donc la suivante, pourquoi à l'initialisation du formulaire la taille de la cellule ne pose pas de problème pour la listbox, alors qu'avec le code ci-dessus SI ?

Deuxième question : excel limite le nombre de caractères à combien dans une "cellule" d'une listbox ?

Dernière question : comment résoudre mon problème ?

Afin d'illustrer mon problème, je vous ai mis en PJ le formulaire (réduit au mimimum pour vous le transmettre) posant problème avec son code (lui aussi réduit au minimum).

Merci d'avance pour votre aide

**unparia** · 05/12/2018, 19h25

Bonjour
la règle est ici une seule question/difficulté par discussion. Aucune limitation en ce qui concerne le nombre d'articles que peut contenir une listbox. Il en va différemment en ce qui concerne le nombre de ceux pouvant être exploités : il est limité à celui d'un integer. (32000 et des poussières); ceci étant dit --->> une liste de plus de 1000 articles est en général "imbuvable".
Je n'ai pas ouvert ton classeur (je n'ouvre et n'ouvrirai jamais un classeur tiers)
Une listbox ne peut être alimentée que par du texte. Une erreur est inévitable si tu cherches à y inscrire le contenu inexploitable (cellule en erreur) d'une cellule

**leblesois** · 05/12/2018, 19h43

Merci de répondre si rapidement, mais malheureusement, je ne comprends pas votre réponse. En effet, ma listbox n'est alimentée que par du texte étant donné qu'elle va chercher le contenu d'une cellule qui n'est absolument pas en erreur...

Donc mon problème persiste ... SNIFF !

**Patrice740** · 05/12/2018, 20h42

Bonjour,

Il n'y a aucun intérêt à disposer d'une entrée de Listbox avec 3205 caractères !
Une Listbox ne doit pas être un substitut de feuille de calcul.

**leblesois** · 05/12/2018, 20h46

Aucun intérêt pour vous !
Mais quand il s'agit de récupérer un descriptif qui se trouve dans une cellule, je ne vois pas comment faire autrement pour faire apparaitre dans un formulaire le contenu de cette cellule ...

Ce genre de réflexion ne fait pas avancer la discussion...

**unparia** · 05/12/2018, 20h54

Bien.
Cette réponse à Patrice me convainc que je n'ai aucun intérêt à rester dans cette discussion.
Salut.

**Patrice740** · 05/12/2018, 20h58

Envoyé par leblesois

Aucun intérêt pour vous !
Mais quand il s'agit de récupérer un descriptif qui se trouve dans une cellule, je ne vois pas comment faire autrement pour faire apparaitre dans un formulaire le contenu de cette cellule ...

Ce genre de réflexion ne fait pas avancer la discussion...

Pour récupérer le contenu d'une cellule, un label suffit !
Et s'il s'agit de pouvoir modifier le texte, c'est un Textbox qui est le plus adapté.

**leblesois** · 05/12/2018, 21h03

Après plusieurs tests, il ressort que ce problème apparait dès qu'il y a au moins 2048 caractères dans une cellule... Les listbox alimentées par une boucle du type

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
For N = 1 To NbCol
Me.ListBox_Articles.List(I, N - 1) = c.Offset(, N - 1).Value
Next N

sont donc concernés par cela... mais pas celles alimentées par ce code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
 
For LIG = LBound(clé) To UBound(clé)
        For COL = LBound(BDD_ORIGINE, 2) To UBound(BDD_ORIGINE, 2)
            b(LIG, COL) = BDD_ORIGINE(index(LIG), COL)
        Next COL
Next LIG
    Me.ListBox_Articles.List = b

Bizarre, Bizarre....

Si vous avez une explication, je suis preneur ! MERCI !

**Patrice740** · 05/12/2018, 21h17

De quel type les variables sont-elles déclarées ?

**leblesois** · 05/12/2018, 21h44

Envoyé par Patrice740

Pour récupérer le contenu d'une cellule, un label suffit !
Et s'il s'agit de pouvoir modifier le texte, c'est un Textbox qui est le plus adapté.

C'est effectivement ce que je fais. En cliquant dans Listbox (dont certaines colonnes sont à zéro en largeur pour ne pas les afficher), le texte correspondant au descriptif (3205 car.) apparait dans le TextBox (cf. fichier excel joint plus haut, merci)

Envoyé par Patrice740

De quel type les variables sont-elles déclarées ?

Pour les colonnes, Integer

Pour les Lignes et autres variables numériques Long

(Merci pour ton aide !)

Envoyé par unparia

Bien.
Cette réponse à Patrice me convainc que je n'ai aucun intérêt à rester dans cette discussion.
Salut.

Ma réponse n'était pas du tout agressive, la preuve, lui, il essaye encore de m'aider... Je ne faisais que dire que sa réponse ne faisait pas avancer le schmilblick...

**unparia** · 05/12/2018, 22h01

Tu crois ? (pas moi)
Bon -->> je vais alors mettre un peu (pas trop) d'eau dans mon vin et te répondre ainsi :
Il n'est pas du tout indispensable que la textbox en question (celle pour afficher) corresponde à une donnée figurant dans la listbox.
Il suffit, au click sur une ligne de la listbox, d'afficher dans la textbox le contenu de la cellule correspondante. La propriété listindex te permet de définir la propriété R row de la feuille -->> tu donnes à la textbox la valeur de la cellule, qui, sur cette ligne, contient ton texte à afficher.

Je te laisse là.

**Patrice740** · 05/12/2018, 22h20

Envoyé par leblesois

Pour les colonnes, Integer

Pour les Lignes et autres variables numériques Long

(Merci pour ton aide !)

Quelques conseils :
- commencer tous les modules par Option Explicit, ce qui oblige à déclarer toutes les variables ;
- déclarer toutes les variables avec le type ad hoc ;
- limiter leur portée au strict nécessaire (i.e. locale, privée, publique ou globale) ;
- ne jamais utiliser .Select, éviter les objets actifs : Selection, Activecell, Activesheet, ... ;
- envisager tous les types potentiels de chaque variable pour éviter les erreurs, dans le doute prévoir un gestionnaire d"erreur ;
- éviter d'utiliser des propriétés ou méthodes d'objet qui pourraient ne pas exister (Ex: au lieu de Sheets(1).Range("A1") écrire Workheets(1).Range("A1") ;
- éviter les références implicites (i.e. partielles), privilégier les références explicites (ex: au lieu de =Cells(1,2) écrire =Worksheets(1).Cells(1,2).Value) ;
- éviter d'utiliser le Presse-Papier, préférer la copie directe (une seule instruction) : Source.Copy Destination ou Destination.valeur = Source.Valeur

**leblesois** · 06/12/2018, 14h13

Merci à vous deux, avec tout cela, je vais pouvoir régler mon problème.

Bonne continuation !

**MarcelG** · 06/12/2018, 14h45

Bonjour,

Patrice,

Pour ton dernier post, pouce vers le haut!

Juste

commencer tous les modules par Option Explicit, ce qui oblige à déclarer toutes les variables

Je conseillerais même de rendre cette option obligatoire via le menu Options de l'Editeur VBE.

**patricktoulon** · 09/12/2018, 11h21

re
ca aurait été tellement plus simple d'ajouter une colonne dans la listbox voir la cacher et y metre les index de ligne
pour le long descriptif se servir de cet index avec la lettre de colonne pour recupérer le value de cells(index,colonne)
pas de soucis de longeur de texte puisque on ne le stocke pas dans la listbox
tellement plus simple

**patricktoulon** · 09/12/2018, 12h33

re
a faire un sheets "variable" pour créer des liste pour tes controls assure toi que l'orthographe soit identique en colonne "F" du sheets "Articles" ca risque pas de fonctionner sinon (corrigé)

j'ai tout viré
je n'ai garder que la combobox et son label, la listbox, la frame et son textbox

ton code userform bye bye!! et je l'ai remplacé par celui la

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
Option Explicit
Private Sub Cbb_Catégorie_Change()
    Dim ro&, cel As Range
    ListBox_Articles.Clear
    Txt_Detail = ""
    With Cbb_Catégorie
        For Each cel In Sheets("Articles").Range("F2", Cells(Rows.Count, "F").End(xlUp)).Cells
            If cel.Value = .Value Then
                ro = cel.Row
                With ListBox_Articles
                    .AddItem cel.Row
                    .List(.ListCount - 1, 1) = Format(Sheets("Articles").Cells(ro, "B"), "dd/mm/yyyy")
                    .List(.ListCount - 1, 2) = Sheets("Articles").Cells(ro, "C")
                    .List(.ListCount - 1, 3) = Sheets("Articles").Cells(ro, "E")
                    .List(.ListCount - 1, 4) = Sheets("Articles").Cells(ro, "F")
                End With
            End If
        Next
    End With
End Sub
'
Private Sub ListBox_Articles_Change()
    Dim ligne
    With ListBox_Articles
        If .ListCount > 0 Then
            ligne = .List(.ListIndex, 0)
            Txt_Detail = Sheets("Articles").Cells(ligne, "D")
        End If
    End With
End Sub
'
Private Sub UserForm_Initialize()
     Dim I&, J&, strTemp$
    Me.Cbb_Catégorie.List = Workbooks(ThisWorkbook.Name).Sheets("Variables").[L_Catégorie_Article].Value
    '     'Tri le contenu du ComboBox par ordre alphabétique
    With Me.Cbb_Catégorie
        For I = 0 To .ListCount - 1
            For J = 0 To .ListCount - 1
                If .List(I) < .List(J) Then
                    strTemp = .List(I)
                    .List(I) = .List(J)
                    .List(J) = strTemp
                End If
            Next J
        Next I
    End With
    ' les Withs des colonnes de la listbox_articles
    With ListBox_Articles
        .ColumnCount = 5
        .ColumnWidths = "15;70;200;100;150"
    'remplacer 15 par 0 si on veut pas voir la colonne 0 qui contient les indexs de lignes du sheets pour les items
    End With
End Sub

je ne suis pas allé plus loin MAIS!!! je pourrais dire que l'on pourrait supprimer le tri alpha de la combo sanchant que tu a un sheets variable qui contient la(les)liste et que ces listes pourraient tres bien etre trier dans le sheets je dis ca moi .....
ce qui donnerait un code d'une 20 aines de ligne dans ton userform
pas de soucis de longueur de texte
pas de soucis pour retrouver la description detaillée
pas de code mastock
et certainement plus rapide j'ai aucun doute la dessus

voila comment on fait

je te redonne ton fichier modifié
medite sur l'option de tri
bon weekend

Message d'erreur incompréhensible dans un USERFORM [XL-2016]

Macros et VBA Excel

Partager

Partager