Numérotation personalisée ACCESS

**Gérald03** · 29/08/2018, 16h27

Bonjour,

J'utilise ce code pour automatiser et incrémenter un numéro de devis.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Private Sub N°_DEVIS_Click()
If IsNull(Me.NrDevis) Then
    Me.NrDevis = Autonumber("Tbl-devis", "Nrdevis", "DEV.[YYYY].", 4)
  End If
End Sub

Avec également un module Autonumber. (que voici)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
' ---
' NUMEROTATION AUTOMATIQUE PERSONNALISEE
' ---
' Entrée : strTable  <- Nom de la table.
'          strField  <- Nom du champ contenant le numéro
'          strFormat <- Gabarit décrivant comment formater
'                       le numéro.
'          intDigits <- Nombre de caractères pour le
'                       numéro proprement dit.
'          dtDate    <- Date de référence pour le calcul
'                       de l'année, du mois...
'
Function Autonumber( _
  ByVal strTable As String, _
  ByVal strField As String, _
  Optional ByVal strFormat As String = "", _
  Optional ByVal intDigits As Integer = 4, _
  Optional ByVal dtDate As Date = #1/1/100#)
 
' Quelques variables...
On Error GoTo AutoNumberErr
Dim varMarkers As Variant, varMark As Variant
Dim strCriteria As String
Dim strNum As String, lngNum As Long, strPart As String
 
' Quelques retraitements...
If dtDate = #1/1/100# Then dtDate = Now()
strField = "[" & strField & "]"
strFormat = Replace(strFormat, "'", "''")
 
' Marqueurs à remplacer
varMarkers = Array("YYYY", "YY", "Q", "MM", "WW", "DD")
For Each varMark In varMarkers
  ' Formater la date et l'injecter dans le template
  strPart = Format(dtDate, varMark, vbMonday, vbFirstFourDays)
  strFormat = Replace(strFormat, "[" & varMark & "]", _
    Format(strPart, String(Len(varMark), "0")))
Next
 
' On cherche la valeur maximale déjà employée dans la table
strCriteria = strField & " LIKE '" & strFormat & "*'"
strNum = Nz(DMax(strField, strTable, strCriteria), "")
 
' On crée le nouveau numéro
lngNum = IIf(strNum = "", 1, Val(Mid(strNum, Len(strFormat) + 1)) + 1)
strFormat = strFormat & Format(lngNum, String(intDigits, "0"))
 
' Valeur finale
Autonumber = strFormat
Exit Function
 
AutoNumberErr:
  MsgBox "Erreur : " & Err.Description, vbCritical
  Autonumber = ""
  Exit Function
End Function

Cela ne fonctionne plus, il n'incrémente plus le numéro, il insére toujours le DEV.2018.0001

J'ai tout essayer, rien n'y fait.
Paradoxalement sur une version conçue il y a plus d'un an, cela fonctionne toujours, par contre dés que je développe une autre application avec la même module et le même code, impossible de de faire fonctionner.

Merci pour vos réponses

GERALD

**hyperion13** · 29/08/2018, 17h42

Salut,
Je viens de faire un essai sur une version Acc2013 avec les éléments fournis et l'incrément fonctionne parfaitement.
Vous évoquez "sur une autre application". Nouvelle base de données ? Acc2007 ou autre ?
Avez-vous changé quelque chose ? Nom de la table, nom du champ ?

**Gérald03** · 29/08/2018, 18h01

Oui j'ai changé le nom de la table et le nom du champ, mais la syntaxe correspond, ne n'est pas la première fois que je le fait, cela a toujours fonctionné. Autre remarque importante, ce matin j'ai fait une petite base pour essai avec ces codes , cela a fonctionnė , j'ai fermé la base je l'ai réouverte j'ai de nouveau essayé et la plus rien ne fonctionne .

**marot_r** · 29/08/2018, 22h03

Bonjour.

plus rien ne fonctionne .

C-a-d ?

Tu as une erreur ? Laquelle ?
Tu as des donnees mais pas celles attendees ? Qu'attendais-tu ? Qu'as-tu eu ?
Tu n'as pas de donnees ?

Dans le dernier cas, as-tu valide que ton code s'executait bien ?
Il est possible que les protections anti-macro d'Access soient enclenchees et empechent le code de fonctionner.

A+

**hyperion13** · 30/08/2018, 09h56

Salut
Pour compléter la réponse de marot_r, n'auriez-vous pas un bandeau de sécurité qui s'affiche à l'ouverture de votre bdd comme sur le lien ici ?

**Gérald03** · 31/08/2018, 16h45

Bonjour,

Je viens de passer une heure dessus, toujours le même problème.
Non pas de bandeau de sécurité qui s'affiche !!

GERALD

**marot_r** · 31/08/2018, 16h51

Bonjour.

as-tu valide que ton code s'excutait bien ?

A+

**Gérald03** · 31/08/2018, 17h42

Bjr,

Vous entendez par quoi VALIDE ?
GERALD

**Gérald03** · 31/08/2018, 17h49

Je poste l'exemple

GERALD

**marot_r** · 31/08/2018, 17h52

Bonjour.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Vous entendez par quoi VALIDE ?

je n'ai pas d'accents sur mon clavier donc c'est le participe passe du verbe "Valider".

Tu mets un point d'arret sur la 1ere ligne de ton code et si Access s'arrete la tu peux suivre pas a pas l'execution en appuyant sur [F8].
Ainsi tu peux valider que tes instructions sont bien executees ou pas.

A+

**Gérald03** · 31/08/2018, 18h10

Toujours pareil, même problème, il n'incrémente pas le N°

a+

**marot_r** · 31/08/2018, 18h28

Est-ce que ton code s'execute ou pas ?

Si oui est-ce qu'il est bien passe sur l'incrementation.

Tu donnes de resultat sans donner de detail de comment tu t'y rends ce qui fait qu'on est dans le noir complet pour t'aider a trouver la cause.

L'interface boule de crystal qui serait tres utile dans ce genre de cas n'est pas encore inventee, desole.

A+

**hyperion13** · 31/08/2018, 18h51

Salut marot_r
J'ai téléchargé la bdd de gérald, l'incrément ne fonctionne pas.
J'ai créé une bdd (en pj) copié le module Autonumber, créé unt tbl et un form, et sur ma bdd l'incrément fonctionne.

Je suis sous PackOffice 2013Pro

**tee_grandbois** · 31/08/2018, 21h37

bonsoir,
j'ai aussi téléchargé la bd de Gérald03: l'option syntaxe compatible SQL Server (ANSI 92) est cochée dans les options Access de la base (options pour Concepteur d'objets). Il faut donc utiliser ALIKE % au lieu de LIKE *

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
' On cherche la valeur maximale déjà employée dans la table
strCriteria = strField & " ALIKE '" & strFormat & "%'"

**Gérald03** · 01/09/2018, 09h21

Bjr, merci pour vos réponses,

Je viens de tester la réponse de tee_grandbois, j'ai mis "ALIKE" au lieu de "LIKE", résultat identique, pas d'incrémentation. On a l'impression que le code est fait pour fonctionner sur deux applications maximum, et que passer ce nombre il ce verrouille. Je l'ai utilisé dans deux applications. Bizarrement, j'ai créer une table et un formulaire sur une application existante ou le code fonctionne bien cela marche a merveille, mais des que je conçois une nouvelle application avec ce code cela ne fonctionne plus !!!!!, j'importe le module en utilisant la commande données externes. Le code événement en copier coller. Et la ça ne fonctionne plus. Est ce que cela pourrai venir d'access lui même, faudrait il le réinstaller ?

gérald

**Gérald03** · 01/09/2018, 09h26

Je viens de tester l'exemple posté par hyperion13, cela ne fonctionne pas sur mon poste !!!

GERALD

**hyperion13** · 01/09/2018, 12h16

Salut Gérald,
Je ne saurais te répondre quant à savoir s'il faut ou non réparer Acc2007. Mais pourquoi pas, sait-on jamais.
Sinon, une alternative à ton problème

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub Commande7_Click()
Me.Nrdevis = "DEV." & Format(Now(), "mm") & "-" & Format(Now(), "yyyy") & "." & Format(DMax("iddevis", "tbldevis") + 1, "0000")
End Sub

**Gérald03** · 01/09/2018, 13h12

Bjr,

Merci pour votre réponse, je viens de tester le code que vous avez posté, ca fonctionne parfaitement, je vais l'utiliser en attendant de trouver la solution.
Encore merci

GERALD

**hyperion13** · 01/09/2018, 15h20

Re,
J'ai repris le travail réalisé par Christophe Warin ici pour trouver une alternative aux problème de ta fonction Autonumber().
Par contre j'ai ajouté un champ dateDev et un champ indice. Il faut sélectionner une date pour ensuite cliquer sur le btn.
La numérotation reprendra à 0001 à chaque début de nouveau mois de chaque année, ou bien à chaque année.

**tee_grandbois** · 01/09/2018, 15h57

bonjour,

Envoyé par Gérald03

Bjr, merci pour vos réponses,

Je viens de tester la réponse de tee_grandbois, j'ai mis "ALIKE" au lieu de "LIKE", résultat identique, pas d'incrémentation. On a l'impression que le code est fait pour fonctionner sur deux applications maximum, et que passer ce nombre il ce verrouille. Je l'ai utilisé dans deux applications. Bizarrement, j'ai créer une table et un formulaire sur une application existante ou le code fonctionne bien cela marche a merveille, mais des que je conçois une nouvelle application avec ce code cela ne fonctionne plus !!!!!, j'importe le module en utilisant la commande données externes. Le code événement en copier coller. Et la ça ne fonctionne plus. Est ce que cela pourrai venir d'access lui même, faudrait il le réinstaller ?

gérald

ALIKE tout seul ne suffit pas si tu ne remplace pas * par % et c'est pourtant bien ce que j'ai écris !

Il faut donc utiliser ALIKE % au lieu de LIKE *

et j'ai même mis le code corrigé:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
' On cherche la valeur maximale déjà employée dans la table
strCriteria = strField & " ALIKE '" & strFormat & "%'"

Numérotation personalisée ACCESS [AC-2007]

VBA Access

Discussions similaires

Partager

Partager