Discussion :

[licpegpon]

Bonjour,

Voici ce que j'essaie de faire (sans succès pour l'instant) :

Je dispose d'un fichier EXCEL nommé "FOLLOW_UP_TEST.xlsm" comportant de nombreux onglets.

Je souhaiterais enregistrer uniquement l'onglet "COMPARE" de ce fichier dans un nouveau fichier qui se nommerait "COMPARE_TEST_A_Date_heure.xlsx".

Le nouveau fichier ne doit pas comporter de formules. Il s'agit donc de faire un copier coller spécial valeurs.

Voici un début de procédure (qui ne fonctionne pas ) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Sub Create_new_file()
Dim Filename As String
'
'Saisie du dossier
Dossier_racine = InputBox("Enter the root directory", "Root directory", "P:\2-Planning\Test\2019\IDs")
'
Worksheets("COMPARE").Copy
With ActiveWorkbook
     .SaveAs Filename:="Compare_TEST_A_" & Format(Date, "yyyymmdd") & "_" & Format(Time, "hhmmss") & ".xlsx", FileFormat:=xlOpenXMLWorkbook
     .Close SaveChanges:=False
End With
End Sub

Des suggestions ? Merci par avance.

Cdlt.
Jérôme.

[MarcelG]

Bonjour,

Ouh la!

Filename est un mot clé de VBA, non une variable.

D'autre part, le classeur venant d'être sauvegardé, l'argument SaveChanges est redondant.

Après en avoir intégré les méthodes et propriétés, essaie d'adapter ce code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub copie_wks()
 
Dim dossier_racine As String
dossier_racine = InputBox(Prompt:="Enter the root directory", Title:="Root directory", Default:="P:\2-Planning\Test\2019\IDs")
 
Feuil1.Copy
With ActiveWorkbook
        With .ActiveSheet.UsedRange
                .Value = .Value
        End With
        .SaveAs Filename:=dossier_racine & Application.PathSeparator & "Compare_TEST_A_" & Format(Date, "yyyymmdd") & "_" & Format(Time, "hhmmss") & ".xlsx", FileFormat:=xlOpenXMLWorkbook
        .Close
End With

Tu remarqueras que, une chaîne de caractères étant attendue, l'Inputbox est déclaré en String.

[patricktoulon]

bonjour
perso j'aimerais bien comprendre l'interet de l'utilisation d'un input ca fait plusieurs demande que je vois passer avec ce procédé
ca m'interpelle

perso je pense qu'avec la boite de dialogue GetSaveAsFilename,il nous est toujours possible de choisir un autre chemin par des simple clics
ainsi que modifier le nom qui est codé par défaut (en bleu dans le dialog)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub copie_wks()
    Dim chemin_complet As Variant, dossier As String, Lname As String
    dossier = "P:\2-Planning\Test\2019\IDs"
    Lname = "Compare_TEST_A_" & Format(Date, "yyyymmdd") & "_" & Format(Time, "hhmmss") & ".xlsx"
    chemin_complet = Application.GetSaveAsFilename(InitialFileName:=dossier & "\" & Lname, filefilter:="Exel Files (sans macro) (*.xlsx), *.xlsx", Title:="ENREGISTREMENT DE LA COPIE DE LA FEUILLE")
    If chemin_complet <> False Then
        Feuil1.Copy
        With ActiveWorkbook
            With .ActiveSheet.UsedRange
                .Value = .Value
            End With
            .SaveAs Filename:=chemin_complet, FileFormat:=xlOpenXMLWorkbook
            .Close
        End With
    End If
End Sub

[licpegpon]

Bonjour,

MERCI beaucoup à vous deux !!

J'ai remplacé :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Feuil1.Copy

par

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

compare.Copy

car c'est la feuille "COMPARE" que je veux copier. Le pb c'est que même si je mets "compare" en majuscule, automatiquement il est modifié et remis en minuscule. Quand j'exécute j'ai une erreur de compilation....fonction ou variable attendue.

Un truc m'échappe. Pourquoi "chemin complet" intègre t-il "dossier" ? dossier peut varier si je choisis d'enregistrer le fichier ailleurs que dans le dossier par défaut ?

pour ma culture, que signifie l'instruction :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

If chemin_complet <> False Then

Merci pour vos lumières...

Cdlt.
Jérôme.

[licpegpon]

Je pense avoir compris...

Je remplace :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Feuil1.Copy

par

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Worksheets("COMPARE").Copy

L'instruction :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

If chemin_complet <> False Then

teste si le dossier existe. Si chemin_complet est différent de False signifie (si j'ai bien compris) si chemin_complet existe alors copie l'onglet "COMPARE" sinon ne fait rien.

Merci à vous...

Cdlt.
Jérôme.

[patricktoulon]

re

teste si le dossier existe. Si chemin_complet est différent de False signifie (si j'ai bien compris) si chemin_complet existe alors copie l'onglet "COMPARE" sinon ne fait rien.

pas tout a fait
normalement il existe pas

le test false c'est pour le retour du dialog au cas ou tu ai cliquer "annuler"ca renvoie false c'est normal donc ne fait rien
mais en aucun cas il test si un dossier ou fichier existe