Récupérer des éléments d'une page sur internet

**patricktoulon** · 19/07/2011, 18h56

bonjour a tous

je suis en train de peaufiner un plugins media center (replay tv)qui s'intègre un peu mieux que ce qui c'est fait jusqu'à présent

et j'ai besoin de créer un fichier excel dans le quel des données dans la page de la chaîne désirée serait inscrites dans la feuil1

il me faut les vignette et les liens correspondant

j'ai regardé un peu dans la faq mais je n'ai pas trouvé ce que je cherche

une idée??

merci d'avance

au plaisir

**patricktoulon** · 20/07/2011, 14h37

bonjour edelveisseric

et bien petite fleur de velours c'est tout simple

je cherche a récupérer les petites images (aperçu des séries) avec le liens qui donne vers la page pour visionner le replay de l'a vignette en question

alors c'est assez difficile en effet sachant que les séries ne sont pas perpétuelles

non en fait il faudrait que sa se face automatiquement
j'explique

il y a plusieurs séries et épisodes proposées en replay

il faudrais tout simplement un code qui fouille la page cherche les séries en replay(ou toutes les videos)
récupère la vignette (petite image du film) et le lien

et me liste tout ça dans un sheets

a partir de la je crée un page html qui sera intégrée a mon fichier "xxxx.mcl"
avec les donnée du sheet et qui se retrouvera dans les bonus de media center

maintenant si la liste est créée dans un fichier text sa ne me derange pas

voila j'espere avoir été plus clair

merci pour ton aide

pour le momment mes plugins replay tv se presente de cette facon
j'affiche tout simplement la page de la chaine x replay

comme ceci

fichier de la chaine nrj12 replay

ce fichier on le place dans

"C:\Users\patrick\AppData\Roaming\Media Center Programs"

au plaisir

**Qwazerty** · 22/07/2011, 07h25

Salut
Tu peux manipuler un objet Internet Explorer, il est ensuite possible de naviguer d'une page a l'autre et de récupérer les éléments qui t’intéresse, il existe des poste à ce sujet, j'ai participé a certains.

Il serait peut être aussi intéressant de regarder dans Excel, il est possible de faire un lien vers des donnée extérieur contenu dans un site web.

[Edit] Je viens de regarder la page NRJ12, la structure de la page semble assez pratique pour réaliser des boucles permettant de contrôler la date de dépose de l'épisode dans la liste et de récupéré le lien de l'image (voir même l'image, il faut que je regarde mais j'ai vu un code permettant de récupérer une image à partir de son URL).
Fait signe si tu as besoin, j'ai fais pas mal de recherche depuis quelque temps sur le sujet IE, je regarderais peut être ce weekend d’ailleurs.
[/Edit]
++
Qwaz

Salut
Voila un exemple de ce qui est faisable.
Les dates des mises en ligne sont affichées dans le débugger et les miniatures sont placées dans un répertoire sur le DD.

J'utilise la function GetElementsByClassName, elle n'est pas totalement debugger, je n'ai pas encore pris le temps de la terminer comme il faut!

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
Option Explicit
 
Sub ListerBalise()
Dim IE As New InternetExplorer
Dim IEdoc As HTMLDocument
Dim htmlTagDate() As IHTMLElement
Dim htmlTagMedia() As IHTMLElement
Dim Generic As HTMLGenericElement
Dim htmlImg As htmlImg
Dim hDiv As HTMLDivElement
Dim i As Integer
 
 
 
'Ouvre la page WEB
IE.navigate "http://www.nrj12.fr/nrj12-replay-3276/nrj-12-562/collectionvideo/922-stargate-atlantis.html"
IE.Visible = True
WaitIE IE
Set IEdoc = IE.document
 
'On recupere l'element contenant le tableau de vignettes
htmlTagDate = getElementsByClassName(IEdoc.body, "date", False)
htmlTagMedia = getElementsByClassName(IEdoc.body, "media", False)
 
 
'On boucle sur les element contenu dans le tableau
For i = 0 To UBound(htmlTagDate) - 1
    'On recupere la date
    Debug.Print htmlTagDate(i).innerText
    'On sauvegarde l'image
    SaveHtmlFile htmlTagMedia(i).all(1).href, "D:\MiniPicto\" & htmlTagMedia(i).all(1).nameProp
Next
 
Set IE = Nothing
Set IEdoc = Nothing
End Sub
 
Sub SaveHtmlFile(aUrl As String, aDestination As String)
'Pris sur le forum de la msdn (avec quelques menues modifs)
Dim WinHttpReq As Object, oStream As Object
Dim TheURL As String
Set WinHttpReq = CreateObject("Microsoft.XMLHTTP")
WinHttpReq.Open "GET", aUrl, False
WinHttpReq.send
 
TheURL = WinHttpReq.responseBody
 
If WinHttpReq.Status = 200 Then
    Set oStream = CreateObject("ADODB.Stream")
    oStream.Open
    oStream.Type = 1
    oStream.Write WinHttpReq.responseBody
    oStream.SaveToFile aDestination
    oStream.Close
End If
End Sub
 
Function getElementsByClassName(IeParentElement As IHTMLElement, ClassName As String, DansSousElement As Boolean) As IHTMLElement()
'Fonction perso, attention par contre je ne l'ai pas encore bien finalisé ^^
'Ne pas utiliser le mode DansSousElement à True, il bug
Dim aElement As IHTMLElement
Dim SousElements() As IHTMLElement
Dim FuncElements() As IHTMLElement
Dim iElem As Integer, iElemS As Integer
Dim Tmpi As Integer
 
DansSousElement = False
 
For Each aElement In IeParentElement.all
'On pointe notre tableau de retour
    FuncElements = getElementsByClassName
 
    If ClassName = aElement.ClassName Then
        If IsArray(FuncElements) Then
            Tmpi = UBound(FuncElements) + 1
        Else
            Tmpi = -1
        End If
        ReDim Preserve FuncElements(Tmpi)
        Set FuncElements(Tmpi) = aElement
    End If
 
    If DansSousElement Then
        'On recherche dans les sous element
        SousElements = getElementsByClassName(aElement, ClassName, False)
        'Si on a des element retourné, on les rajoute au tableau precedent
        If IsArray(SousElements) Then Tmpi = UBound(SousElements)
        If Tmpi > -1 Then
            If IsArray(FuncElements) Then Tmpi = UBound(FuncElements) + Tmpi + 2
            If (Tmpi > 0) Then
                ReDim Preserve FuncElements(Tmpi - 1)
                iElemS = UBound(FuncElements) - UBound(SousElements) ' - 1
                For iElem = iElemS To UBound(FuncElements)
                    Set FuncElements(iElem) = SousElements(iElem - iElemS)
                Next
            End If
        End If
    End If
    getElementsByClassName = FuncElements
    Erase SousElements
Next
Erase FuncElements
 
End Function
Sub WaitIE(IE As InternetExplorer)
'On boucle tant que la page n'est pas totalement chargé
Do Until IE.readyState = READYSTATE_COMPLETE
    DoEvents
Loop
End Sub

++
Qwaz

**patricktoulon** · 22/07/2011, 23h20

re bonsoir qwazerty

ton code fonctionne a merveille pour les image

il me faudrai l'astuce pour récupérer le lien vers les quels elles pointent

mais attention mon projet est:

recupérer dans la page d'accueil les image et le liens vers les sections

ensuite recuperer dans chaque section les image et les liens et le résume du film

en effet dans ton exemple l'adresse de la section est connu
mais stargate atlantis peut être arrête donc le liens deviendra obsolète

je cherche si il y a une variable ou constante pour le lien

et en affichant la source je commence a comprendre ou et comment tu va chercher les données

pour continuer dans la lancé de ton code il faudrai recupéré dans la class

exemple dans la source

pour le lien :

<a href="/nrj12-replay-3276/nrj-12-562/media/video/389894-sous-hypnose.html"

pour le titre:

title="STARGATE ATLANTIS Replay - SOUS HYPNOSE - NRJ 12 Replay"

merci pour le coup de main

mais je suis dans le flou

au plaisir

**Qwazerty** · 23/07/2011, 06h52

Salut

Voila une modif pour aller chercher le résumer

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
Sub ListerBalise()
Dim IE As New InternetExplorer
Dim IEdoc As HTMLDocument
Dim IEBis As New InternetExplorer
Dim htmlTagDate() As IHTMLElement
Dim htmlTagMedia() As IHTMLElement
Dim htmlTagResum() As IHTMLElement
Dim Generic As HTMLGenericElement
Dim htmlImg As htmlImg
Dim hDiv As HTMLDivElement
Dim i As Integer
 
 
 
'Ouvre la page WEB
IE.navigate "http://www.nrj12.fr/nrj12-replay-3276/nrj-12-562/collectionvideo/922-stargate-atlantis.html"
IE.Visible = True
WaitIE IE
Set IEdoc = IE.document
 
'On recupere l'element contenant le tableau de vignettes
htmlTagDate = getElementsByClassName(IEdoc.body, "date", False)
htmlTagMedia = getElementsByClassName(IEdoc.body, "media", False)
 
 
'On boucle sur les element contenu dans le tableau
For i = 0 To UBound(htmlTagDate) - 1
    'On recupere la date
    Debug.Print htmlTagDate(i).innerText
    'On sauvegarde l'image
    SaveHtmlFile htmlTagMedia(i).all(1).href, "D:\MiniPicto\" & htmlTagMedia(i).all(1).nameProp
 
    'Le resumé
    'On charge la page du replay
    IEBis.navigate htmlTagMedia(i).all(0).href 'pour info ici tu as le lien vers la page contenant la vidéo htmlTagMedia(i).all(0).href
    WaitIE IEBis
 
    'Ici on recherche l'emplacement du résumé Nom de la class "type_3_tier"
    htmlTagResum = getElementsByClassName(IEBis.document.body, "type_3_tier", False)
    Debug.Print htmlTagResum(0).all(0).innerText
 
Next
 
Set IE = Nothing
Set IEdoc = Nothing
End Sub

Pour ce qui est d'aller chercher sur la page principal, le principe est exactement le même, j'ai pris SG1 pour avoir de suite accès a des infos.
Pour rechercher plus efficacement dans ta page web, je te donne une astuce, dans IE et Chrome (surement firefox et les autres aussi) utiliser la touche F12, elle fait apparaître l'outil d'aide au développement, sur IE par exemple, il y as un petit bouton avec une flache de souris dedans, une fois cliqué dessus, clique sur un élément de ta page web et le code se calera directement sur la partie gérant l'élément en question.

Il te reste a mettre en place une boucle qui intègre le code que je t'ai donné et qui chargera une à une toutes les séries présente en page principale.

Si tu as besoin d'un coup de pouce fais signe.

Bon courage.

++
Qwaz

**patricktoulon** · 23/07/2011, 17h01

bonjour qwazerty

pour le résumé sa fonctionne a merveille

mais je n'arrive toujours pas a récupérer le lien

exemple pour stargate

htmlTagMedia(i).all(1).href

me donne le lien de l'image et non pas le lien vers la page du film

exemple :

http://media.nrj.fr/160x120/mogador/..._prod_4875.jpg

alors qu'il pointe vers ça:

http://www.nrj12.fr/nrj12-replay-327...-partie-2.html

c'est très important que je puisse récupérer le lien qui est pointé par l'image

car je rempli un liste en feuill1 et a partir de cette feuille je relance la macro plusieurs fois (autant que d'image) pour remplir d''autre feuille avec les donnée de la page que le lien pointe

car j'ai bien essayé avec

htmlTagMedia(i).all(1).href

mais comme le lien qu'il représente est le lien vers l'image sa ne fonctionne pas

une idée??

merci a toi
au plaisir

**Qwazerty** · 23/07/2011, 17h58

Salut

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

    IEBis.Navigate htmlTagMedia(i).all(0).href 'pour info ici tu as le lien vers la page contenant la vidéo htmlTagMedia(i).all(0).href

il faut utiliser

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

htmlTagMedia(i).all(0).href

pour avoir le lien de la page contenant la vidéo.

++
Qwaz

**patricktoulon** · 23/07/2011, 18h54

re bonjour qwazerty

oui j'avais bien compris pour naviguer dans la page

mais je veux simplement récupérer le lien en "string" (text) et la ca ne fonctionne pas
edit :

oupss!! je n'avais pas bien regardé pour le lien ca fonctionne maintenant

il manque plus qu'a trouver le titre du film

je cherche ,je cherche

au plaisir

**Qwazerty** · 23/07/2011, 21h45

Salut

Tu peux le récupérer comme ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
'On boucle sur les element contenu dans le tableau
For i = 0 To UBound(htmlTagDate) - 1
    'On recupere la date
    Debug.Print htmlTagDate(i).innerText
    'On sauvegarde l'image
    SaveHtmlFile htmlTagMedia(i).all(1).href, "D:\MiniPicto\" & htmlTagMedia(i).all(1).nameProp
 
    'Le Titre
    Set Generic = htmlTagMedia(i).parentElement.all(4)
    Debug.Print Generic.innerText
 
    'Le resumé
    'On charge la page du replay
    IEBis.Navigate htmlTagMedia(i).all(0).href 'pour info ici tu as le lien vers la page contenant la vidéo htmlTagMedia(i).all(0).href
    WaitIE IEBis
 
    'Ici on recherche l'emplacement du résumé Nom de la class "type_3_tier"
    htmlTagResum = getElementsByClassName(IEBis.document.body, "type_3_tier", False)
    Debug.Print htmlTagResum(0).all(0).innerText
 
Next

++
Qwaz

**patricktoulon** · 23/07/2011, 22h54

re bonsoir qwazerty

puré tu maîtrise plus que bien

c'est tip top

a quelques détails près selon les section il n'y a pas de résumé
un e erreur se produit
"l'indice n'appartient pas a la sélection"
ensuite j'ai constaté une certaine instabilité quand même
la macro fonctionne très bien mais si je la reproduit plusieurs fois l'opération
de temps en temps ça plante

je met tout ça au propre et je pose un fichier exemple

merci pour ton coup de main

trop fort

au plaisir

**Qwazerty** · 24/07/2011, 07h12

Salut

J'ai aussi eu des soucis mais ils étaient dû à un non chargement de la page, la page fini bien de ce charger, mais elle ne contient pas les série. J'ai même eu un message "Votre site NRJ12 revient dans quelques minutes".

Il suffit à mon avis de tester le contenu de htmlTagDate par exemple,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
 
Dim TabVide as Variant
'On regarde si notre variable contient des données
On Error Resume Next
TabVide = UBound(htmlTagDate)
On Error GoTo 0
 
If IsEmpty(TabVide) Then
    [...] Ici la page n'est pas chargé correctement

Ça devrait suffire pour savoir si les champs sont présent ou non et faire de même sur la page de la vidéo.
Ensuite tu peux mettre la partie chargement de la page dans une boucle Loop While jusqu'a avoir un contenu dans htmlTagDate, si tu fais ça pense à mettre un chien de garde en plaçant une variable que tu incrémente à chaque chargement et une sortie de la boucle au bout de x essai avec message d'erreur.

Pour le résumé, c'est pareil, il faut regarder la structure du code lorsque le résumé n'existe pas et tester si l'élément qui contient le message existe ou non. Idem que sur htmlTagDate pour ma méthode.

++
Qwaz

Salut

Une autre solution, qui me semble plus propre

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
htmlTagMedia = getElementsByClassName(IEdoc.body, "content_internal_type_15", False)
Set Generic = htmlTagMedia(0)
 
'On passe en revu les elements fils
For Each TheElement In Generic.Children
    'On passe les lignes de séparation
    If TheElement.ClassName <> "clear" Then
        'Date
        Debug.Print TheElement.Children(0).innerText
 
        'Titre
        Debug.Print TheElement.Children(2).innerText
 
        'Image
        SaveHtmlFile TheElement.Children(1).all(1).href, "D:\MiniPicto\" & TheElement.Children(1).all(1).nameProp
 
        'Résumé
        'On charge la page du replay
        IEBis.Navigate TheElement.Children(1).all(0).href 'pour info ici tu as le lien vers la page contenant la vidéo htmlTagMedia(i).all(0).href
        WaitIE IEBis
 
        'Ici on recherche l'emplacement du résumé Nom de la class "type_3_tier"
        htmlTagResum = getElementsByClassName(IEBis.document.body, "type_3_tier", False)
        If UBound(htmlTagResum) <> -1 Then
            Debug.Print htmlTagResum(0).all(0).innerText
        End If
 
 
    End If
Next

Attention aussi à l'enregistrement du fichier image, si l'image existe déjà ça plante, mais bon je suppose que tu ne rajoutes que les éléments qui n'existaient pas encore dans ton fichier, sinon un on error resume next résoudra le soucis ou alors il faut tester l’existence du fichier et le detruire si tu veux le remplacer.

++
Qwaz

**patricktoulon** · 24/07/2011, 17h12

bonjour qwazerty

va y doucement avec mon cerveau je n'ai pas eu le temps de tout assimiler

je vais regarder ta nouvelle version
en attendant voila le fichier qui me liste le menu principal et enregistre les images

et ensuite toutes les sections
un sheets est créé à chaque changement de section les image sont enregistrées aussi

j'ai volontairement bloqué avec un apostrophe les lignes pour le résumé

en effet je n'arrive pas encore a le gérer au cas ou il y en a pas
edit :
heu!!! javoue que la je patoge on travaillait avec le .parent et maintenant c'est avec le .children

ou je met ca maintenant

voila le fichier

**Qwazerty** · 24/07/2011, 18h08

Salut

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
Sub ListerBalise2()
    Dim IE As New InternetExplorer
    Dim IEdoc As HTMLDocument
    Dim IEBis As New InternetExplorer
    Dim htmlTagDate() As IHTMLElement
    Dim htmlTagMedia() As IHTMLElement
    Dim htmlTagResum() As IHTMLElement
    Dim Generic As HTMLGenericElement
    Dim htmlImg As htmlImg
    Dim hDiv As HTMLDivElement
    Dim i As Integer
    Dim NomSheets As String
    Dim NewSheet As Worksheet
    Dim Page As Long
 
    For Page = 2 To Sheets("Menu principal").Cells(Rows.Count, "A").End(xlUp).Row
        NomSheets = Sheets("Menu principal").Cells(Page, 4).Value
        Set NewSheet = Sheets.Add(After:=Sheets(Sheets.Count))
        NewSheet.Name = NomSheets
 
        'Ouvre la page WEB
        IE.navigate Sheets("Menu principal").Cells(Page, 3).Value
        IE.Visible = True
        WaitIE IE
        Set IEdoc = IE.document
 
        'On recupere l'element contenant le tableau de vignettes
        htmlTagDate = getElementsByClassName(IEdoc.body, "date", False)
        htmlTagMedia = getElementsByClassName(IEdoc.body, "media", False)
 
 
        'On boucle sur les element contenu dans le tableau
        For i = 0 To UBound(htmlTagDate)
            'On recupere la date
            Debug.Print htmlTagDate(i).innerText
            'On sauvegarde l'image
            'Le Titre
            Set Generic = htmlTagMedia(i).parentElement.all(4)
            With NewSheet
                .Cells(i + 2, 1).Value = htmlTagDate(i).innerText  'recupere la date
                .Cells(i + 2, 2).Value = "D:\MiniPicto\" & NomSheets & "-icon" & i & ".jpg"    'je recupere l'image dans le dossier pour l'avoir a dispo
                'Ici c'est le lien de la page contenant la vidéo
                .Cells(i + 2, 3).Value = htmlTagMedia(i).all(0).href    'je recupere le lien de l'image au cas ou je voudrais simplement l'appeler _
                'Titre                                                                         dans la construction futur de la page html qui sera integré dans le plugins(gain de place et evite d'avoir des paquet d'images qui s'entassent si cette option n'est pas trop lente
                .Cells(i + 2, 4).Value = Generic.innerText
 
                'C'est ici pour le lien de l'image
                .Cells(i + 2, 5).Value = htmlTagMedia(i).all(1).href
                'SaveHtmlFile htmlTagMedia(i).all(1).href, ThisWorkbook.Path & "\MiniPicto\" & htmlTagMedia(i).all(1).nameProp
            End With
            SaveHtmlFile htmlTagMedia(i).all(1).href, ThisWorkbook.Path & "\MiniPicto\" & NomSheets & "-icon" & i & ".jpg"
 
 
            'Le resumé
            'On charge la page du replay
            IEBis.navigate htmlTagMedia(i).all(0).href    'pour info ici tu as le lien vers la page contenant la vidéo htmlTagMedia(i).all(0).href
            'Penser a rendre visible  au moins le temps de faire les essais
            IEBis.Visible = True
            WaitIE IEBis
 
            'Ici on recherche l'emplacement du résumé Nom de la class "type_3_tier"
            htmlTagResum = getElementsByClassName(IEBis.document.body, "type_3_tier", False)
            If UBound(htmlTagResum) <> -1 Then
                Debug.Print htmlTagResum(0).all(0).innerText
                Sheets(NomSheets).Cells(i + 2, 5).Value = htmlTagResum(0).all(0).innerText
            End If
        Next
 
    Next
    IE.Quit
    Set IE = Nothing
    IEBis.Quit
    Set IEBis = Nothing
    Set IEdoc = Nothing
 
End Sub

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
Sub Lister_les_sections()
Dim IE As New InternetExplorer
Dim IENavigate As InternetExplorer
Dim IEdoc As HTMLDocument
Dim htmlTagDate() As IHTMLElement
Dim htmlTagMedia() As IHTMLElement
Dim htmlTaglink() As IHTMLElement
Dim Generic As HTMLGenericElement
Dim htmlImg As htmlImg
Dim hDiv As HTMLDivElement
Dim i As Integer
 
 
'Ouvre la page WEB
IE.navigate "http://www.nrj12.fr/nrj12-replay-3276/nrj-12-562/collectionvideo/" '"http://www.nrj12.fr/nrj12-replay-3276/nrj-12-562/collectionvideo/922-stargate-atlantis.html"
IE.Visible = True
WaitIE IE
Set IEdoc = IE.document
 
'On recupere l'element contenant le tableau de vignettes
htmlTagDate = getElementsByClassName(IEdoc.body, "date", False)
htmlTagMedia = getElementsByClassName(IEdoc.body, "media", False)
'Attention ce nom de class "a href" n'existe pas dans la page
htmlTaglink = getElementsByClassName(IEdoc.body, "a href", False)
 
'On boucle sur les element contenu dans le tableau
For i = 0 To UBound(htmlTagDate) - 1
    'On recupere la date
    Debug.Print htmlTagDate(i).innerText
    Set Generic = htmlTagMedia(i).parentElement.all(4)
 
    With Sheets("Menu principal")
        'Date
        .Cells(i + 2, 1).Value = htmlTagDate(i).innerText
        'Image
        .Cells(i + 2, 2).Value = ThisWorkbook.Path & "\image_menu\" & "icon" & i & ".jpg"
        'Titre
        .Cells(i + 2, 4).Value = Generic.innerText
        'Lien
        .Cells(i + 2, 3).Value = htmlTagMedia(i).all(0).href
 
    End With
    'On sauvegarde l'image
    SaveHtmlFile htmlTagMedia(i).all(1).href, ThisWorkbook.Path & "\image_menu\" & "icon" & i & ".jpg"
 
 
Next
 
Set IE = Nothing
Set IEdoc = Nothing
End Sub

Quelques menues modifs, j'ai réactivé le contrôle de résumé.

Bon courage, n'hésite pas si tu as besoin

++
Qwaz

**patricktoulon** · 25/07/2011, 14h48

bonjour qwazerty

j'ai toujours la même erreur au niveau du résume

j'ai bien essayé le "on error goto " mais même avec ça ça ne fonctionne pas
çà plante toujours

çà me donne mal a la tête

une idée?

au plaisir

**Qwazerty** · 25/07/2011, 14h52

Salut
Sur quelle série et quel épisode as tu le problème? Je n'ai pas laissé la macro faire toutes les pages lorsque j'ai lancé ton fichier.

++
Qwaz

**patricktoulon** · 25/07/2011, 16h17

des le premier c'est a dire la section "tellement vrai"

la ligne en jaune est

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

If UBound(htmlTagResum) <> -1 Then

je vais supprimer une a une les section dans la page menu en re activant la macro car je pense qu'il y en a d'autre

merci du coup de main

il semble aussi que l'automation ole soit instable maintenant même pour stargate qui normalement fonctionne et bien bug
je vérifie si je n'ai pas fait une erreur mais je ne crois pas

merci encore a toi

en fait pour répondre a ta question "sur quelles sections sa bug"

sa fonctionne rien que sur les séries a l'exception de "mes parents vont t'adorer"
cela dis ça n'est pas une série que je suis mais comme je cherche a faire
des plu gins répondant a tout les goûts je le garderai

il me vient une idée

puisque a chaque boucle sur une section je créer un sheet et je le nomme avec le nom de la section

avec array comportant toute les série

ne pourrait on pas faire une simple condition
si le nom fait partie de l'array alors chercher le résumé sinon continue

mais j'avoue que je ne sais pas trop comment manipuler l'array dans la condition

au plaisir

**Qwazerty** · 25/07/2011, 17h08

Salut

Alors

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

            IEBis.Navigate2 htmlTagMedia(i).all(0).href

Navigate2 évite de charger une nouvelle feuille à chaque fois...

Pour le problème Ubound ... en effet ça me le fait aussi, je me souviens l'avoir eu une fois, mais la c'est systématique, et le pire c'est que quand on relance ... ça repart sans problème...
Donc à problème pas propre ... solution pas propre

Dans un module

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)

Dans le code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
            'Ici on recherche l'emplacement du résumé Nom de la class "type_3_tier"
            htmlTagResum = getElementsByClassName(IEBis.document.body, "type_3_tier", False)
 
            Sleep 500
 
            If UBound(htmlTagResum) <> -1 Then

Et maintenant ça carbure ... mais bon

++
Qwaz

**patricktoulon** · 25/07/2011, 17h37

re bonjour

ca me fait "erreur d'execution(9)
l'indice n'apartient pas a la selection

la j'ai vraiment mal a la tete pourtant l'idée d'endormir avec le kernel etait bien trouvé je n'y aurais pas pensé

dis moi si l'idée d'utiliser un array contenant lesserie que l'on pourrais metre a jour ne serait pas une solution plus propre finalement

je ne savait pas pour navigate2 ca m'affichait la page sans redemarrer une autre ie ca ca m'interesse justement

on va bien finir par trouver je compte sur ton aide precieuse j'aimerais bien faire aboutir ce projet

merci encore a toi

il me vient une autre idée mais je ne sais pas si c'est possible

en fait le problème c'est que dans certaine section les éléments n'ont pas de résumés

et nous nous cherchons dans le class "type-3-tiers"

ne pourrait on pas boucler sur toute la page en iebis et chercher si la classe est existante a partir de la la réponse est simple mais encore une fois je ne sais pas si c'est possible

qu'en pense tu?

edit:

en affichant la source on se rend bien compte que la classe 3tiers ne comprend pas les elements de "tellement vrai"

<li class="txt"
><h1><a href="/nrj12-replay-3276/nrj-12-562/media/video/275627-c-est-decide-je-change-de-vie.html" title="c-est-decide-je-change-de-vie">C est decide je change de vie</a></h1></li>

**Qwazerty** · 25/07/2011, 18h37

Salut
En fait le soucis ne vient pas de la présence ou de l'absence de l'élément ayant "type_3_tier", c'est juste que VBA provoque une erreur lors du teste UBound et le fait de mettre Sleep juste avant, chez moi ça fonctionne, comme s'il avait pas le temps d'initialiser comme il faut le contenu de la variable htmlTagResum .
A mon avis, il faut résoudre ce problème, essai avec une valeur de Sleep un peu plus longue, (500 correspond a 500ms).

Si on est sur que le problème apparaît uniquement si l'élément est absent, quelque chose dans le genre passerait surement

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
            On Error Resume Next
            vTeste = -1
            vTeste = UBound(htmlTagResum)
            On Error GoTo 0
 
            If vTeste <> -1 Then
                Debug.Print htmlTagResum(0).all(0).innerText
                Sheets(NomSheets).Cells(i + 2, 6).Value = htmlTagResum(0).all(0).innerText
            End If

Ou alors quitte à y aller, carrement ça

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
            On Error Resume Next
            Debug.Print htmlTagResum(0).all(0).innerText
            Sheets(NomSheets).Cells(i + 2, 6).Value = htmlTagResum(0).all(0).innerText
            On Error GoTo 0

On ne cherche même plus a savoir si l'élément existe...
[Edit]
La dernière solution fonctionne très bien, il faut aussi modifier le numéro de colonne du Cells, 5 ça recouvre le lien de l'image.
[/Edit]
++
Qwaz

**patricktoulon** · 26/07/2011, 15h03

bonjour qwazerty

alors la première solution avec vteste supprime carrément le résume partout

par contre la deuxième solution avec les deux "on error goto..." fonctionne

quand il y a résumé il s'inscrit sinon il passe au suivant

par contre ça rallonge le temps d'exécution de la macro de 400% au moins

est ce normal?

sinon ca fonctionne nickel

Récupérer des éléments d'une page sur internet

VBA

Discussions similaires

Partager

Partager