Discussion :

[patricktoulon]

bonjour a tous
quand on remplie une listbox dans avec deux boucles imbriquées on est contraint a 10 colonnes
quand elle est remplie avec ROWSOURCE elle est figé on ne peut plus modifier quoi que ce soit

quand on la remplie avec un range on a la possibité de + de 10 colonne mais les valeurs sont celles de la plage(range)
je vous propose cette astuce
dans l'exemple qui suit elle est remplie avec 2 boucle inbriquées sur 15 colonnes

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Option Explicit
Private Sub UserForm_Activate()
Dim I As Long, C As Long
    With ListBox1
        .ColumnCount = 15
        '--------------------------------------------------
        ' !!!!!!C EST CA L ASTUCE!!!!!!!!!on la renplie avec une ligne de cellule(15 colonne) et on la clear
        .List = Range("A1").Resize(1, .ColumnCount).Value: .Clear
        '--------------------------------------------------
        'elle est maintenant dimentionné a 15 colonne et valide pour 15 colonnes  MEME!!!!!! si elle est vide !!!!!!!!!!!!
        'maintenant on (((peut)))!!! la remplir normalement avec 2 boucles ligne/colonnes )imbriquées
        For I = 0 To 10
            .AddItem ""
            For C = 0 To 14
                .List(I, C) = "Ligne" & I + 1 & " Col" & C + 1
            Next
        Next
    End With
End Sub
Private Sub UserForm_Click()
End Sub

en effet l'orsque l'on la remplie avec une plage par le ".List", elle accepte + de 10 colonne et quand on la vide elle garde le dimensionnement du columncount

le principe et donc de la remplir provisoirement avec 1 range d'une ligne et x colonnes et de la vider avant de la remplir avec les boucles

testé sur 2007 et 2013

[Pierre Fauconnier]

Salut.

A quoi elle sert, "l'astuce"? Tant qu'à utiliser des boucles, je trouve alors plus intéressant de remplir d'abord un tableau avec les boucles puis de passer le tableau à la propriété List du listbox. Resizer une plage pour la passer à .List, vider .List puis l'alimenter par boucles imbriquées, ça me semble franchement tordu et absurde. Je ne vois vraiment pas l'intérêt de cette "astuce" inutile

Qui plus est, cette "astuce" ne peut s'appliquer qu'à Excel, et pas à Word, Powerpoint...

Code vba :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub Test()
  Dim t(0 To 10, 0 To 14)
  Dim l As Long, c As Long
 
  For l = 0 To 10
    For c = 0 To 14
      t(l, c) = "L" & l & ":C" & c
    Next c
  Next l
  With UserForm1
    .ListBox1.List = t
    .Show
  End With
End Sub

[patricktoulon]

re
tu n'a pas compris la démarche

le remplissage 2 boucles c'est pas ce qui est intéressant ici
tu peux tres bien avoir a ajouter a un moment donné des lignes sans que ce soit systématique dans une boucle

certe la variable tablo fonctionne aussi

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
with listbox1
.columncount=15
.list=range("A1").Resize(1,.columncount):.clear
 
'tu fait ce que tu veux avec ta liste après elle a ses 15 colonnes
end with

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
with listbox1
.columncount=15
redim tabo(1,.columncount)
.list=tablo:.clear
 
'tu fait ce que tu veux avec ta liste après elle a ses 15 colonnes
end with

[Pierre Fauconnier]

J'ai bien compris la démarche, et je maintiens qu'elle ne sert à rien.

Comment vas-tu remplir la listbox, après l'avoir nettoyée avec Clear? A part en bouclant, je ne vois pas trop. Car si tu ne la remplis pas en bouclant, tu n'as besoin de la préparer avant. Quand tu mets en commentaire dans ton code "'tu fait ce que tu veux avec ta liste après elle a ses 15 colonnes", ben à part la charger avec une boucle, je ne vois pas ce que tu pourrais en faire.


Donc

• soit tu n'as pas besoin de boucle(s), et donc pas besoin de préparer la listbox;
• soit tu as besoin de boucle(s), et alors, ne prépare pas ta listbox, boucle pour remplir un tableau et passe ton tableau à .List.

Dans les deux cas, passer par un .List suivi d'un .Clear ne sert à rien, et même si on arrivait à me prouver la quelconque utilité de ce bazar, c'est de toute façon stupide, selon moi, de passer par une plage redimensionnée à coup de .Resize.

C'est en cela que je dis que ton astuce n'en est pas une puisqu'elle ne sert à rien et qu'elle n'est pas générique VBA, puisqu'elle utilise une plage Excel... Ca n'a vraiment aucun sens

[boisgontierjacques]

Bonjour,


AddItem est lent.
.List Array ou .Column Array sont beaucoup plus rapides

Boisgontier