Discussion :

[JohannCOU]

Bonjour à tous,

Je me permets de vous solliciter car j’ai un problème que je n’arrive pas à résoudre. Dans un fichier Excel qui gère une multitude de données dans un tableau structuré, j’ai réalisé une petite macro qui gère l’affichage des colonnes en passant par une Userform contenant des checkboxes. Jusque-là, tout fonctionne. Dans la Userform, j’ai créé des frames par catégorie de données afin de structurer visuellement la userform en fonction des besoins des utilisateurs. Afin d’éviter aux utilisateurs de coché ou décoché toutes les checkboxes d'une catégorie (Frame), j’ai ajouté une checkbox dans chaque frame pour gérer les checkboxes de la catégorie en question. Et j’aimerais que la valeur de la checkbox qui gère la catégorie se mette à jour en fonction de la valeur des autres checkboxes (Si elles sont toutes cochées, elle se coche. S'il y en a une qui est décochée, elle se décoche).

J’ai créé un fichier très simplifié pour exposé mon problème.
Dans la userform, il y’a 3 frames (qui ont la même fonction mais c’est pour l’exemple) qui résume le cheminement de ma réflexion.
Dans le frame « Problème 1 », la checkbox qui est ajoutée pour gérer les autres fonctionne mais ne se met pas à jour.
Dans le frame « Problème 2 », elle se met à jour mais ne gère pas les autres.
Dans le frame « Problème 3 », qui est la conclusion des deux autres frames, ne fonctionne pas et en plus je ne comprends pas leurs réactions. Mon code me parait pourtant logique mais quelque chose m’échappe.

Gestion données simplifiée.xlsm

Si quelqu’un à une solution ou des explications, je suis preneur !
Je vous remercie par avance.
Johann.

[Nagel Tha]

Bonjour,

Il faut que tu utilises les évènements des checkboxes de ton UserForm à mon avis. J'ai fait quelque chose de similaire récemment. Le clic sur la checkbox ou son changement de valeur doit déclencher la vérification de l'état de toutes les checkboxes dans une boucle contenant un test conditionnel.

Essaye ça en l'adaptant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Dim i As Integer
i = 0
For Each Ctrl In Controls
If Not Ctrl.Value Then 
  Me.CheckBoxToutCoche.Enabled = False
  Exit For
End If
i = i + 1
Next Ctrl
If i = Me.Controls.Count Then Me.CheckBoxToutCoche.Enabled = True

[galopin01]

Bonjour,

J'ai un peu l'impression que tu essaies de savoir qui fait l'oeuf ou la poule...

Tu veux des CheckBox qui se cochent en fonction des colonnes visibles : pas de problème. Mais si après tu essaies de gérer les colonnes d'après les CheckBox tu ne peux pas le faire avec un CheckBox "collectif" car si le collectif est coché, à la moindre tentative de décocher une colonne, ça va décocher le collectif donc toutes les colonnes...
C'est un peu le même problème que si on utilise un "Plan" : Le fait de masquer ou démasquer un élément du plan n'agit pas sur la synthèse annuelle. et le fait de réduire ou pas une année ne peut développer tout ou partie des trimestres...

[EDIT] Bonjour Nagel... Juste pour suivre le sujet.

A+

[patricktoulon]

re
bonsoir

Tu veux des CheckBox qui se cochent en fonction des colonnes visibles : pas de problème. Mais si après tu essaies de gérer les colonnes d'après les CheckBox tu ne peux pas le faire avec un CheckBox "collectif" car si le collectif est coché, à la moindre tentative de décocher une colonne, ça va décocher le collectif donc toutes les colonnes...

faite moi plaisir observez le comportement des evenement surtout nagel tha tiens!!il comprends pourquoi
observez l'evenement mouse up l'effet( l'oeuf ou la poule/le serpent qui se mort la queue) pourrait bien ne pas avoir lieu

[patricktoulon]

je vais meme etre plus precis en fait il y a un evenement qui le gere encore mieux cet effet
c'est l'effet beforeupdate

testez ca dans un userform et apres refaite le meme test mais avec l'evenement click c'est marrant non ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Private Sub CheckBox1_BeforeUpdate(ByVal Cancel As MSForms.ReturnBoolean)
Allcheck
End Sub
'
Private Sub CheckBox2_BeforeUpdate(ByVal Cancel As MSForms.ReturnBoolean)
Allcheck
End Sub
'
Private Sub CheckBox3_BeforeUpdate(ByVal Cancel As MSForms.ReturnBoolean)
Allcheck
End Sub
'
Private Sub CheckBox4_BeforeUpdate(ByVal Cancel As MSForms.ReturnBoolean)
For i = 1 To 3
Me.Controls("CheckBox" & i).Value = CheckBox4.Value
Next
End Sub
'
Private Sub Allcheck()
For i = 1 To 3
If Me.Controls("CheckBox" & i).Value = True Then X = X + 1
Next
If X >= 3 Then CheckBox4.Value = True Else CheckBox4.Value = False
End Sub

maintenant prenez le meme code mais avec les evenement click pour les 4 checkbox il va rester plus que la tete du serpent

je connais un certain Nagel tha qui va etre tres...tres content

[Nagel Tha]

Dans l'évènement BeforeUpdate, l'évènement est déclenché avant que la valeur de l'objet ne change réellement de valeur donc au moment de l'exécution du code la valeur contenue dans le contrôle n'a pas été mise à jour. Dès que j'ai le temps, j'ai vais tester à fond tous les évènements.
Cela dit pour tirer les meilleur des contrôles, il faut utiliser les modules de classe si j'ai bien compris ? (je n'ai pas encore touché à ces bêtes-là)

[patricktoulon]

re
teste avant de tirer des conclusion

Cela dit pour tirer les meilleur des contrôles, il faut utiliser les modules de classe si j'ai bien compris ? (je n'ai pas encore touché à ces bêtes-là)

rien a voir les classe controls sont faite pour gerer les evenements de X meme controls en un seul evenement

[Nagel Tha]

re
teste avant de tirer des conclusion

Je conçois le truc comme ça pour ne pas créer de conflit entre les évènements. Sinon oui je testerai

Edit : J'avais pas vu ta vidéo. Effectivement c'est marrant. C'est sympa cette fonction vidéo. Merci pour la démo

re
teste avant de tirer des conclusion

rien a voir les classe controls sont faite pour gerer les evenements de X meme controls en un seul evenement

C'est bien ce à quoi je pensais ! Et cela justement serait utile quand on a de nombreux contrôles identiques il me semble

[patricktoulon]

pour t'eclaire sur l'evenement click pour les checkbox
le meme modele mais avec les evenement click
tu va comprendre la grosse coquille qu'il y a dans cet evenement

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Private Sub CheckBox1_Click()
Debug.Print "evenement CheckBox1 et le vrai checkbox qui a été cliqué c'est le :" & ActiveControl.Name
If ActiveControl.Name = "CheckBox2" Then Allcheck
End Sub
Private Sub CheckBox2_Click()
Debug.Print "evenement CheckBox2 et le vrai checkbox qui a été cliqué c'est le :" & ActiveControl.Name
If ActiveControl.Name = "CheckBox2" Then Allcheck
End Sub
Private Sub CheckBox3_Click()
Debug.Print "evenement CheckBox3 et le vrai checkbox qui a été cliqué c'est le :" & ActiveControl.Name
If ActiveControl.Name = "CheckBox3" Then Allcheck
End Sub
Private Sub CheckBox4_Click()
Debug.Print "evenement CheckBox4 et le vrai checkbox qui a été cliqué c'est le :" & ActiveControl.Name
If ActiveControl.Name = "CheckBox4" Then
For i = 1 To 3
Me.Controls("CheckBox" & i).Value = CheckBox4.Value
Next
End If
End Sub
Private Sub Allcheck()
For i = 1 To 3
If Me.Controls("CheckBox" & i).Value = True Then X = X + 1
Next
If X >= 3 Then CheckBox4.Value = True Else CheckBox4.Value = False
End Sub

tu constera que avec le 4 tu declanche le click du 1,2,3
POURTANT!!!!!!! quand tu regarde dans le debug on se rend bien compte que meme dans les evenement déclanchés a tords le activecontrol est bien le bon
c'est pas formidable ca
pour palier a cette petite coquille je met une condition dans chaque checkbox sur le activecontrol.name
voila comme ca tu a le modele avec l'evenement clik

pour demo voila ce que j'obtiens quand je clique sur le 4

demonstration

maintenant tu sais quoi faire pour le tien Nagel tha
@gallopin "de la poule et l'oeuf ....." alors maintenant ???

le probleme residait tout simplement au fait que changer la valeur du checkbox declanchait son evenement click si ca c'est pas une coquille je suis ......
je te fait un petit model avec une classe si tu veux Nagel tha

[Nagel Tha]

Merci beaucoup ! s'il y avait un super pouce je te le mettrais

Pour le modèle je dis pas non si tu as le temps ^^

Sinon jusque là je n'ai pas de problème de collision d'évènement : par défaut je désactive tous les contrôles et je les désactive dès qu'ils ne sont plus utilisés et j'utilise des booléens en parallèle pour activer ou désactiver le code de l'évènement. Par contre, ce que j'ai du mal à gérer est le SetFocus qui semble ne pas fonctionner dans certains cas (dans mon UserForm chargé de moult contrôles, il ne fonctionne pas mais j'ai pu constater qu'il fonctionnait dans un UserForm test avec trois contrôles...)

[patricktoulon]

ok je t'en fait un
Attention avec setfocus sur des controls qui ont comme parent un Frame aie!! aie!! la belle coquille que l'ont appele en JS l'event propagation
qui conste a declancher l'evenement du parent avant son propre evenement

non déactiver/reactiver avec booleen c'est pas une bonne idéee ca doit bien bouffer en gourmandise ca
en faisant comme ca tu declanche les evenement sur des controls qui son disabled (enabled=false)je sais que dans ce cas la l'erreur n'est pas relevée
pourtant declancher un evenement d'un control déactivé en est une !!!! a moins de mettre des if et suib if partout qu'elle horreur
un vrai calvere alors que mon modele avec les click fonctionne tres bien

[patricktoulon]

re
voila un exemple avec la gestion des checkboxs dans un module classe

dans un userform 3 frames comme dans le tiens
dans chaques frame 4 checkboxs
dans le nom du 4 eme checkbox de chaques frames il faut qu'il y est le mot "general"

alors voila le code dans le userform

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Dim cl As New Classecheckbox
Private Sub UserForm_Activate()
    cl.initiate Me
End Sub

et le module classe s'appelle "Classecheckbox"
le code dans ce module classe

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
 
Option Explicit
Public WithEvents check As MSForms.CheckBox
Dim cls() As New Classecheckbox
Public Function initiate(usf)
    Dim Ctrl As Object, fra As Object, a&
    For Each fra In usf.Controls
        If TypeName(fra) = "Frame" Then
            For Each Ctrl In fra.Controls
                'Debug.Print ctrl.Name
                a = a + 1: ReDim Preserve cls(1 To a): Set cls(a).check = Ctrl:
            Next
        End If
    Next
End Function
Private Sub check_Click()
    Dim i&, x&
    If check.Parent.ActiveControl.Name = check.Name And Not check.Name Like "*general*" Then
        For i = 0 To 2
            If check.Parent.Controls(i).Value = True Then x = x + 1
        Next
        If x = 3 Then check.Parent.Controls(3).Value = True Else check.Parent.Controls(3).Value = False
    Else
        If check.Name = check.Parent.ActiveControl.Name Then
            For i = 0 To 2
                check.Parent.Controls(i).Value = check.Value
            Next
        End If
    End If
End Sub

demonstration

[Nagel Tha]

Merci beaucoup c'est très sympa de ta part

[JohannCOU]

Bonjour à tous,
Merci d’avoir répondu aussi rapidement et d’avoir trouver la solution. Je suis désolé, je n’ai pas pu revenir vers vous plus tôt.

Merci en particulier à Patrick de nous avoir éclairer sur le sujet. Par contre, avec mon niveau, j’avoue que je n’ai pas tout bien compris. J’ai compris que l’événement click des checkboxes 1,2 et 3 se déclenchaient alors qu’il n’y avait pas de raison. Quand je reprends ton code avec les événements click dans mon modèle réel, cela ne fonctionne pas car je pense que c’est du aux frames. Si j’ai bien tout compris de la conversation, il faut que j’utilise les modules de classe pour résoudre mon problème. Je n’ai jamais fait de module de classe et j’avoue que je ne connais même pas l’utilité !! dure !! Voici mon modèle réel :

Je n’ai pas le même nombre de checkboxes dans chaque frame, faut-il donc que je crée un module de classe pour chacune des frames ?

De mon côté, je vais essayer d'étoffer mes compétences sur les modules de classes.

Merci d’avance pour votre aide.

[JohannCOU]

Bonjour à tous,
Pour résoudre mon problème, j’ai tenté de compter le nombre de checkboxes dans le frame actif mais je n’y suis pas arrivé.
J’ai trouvé une solution qui me plaît moyennement mais fonctionne malgré tout. J’ai créé des checkboxes pour avoir le même nombre de checkboxes dans chaque frame. Dans les propriètés de ces checkboxes j’ai mis dans le nom « invisible », j’ai mis la valeur à Vrai et je les ai rendus invisible.
J’ai ensuite modifié le code de Patrick pour que quand on clique sur le checkbox général, la valeur des checkboxes « invisible » soit Vrai. Avec cette solution, si on décoche tout les checkboxes avec le checkbox « général » et qu’on les re-coche une par une, le checkbox général se met à jour même si le nombre de checkboxes n’ai pas maximal.
Voici le code modifié dans le module de classe de Patrick:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
 
Private Sub check_Click()
    Dim i&, x&, n&
    n = 6
If check.Parent.ActiveControl.Name = check.Name And Not check.Name Like "*general*" Then
        For i = 0 To n - 1
            If check.Parent.Controls(i).Value = True Then x = x + 1
 Next
        If x = n Then check.Parent.Controls(n).Value = True Else check.Parent.Controls(n).Value = False
    Else
        If check.Name = check.Parent.ActiveControl.Name Then
         For i = 0 To n - 1
        If check.Parent.Controls(i).Name Like "*invisible*" Then 'Pour ne pas se préoccuper des checkboxes invisibles car je n'arrive pas à compter les checkboxes dans le frame actif
        check.Parent.Controls(i).Value = True
            Else
                  check.Parent.Controls(i).Value = check.Value 
            End If
            Next
         End If
    End If
End Sub

Je passe la discussion en résolue mais je pense qu’il faudrait quand même trouver une solution pour compter le nombre d’objets dans le frame ACTIF pour avoir une solution plus « propre ».

Encore merci pour votre aide et à bientôt.

[patricktoulon]

bonjou johannCOU
il est ou ton soucis(d'adaptation pour des frames avec un nombre differents de textbox????????
y en a pas de soucis une simple adaptation des boucle avec limite des frames.controls.count
on determine meme le checkbox general de chaque frame avec (a condition que tu l'ai construit dans l'ordre bien sur )
dans les memes conditions que ma demo precedente
x frames avec y checkbox dont un general contenant "general" dans son nom

code userform on change rien

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Dim cl As New Classecheckbox
Private Sub UserForm_Activate()
    cl.initiate Me
End Sub

code de la classe nommée

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
 
Option Explicit
Public WithEvents check As MSForms.CheckBox
Dim cls() As New Classecheckbox
Public Function initiate(usf)
    Dim Ctrl As Object, fra As Object, a&, general As Object
    For Each fra In usf.Controls
        If TypeName(fra) = "Frame" Then
            For Each Ctrl In fra.Controls
                  a = a + 1: ReDim Preserve cls(1 To a): Set cls(a).check = Ctrl:
            Next
        End If
    Next
End Function
Private Sub check_Click()
    Dim i&, x&, checkgeneral As Object, checkcount&
    checkcount = check.Parent.Controls.Count
   Set checkgeneral = check.Parent.Controls(checkcount - 1)
     If check.Parent.ActiveControl.Name = check.Name Then
        If check.Name <> checkgeneral.Name Then
            For i = 0 To checkcount - 1
                If check.Parent.Controls(i).Value = True Then x = x + 1
            Next
            If x = checkcount - 1 Then checkgeneral.Value = check.Value
        ElseIf check.Name = checkgeneral.Name Then
            For i = 0 To checkcount - 1
                check.Parent.Controls(i).Value = check.Value
            Next
        End If
    End If
End Sub

non vraiment rien de compliqué

demo:

[JohannCOU]

Merci Patrick d'avoir donner la solution pour compter les checkboxes dans le frame actif.

Discussion vraiment résolue cette fois!

A bientôt.