Remplir combobox,condition et autre combo

**Gioge** · 25/06/2019, 09h45

Salut,

J'ai reussi à remplir une liste d'un combobox1 ( la liste se trouver sur une plage de cellule, donc facile )

Mais maintenant je veux remplir un combobox2 mais selon le choix que je fais dans mon premier combobox1 ( la valeur selectrionné par l'utilisateur dans la liste deroulante )
Le combobox2 doit se remplir toujours avec une plage de cellule, mais cette fois sous condition, je m'explique :

Je dois parcour un ensemble de colonne, et je dois dire si la valeur selectionné dans combobox1 est égale à la valeur qu'on parcour dans UNE colonne, alors : on prend la valeur de la colonne d'a coté sur la même ligne et on l'ajoute dans la liste du combobox1
voici mon code( avec les nom changé ) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
 
Private Sub comboboxListePrincipale_Change()
        combobox2_rchg.Clear
        combobox3.Clear
        combobox4.Clear
 
        Dim i As Long
        Dim j As Long
        Dim DernLigne As Long
 
    DernLigne = wksfd.Range("C1048576").End(xlUp).Row
    MsgBox DernLigne
    For i = 4 To DernLigne
 
            If wksfd.Cells(i, 8).Value = comboboxListePrincipale.Value Then
                If wksfd.Cells(i, 4).Value <> "" Then
                    combobox2_rchg.AddItem wksfd.Cells(i, 4).Value
                ElseIf wksfd.Cells(i, 5).Value <> "" And wksfd.Cells(i, 6).Value <> "" Then
                    combobox3.AddItem wksfd.Cells(i, 5).Value
                    combobox4.AddItem wksfd.Cells(i, 6).Value
 
                End If
 
            End If
 
            Next i
 
End Sub

Merci beaucoup !

PS : toutes les combobox sont rempli avec des nombres !

**MarcelG** · 25/06/2019, 10h36

Bonjour Gioge,

Pour l'alimentation des items, mieux vaut utiliser la méthode AddItem que la propriété RowSource.

La problématique que tu soulèves est classique.
Elle a pour nom "Combobox en cascades."

Une recherche rapide te donnera plusieurs solutions dont
cette discussion

**patricktoulon** · 25/06/2019, 10h57

bonjour a tous

perso j'ai un soucis avec cette logique moi

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
If wksfd.Cells(i, 8).Value = comboboxListePrincipale.Value Then
                If wksfd.Cells(i, 4).Value <> "" Then
                    combobox2_rchg.AddItem wksfd.Cells(i, 4).Value
                ElseIf wksfd.Cells(i, 5).Value <> "" And wksfd.Cells(i, 6).Value <> "" Then
                    combobox3.AddItem wksfd.Cells(i, 5).Value
                    combobox4.AddItem wksfd.Cells(i, 6).Value
 
                End If
 
            End If

j'opterais pour un, select case

non pas qu'elle fonctionne pas mais chez moi un test if elseif se fait sur la même chose

pourquoi?
et bien si ta cell(i,4)<>"" et que la (i,5) et (i,6) sont aussi<>"" que devrait on faire selon ton souhait?

est ce que ton test if elseif représente bien ce que tu veux faire??

**Gioge** · 25/06/2019, 13h24

Envoyé par patricktoulon

Salut, théoriquement dans ma base de données, soit la cells(i,4) est remplie par un nombre, soit elle est vide et alors c'est les 2 autres qui sont remplis ( qui sont un couple de 2 nombres ),
et vice versa, si cells(i,5) et (i,6) sont vides, alors la cells(i,4) est remplie.

Avoir seulement (i,5) rempli, ou avoir (i,4) et (i,6) rempli est une erreur de saisie dans la base de données
Que me proposes-tu en select case ? Tu penses que ça devrait remplir mes 3 combo qui dépendent du combo principal ?

Merci

Envoyé par MarcelG

Justement j'utilise bien AddItem, et pas de rowsource comme tu peux le voir sur mon code

Merci du lien, je vais regarder, et voir si je comprends

**Gioge** · 25/06/2019, 16h53

Rebonjour,

Je n'arrive pas à comprendre l'autre topic...
J'ai crée un fichier par contre pour vous montrez ce que je cherche à faire :
combo partir combov2.xlsm

Merci

**mercatog** · 25/06/2019, 17h21

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
Option Explicit
 
Dim DernLigne As Long
 
Private Sub UserForm_Initialize()
Dim Itm As String
Dim i As Long
 
With Feuil1
    DernLigne = .Cells(.Rows.Count, 2).End(xlUp).Row
    For i = 3 To DernLigne
        Itm = .Cells(i, 2).Value
        With Me.ComboBoxPrinci
            .Value = Itm
            If .ListIndex = -1 Then .AddItem Itm
        End With
    Next i
End With
End Sub
 
Private Sub ComboBoxPrinci_Change()
Dim i As Long
 
Me.ComboBox2.Clear
Me.ComboBox3.Clear
Me.ComboBox4.Clear
With Feuil1
    For i = 3 To DernLigne
        If .Cells(i, 2).Text = Me.ComboBoxPrinci.Value Then
            If .Cells(i, 4).Value <> "" Then
                Me.ComboBox2.AddItem .Cells(i, 4).Value
            ElseIf .Cells(i, 5).Value <> "" And .Cells(i, 6).Value <> "" Then
                Me.ComboBox3.AddItem .Cells(i, 5).Value
                Me.ComboBox4.AddItem .Cells(i, 6).Value
            End If
        End If
    Next i
End With
End Sub

**MarcelG** · 25/06/2019, 17h44

Hé salut à toi ô grand parmi les grands!

Juste un détail.
A mon avis, mieux vaut énoncer un bloc Select Case (éventuellement à True) plutôt que d'imbriquer des blocs If.
Depuis 10 ans, pour ma part, je n'ai jamais utilisé l'instruction ElseIf.

A plus.

**Gioge** · 26/06/2019, 11h43

Envoyé par mercatog

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
Option Explicit
 
Dim DernLigne As Long
 
Private Sub UserForm_Initialize()
Dim Itm As String
Dim i As Long
 
With Feuil1
    DernLigne = .Cells(.Rows.Count, 2).End(xlUp).Row
    For i = 3 To DernLigne
        Itm = .Cells(i, 2).Value
        With Me.ComboBoxPrinci
            .Value = Itm
            If .ListIndex = -1 Then .AddItem Itm
        End With
    Next i
End With
End Sub
 
Private Sub ComboBoxPrinci_Change()
Dim i As Long
 
Me.ComboBox2.Clear
Me.ComboBox3.Clear
Me.ComboBox4.Clear
With Feuil1
    For i = 3 To DernLigne
        If .Cells(i, 2).Text = Me.ComboBoxPrinci.Value Then
            If .Cells(i, 4).Value <> "" Then
                Me.ComboBox2.AddItem .Cells(i, 4).Value
            ElseIf .Cells(i, 5).Value <> "" And .Cells(i, 6).Value <> "" Then
                Me.ComboBox3.AddItem .Cells(i, 5).Value
                Me.ComboBox4.AddItem .Cells(i, 6).Value
            End If
        End If
    Next i
End With
End Sub

Merci beaucoup après adaptation et légère modification ça fonctionne

Par contre, mes combo2, 3 et 4 ont des doublons.
Sur les colonnes de ma feuille j'ai effectivement des doublons, car pour une même valeur de comboprinci, je peux avoir plusieurs valeur différente de combo2 ou du couple (combo3 et 4), ou alors pour des valeurs differente de comboprinci, je peux avoir les mêmes valeurs de combo2 ou du couple (combo3/4).

Par contre lorsque je dois choisir, dans mon Userform, je ne dois pas avoir de doublons ( donc aucune liste des combobox )

Merci

**MarcelG** · 26/06/2019, 12h32

Bonjour,

En adoptant la même architecture que celle du code de mercatog, il est possible de créer des dictionnaires afin d'obtenir des items de Combobox sans doublon.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
Private Sub ComboBoxPrinci_Change()
 
Dim i As Long
 
Me.ComboBox2.Clear
Me.ComboBox3.Clear
Me.ComboBox4.Clear
 
Dim dico2 As Scripting.Dictionary
Set dico2 = CreateObject("Scripting.Dictionary")
 
Dim dico3 As Scripting.Dictionary
Set dico3 = CreateObject("Scripting.Dictionary")
 
Dim dico4 As Scripting.Dictionary
Set dico4 = CreateObject("Scripting.dictionary")
 
With Feuil1
 
    For i = 3 To DernLigne
 
        If .Cells(i, 2).Text = Me.ComboBoxPrinci.Value Then
 
            Select Case True
 
                    Case .Cells(i, 4).Value <> ""
                            If Not dico2.Exists(.Cells(i, 4).Value) Then
                                    dico2.Add .Cells(i, 4).Value, .Cells(i, 4).Value
                                    Me.ComboBox2.AddItem .Cells(i, 4).Value
                            End If
 
                    Case .Cells(i, 5).Value <> "" And .Cells(i, 6).Value <> ""
                            If Not dico3.Exists(.Cells(i, 5).Value) Then
                                    dico3.Add .Cells(i, 5).Value, .Cells(i, 5).Value
                                    Me.ComboBox3.AddItem .Cells(i, 5).Value
                            End If
                            If Not dico4.Exists(.Cells(i, 6).Value) Then
                                    dico4.Add .Cells(i, 6).Value, .Cells(i, 6).Value
                                    Me.ComboBox4.AddItem .Cells(i, 6).Value
                            End If
 
            End Select
 
 
        End If
 
    Next i
 
End With
 
dico4.RemoveAll
Set dico4 = Nothing
 
dico3.RemoveAll
Set dico3 = Nothing
 
dico2.RemoveAll
Set dico2 = Nothing
 
End Sub

Remplir combobox,condition et autre combo

Macros et VBA Excel

Vue hybride

Discussions similaires

Partager

Partager