Garder Excel au premier plan

**MarcelG** · 19/02/2018, 16h48

Bonjour à tous,

Depuis mon applicatif Excel, j'ouvre l'Application Outlook si celle-ci est fermée.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Sub Test_Open_Outlook()
 
Dim Chemin As String
Chemin = "C:\Program Files (x86)\Microsoft Office\root\Office16\OUTLOOK.exe"
 
Dim Appli As Object
Dim session_Outlook As New Outlook.Application
Dim Ole_appli As Object
 
On Error Resume Next
Set Appli = GetObject(, "Outlook.Application")
 
If Appli Is Nothing Then
      'Ouvre Outlook
        session_Outlook = Shell(Chemin, 1)
Else
        'Fermeture de l'application Outlook si ouverte et réouverture d'une nouvelle
        Set Ole_appli = CreateObject("Outlook.Application")
        Ole_appli.Quit
        session_Outlook = Shell(Chemin, 1)
End If
 
 
Set Ole_appli = Nothing
Set Appli = Nothing
 
End Sub

Mon problème est que si Outlook n'est pas activé, la procédure ouvre bien une session Outlook mais celle-ci reste au premier plan.
Après avoir regardé le descriptif de la méthode Shell, j'ai changé le 2nd argument mais rien n'y fait.

Merci!

**kiki29** · 19/02/2018, 16h53

Salut, à voir mais cela a dû être déjà fait ? sinon voir aussi ici

**Marc-L** · 19/02/2018, 16h58

Bonjour,

comme indiqué dans l'aide VBA interne, voir déjà du côté de l'instruction AppActivate …

___________________________________________________________________________________________________________

Je suis Paris, Egypte, Nigeria, New-York, Mogadicio, Barcelone, London, Manchester, Stockholm, Istanbul, Berlin, Nice, Bruxelles, Charlie, …

**MarcelG** · 19/02/2018, 17h57

Bonsoir,

Merci à vous deux pour vos réponses.

A Marc:

La méthode AppActivate "Microsoft Excel" ne donne rien sur mon poste.

A Kiki :

En voulant tester le code correspondant à ton premier lien, j'ai fermé mon applicatif après l'avoir sauvegardé.
A sa réouverture, la fenêtre porte son nom suffixé

.xlsm:1

Pourquoi ce :1

Merci bien en tout cas.
Demain, j'effectuerai un 2ème test.

**MarcelG** · 20/02/2018, 11h02

Bonjour,

Comme indiqué par Kiki, j'ai adapté le code figurant dans la FAQ
Cette opération m'a formé sur les "Handle"
Mais sans succès.
La variable Long Hwnd est bien retournée mais les méthodes

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Ramène Excel au premier plan
BringWindowToTop Hwnd
'Affiche en mode "Normal"
ShowWindow Hwnd, 1

sont sans effet.

Code complet:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
Option Explicit
 
Private Declare Function BringWindowToTop Lib "user32" _
    (ByVal Hwnd As Long) As Long
 
Private Declare Function FindWindow Lib "user32" Alias _
    "FindWindowA" (ByVal lpClassName As String, _
    ByVal lpWindowName As String) As Long
 
Private Declare Function ShowWindow Lib "user32" _
    (ByVal Hwnd As Long, ByVal nCmdShow As Long) As Long
 
Sub Test_Open_Outlook()
 
Dim Chemin As String
Chemin = "C:\Program Files (x86)\Microsoft Office\root\Office16\OUTLOOK.exe"
 
Dim Appli As Object
Dim session_Outlook As New Outlook.Application
Dim Ole_appli As Object
 
On Error Resume Next
Set Appli = GetObject(, "Outlook.Application")
 
If Appli Is Nothing Then
      'Ouvre Outlook
        session_Outlook = Shell(Chemin, 1)
Else
        'Fermeture de l'application Outlook si ouverte et réouverture d'une nouvelle
        Set Ole_appli = CreateObject("Outlook.Application")
        Ole_appli.Quit
        session_Outlook = Shell(Chemin, 1)
End If
 
Set Ole_appli = Nothing
Set Appli = Nothing
 
Call Excel_premier_plan
 
End Sub
 
Sub Excel_premier_plan()
 
'Voir FAQ Développez.com
'https://excel.developpez.com/faq/?page=Automation#AppliPremierPlan
 
'Remarque importante:
'La procédure ne doit pas être déclenchée depuis l'éditeur de macros /!\
 
Dim Hwnd As Long
 
'Récupère le Handle d'une fenêtre
'Le Handle est un nombre entier unique généré par Windows afin d'identifier les fenêtres.
'2ème argument = titre de la fenêtre.
 
Hwnd = FindWindow(vbNullString, ThisWorkbook.Name & " - Excel")
If Hwnd = 0 Then _
      Hwnd = FindWindow(vbNullString, ThisWorkbook.Name & ":1 - Excel")
 
Debug.Print "Hwnd : " & Hwnd
 
'Ramène Excel au premier plan
BringWindowToTop Hwnd
'Affiche en mode "Normal"
ShowWindow Hwnd, 1
 
Application.WindowState = xlMaximized
 
End Sub

Si un sachant peut tester.

Merci

**patricktoulon** · 20/02/2018, 13h03

salut MarcelG

somme toute pas de quoi fouter un chat
la fonction setwindowpos de l'api user32 fait cela mieux que toutes les autre et pas besoins d'autre api ni meme!!! findwindow
seul petit probleme il lui faut les cote de la fenetre EN PIXEL!!! ce qui implique encore d'autre fonction de conversion pointtopixel
que j'aurais pu te donner
mais comme c'est juste pour un "infirstplan" on va faire simple

on va utiliser setwindowpos avec le cote 0 0 0 0 en ayant préalablement memoriser les cotes de ta fenetre application
voila la fentre est au premier plan mais toute petite
que cela te tienne on la remet au cote et position initiale
elle restera en firstplan

1°declaration de l'api a adapter si tu travail avec excel ebn 64 bits

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Private Declare Function SetWindowPos Lib "user32" (ByVal Hwnd As Long, ByVal hWndInsertAfter As Long, ByVal x As Long, ByVal y As Long, ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long) As Long

2°pour la mettre en first plan

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Sub first_in_plan()
    Dim app, posioton, L, T, W, H
    Set app = Application
    T = app.Top: L = app.Left: W = app.Width: H = app.Height
     Position = SetWindowPos(app.Hwnd, -1, 0, 0, 0, 0, 0)
    app.Top = T: app.Left = L: app.Width = W: app.Height = H
End Sub

3°pour la sortir du firstplan

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Sub No_first_in_plan()
    Dim app, posioton, L, T, W, H
    Set app = Application
    T = app.Top: L = app.Left: W = app.Width: H = app.Height
    Position = SetWindowPos(app.Hwnd, -2, 0, 0, 0, 0, 0)
    app.Top = T: app.Left = L: app.Width = W: app.Height = H
End Sub

salut Marcel

**MarcelG** · 20/02/2018, 13h14

Salut,

Je pense avoir trouvé en appliquant le code retourné par le 2ème lien de Kiki.

Préliminaire
Gestion poste 32 Bits/64 Bits

la ressource développement utilisée est ici

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
Option Explicit
 
 Public Declare Function SetWindowPos _
        Lib "user32" ( _
            ByVal hwnd As Long, _
            ByVal hwndInsertAfter As Long, _
            ByVal x As Long, ByVal y As Long, _
            ByVal cx As Long, ByVal cy As Long, _
            ByVal wFlags As Long) _
    As Long
 
Public Const SWP_NOSIZE = &H1
Public Const SWP_NOMOVE = &H2
Public Const HWND_TOPMOST = -1
Public Const HWND_NOTOPMOST = -2
 
''https://www.extendoffice.com/documents/excel/2030-keep-excel-window-on-top.html
 
Sub Test_Open_Outlook()
 
Dim Chemin As String
Chemin = "C:\Program Files (x86)\Microsoft Office\root\Office16\OUTLOOK.exe"
 
Dim Appli As Object
Dim session_Outlook As New Outlook.Application
Dim Ole_appli As Object
 
Dim typouv As Byte
typouv = 1
 
On Error Resume Next
Set Appli = GetObject(, "Outlook.Application")
 
Call ShowXLOnTop(True)
 
If Appli Is Nothing Then
      'Ouvre Outlook
        session_Outlook = Shell(Chemin, typouv)
Else
        'Fermeture de l'application Outlook si ouverte et réouverture d'une nouvelle
        Set Ole_appli = CreateObject("Outlook.Application")
        Ole_appli.Quit
        session_Outlook = Shell(Chemin, typouv)
End If
 
Set Ole_appli = Nothing
Set Appli = Nothing
 
Call ShowXLOnTop(False)
 
End Sub
 
Sub ShowXLOnTop(ByVal OnTop As Boolean)
    Dim xStype As Long
 
Dim xHwnd As Long
 
If OnTop Then
        xStype = HWND_TOPMOST
    Else
        xStype = HWND_NOTOPMOST
    End If
    Call SetWindowPos(Application.hwnd, xStype, 0, 0, 0, 0, SWP_NOSIZE Or SWP_NOMOVE)
End Sub

2 remarques selon mon usage:
- Procédure à activer hors éditeur VBE
- Bien placer les 2 appels de procédure

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Call ShowXLOnTop(True)

et

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Call ShowXLOnTop(False)

Si quelqu'un détient l'adresse d'un tutoriel sur Public Declare Fonction, user32... alors je suis preneur.

Merci Kiki

**MarcelG** · 20/02/2018, 13h18

Salut Patrick,

Content de te retrouver.

Nos envois se sont croisés.
Je regarde bien entendu

**patricktoulon** · 20/02/2018, 13h20

re
dans mon exemple pour ton cas si je ne me trompe pas
c'est Ole_appli.hwnd a la place de app.hwnd
et bien sur pour les dim et position aussi
en gros partout c'est Ole_appli a la place de app
si ca ne fonctionne pas alors findwindow(vbnullstring,Ole_appli .caption) a la place de app.hwnd
en ayant fait la declaration de la fonction bien sur