Discussion :

[Passepartout007]

Bonjour,

Dans mon fichier Excel j'ai deux feuilles. Une feuille "A" et une feuille "B".
Dans un userforme ou se trouve un Combobox que j'alimente à l'aide d'un code prenant les données de la feuille "A".
Si ma feuille active est la feuille "B" alors je n'arrive pas à compilé les données vers le Combobox.
Il faut savoir qu'au final il n'y aura qu'afficher que mon formulaire et le classeur dont les feuilles ne seront plus visible par les utilisateurs.

Voici le code en question :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Private Sub CBoxMateriel_DropButtonClick() ' prend la liste des UM
Dim X As String
Dim LFTS As Object
Dim Cel As Range ' défini les variables
Set LFTS = CreateObject("Scripting.Dictionary") ' créer un répertoire de l'UM
With Sheets("A") ' Prend les informations dans le feuille A
 
    For Each Cel In .Range("C2:C" & .[B1048576].End(xlUp).Row)
        X = Cel.Row
        If Range(Cells(X, 3), Cells(X, 3)).Value = "FTS" Or Range(Cells(X, 3), Cells(X, 3)).Value = "FTA" Then If Not LFTS.Exists(UCase(Range(Cells(X, 4), Cells(X, 4)).Value)) And Cel.Value <> "" _
            Then LFTS.Add UCase(Range(Cells(X, 4), Cells(X, 4)).Value), UCase(Range(Cells(X, 4), Cells(X, 4)).Value)
 
 
    Next Cel
End With
Me.CBoxMateriel.List = Application.Transpose(LFTS.items)
 
End Sub

Il y à donc cette ligne qui n'est pas prise en compte quand j'ai le feuille "B" activé

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

With Sheets("A") ' Prend les informations dans le feuille Base de données

Et cela créer donc une erreur à cette ligne car LFTS.items est vide et on y retrouve rien.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Me.CBoxMateriel.List = Application.Transpose(LFTS.items)

Je sais que la solution doit être toute simple, mais j'aimerais aussi qu'elle fonctionne quand le classeur est masqué. "Besoin de votre aide","N'hésitez pas à me lance sur des pistes", "J'aime comprendre ce que je fais"

Cordialement,
Passepartout007

[patricktoulon]

re
bonjour
c'est normal
regarde ton code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Private Sub CBoxMateriel_DropButtonClick() ' prend la liste des UM
Dim X As String
Dim LFTS As Object
Dim Cel As Range ' défini les variables
Set LFTS = CreateObject("Scripting.Dictionary") ' créer un répertoire de l'UM
With Sheets("A") ' Prend les informations dans le feuille A
 
    For Each Cel In .Range("C2:C" & .[B1048576].End(xlUp).Row)
        X = Cel.Row
        If Range(Cells(X, 3), Cells(X, 3)).Value = "FTS" Or Range(Cells(X, 3), Cells(X, 3)).Value = "FTA" Then If Not LFTS.Exists(UCase(Range(Cells(X, 4), Cells(X, 4)).Value)) And Cel.Value <> "" _
            Then LFTS.Add UCase(Range(Cells(X, 4), Cells(X, 4)).Value), UCase(Range(Cells(X, 4), Cells(X, 4)).Value)
 
 
    Next Cel
End With
Me.CBoxMateriel.List = Application.Transpose(LFTS.items)
 
End Sub

plus precisément ici, il n'y a pas quelque chose qui te dérange ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

 If Range(Cells(X, 3), Cells(X, 3)).Value = "FTS" Or Range(Cells(X, 3), Cells(X, 3)).Value = "FTA" Then If Not LFTS.Exists(UCase(Range(Cells(X, 4), Cells(X, 4)).Value)) And Cel.Value <> "" _            Then LFTS.Add UCase(Range(Cells(X, 4), Cells(X, 4)).Value), UCase(Range(Cells(X, 4), Cells(X, 4)).Value)

Range(Cells(X, 3) c'est le range de quel sheets et les autres ranges aussi d'ailleurs
que met on devant range dans un with sheets(xxxx)?????

le plus etonnant c'est que tu fait bien au depart

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

For Each Cel In .Range("C2:C" & .[B1048576].End(xlUp).Row)

[Passepartout007]

Bonjour mon chère patricktoulon,
C'est un plaisir de te revoir.
Cette ligne de code indique que c'est sur le sheet "A"

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

With Sheets("A") ' Prend les informations dans le feuille A

Cependant cela ne fonctionne pas.
J'ai bien essayer de faire :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Private Sub CBoxMateriel_DropButtonClick() ' prend la liste des UM
Dim X As String
Dim LFTS As Object
Dim Cel As Range ' défini les variables
Set LFTS = CreateObject("Scripting.Dictionary") ' créer un répertoire de l'UM
With Sheets("A") ' Prend les informations dans le feuille A
 
    For Each Cel In .Range("C2:C" & .[B1048576].End(xlUp).Row)
        X = Cel.Row
        If Sheet("A").Range(Cells(X, 3), Cells(X, 3)).Value = "FTS" Or Sheet("A").Range(Cells(X, 3), Cells(X, 3)).Value = "FTA" Then If Not LFTS.Exists(UCase(Sheet("A").Range(Cells(X, 4), Cells(X, 4)).Value)) And Cel.Value <> "" _
            Then LFTS.Add UCase(Sheet("A").Range(Cells(X, 4), Cells(X, 4)).Value), UCase(Sheet("A").Range(Cells(X, 4), Cells(X, 4)).Value)
 
 
    Next Cel
End With
Me.CBoxMateriel.List = Application.Transpose(LFTS.items)
 
End Sub

Ou encore

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Private Sub CBoxMateriel_DropButtonClick() ' prend la liste des UM
Dim X As String
Dim LFTS As Object
Dim Cel As Range ' défini les variables
Dim Feuille As Worksheets
Feuille = Worksheets("A")
Set LFTS = CreateObject("Scripting.Dictionary") ' créer un répertoire de l'UM
With Sheets("A") ' Prend les informations dans le feuille A
 
    For Each Cel In .Range("C2:C" & .[B1048576].End(xlUp).Row)
        X = Cel.Row
        If Feuille.range(Cells(X, 3), Cells(X, 3)).Value = "FTS" Or Feuille.Range(Cells(X, 3), Cells(X, 3)).Value = "FTA" Then If Not LFTS.Exists(UCase(Feuille.Range(Cells(X, 4), Cells(X, 4)).Value)) And Cel.Value <> "" _
            Then LFTS.Add UCase(Feuille.Range(Cells(X, 4), Cells(X, 4)).Value), UCase(Feuille.Range(Cells(X, 4), Cells(X, 4)).Value)
 
 
    Next Cel
End With
Me.CBoxMateriel.List = Application.Transpose(LFTS.items)
 
End Sub

J'ai essayer d'autre cas avec workbooks ou worksheets en mettant le nom avant le range et en utilisant le with et même en enlevant les with et je ne comprend pas pourquoi cela ne fonctionne pas.

Peux tu m'indiqué qu'elle fonction te semble la plus correcte à utiliser ? (même si la feuille est masqué)
Cordialement,
Passepartout007

[Passepartout007]

Bonjour je viens de comprendre un truc j'ai mi un "." devant les ranges mais cela ne fonctionne pas. je ne comprend pas.
Cordialement,
Passepartout007

[RyuAutodidacte]

Bonjour,

Le pointage dans le code n'est pas à prendre à la légère, et il faut toujours être vigilant là dessus selon le type de contextes :
• Code qui s'exécute entre classeur
• code qui s'exécute entre feuille

3 types d'utilisation :

• Via variables :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Dim sh As Worksheet ' feuille ou
Dim wb As Workbook ' classeur ou
Dim rg As Range ' plage

• de façon direct
Classeur.feuille.plage
Ou
Feuille.plage

• de façon sous-entendus via With - ex. :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
With classeur.feuille
     .PlageA.value = .PlageB.value
End With

Bien respecter ces principes d'écriture évite les problèmes dans un code

PS : qu'en est-il de mon MP ?

[Qwazerty]

Salut

En complément, tu peux simplifier tes écritures

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

.Range(.cells(1,3), .cells(1,3))

équivaut à pointer une plage Range allant de la cellule C1 à la cellule C1, donc la plage ne contiendra que la cellule C1, ainsi autant écrire

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

.cells(1,3)

Pour ce qui est du dictionnaire, par défaut il a un mode de comparaison binaire, il prend en compte la valeur ascii des caractères, donc "A" est différent de "a" dans ce mode de comparaison. Mais il est possible de passer en comparaison de type texte ou "A" = "a". Dans ce dernier cas, il ne tient plus compte de la case pour regarder si la valeur est déjà dans sa liste.

ça donne ça
LFTS

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Dim LFTS As Dictionary
 
Set LFTS = CreateObject("Scripting.Dictionary")
'On rend le dictionnaire insenssible à la case (plus besoin ds UCase()
LFTS.CompareMode = TextCompare
 
'[...] Suite du code
 
If (.Cells(X, 3).Value = "FTS") Or (.Cells(X, 3).Value = "FTA") Then
    If Not LFTS.Exists(.Cells(X, 4).Value) And (Cel.Value <> "") Then LFTS.Add .Cells(X, 4).Value, .Cells(X, 4).Value

++
Qwaz

[Menhir]

Cette ligne de code indique que c'est sur le sheet "A"

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

With Sheets("A") ' Prend les informations dans le feuille A

Cependant cela ne fonctionne pas.

Encore faut-il penser à mettre un "." devant les Range concernés...

Pas sûr aussi que With fonctionne avec un Evaluate (les références entre crochets).
Il faudrait tester.

[Qwazerty]

Salut

J'en avais laissé passer des bouts...

Il faut aussi préciser le classeur sur lequel tu travailles, sinon, si le classeur actif change en cours de route (un clique utilisateur sur un autre classeur) ta macro va continuer à dérouler et prendre en compte ce nouveau classeur lors de la prise en compte du prochain Sheets("A")...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Dim LFTS As Dictionary
Dim Cel As Range
Set LFTS = CreateObject("Scripting.Dictionary")
'On rend le dictionnaire insenssible à la case (plus besoin ds UCase()
LFTS.CompareMode = TextCompare
 
'on tient copte du classeur sur lequel on travail en plus de la feuille
'Ici ThisWorkbook est adapté car il représente le classeur où est contenu le code qui s'execute
With ThisWorkbook.Sheets("A")
    For Each Cel In .Range("C2", .Cells(.Rows.Count, "A").End(xlUp).Row)
        If (.Cells(X, 3).Value = "FTS") Or (.Cells(X, 3).Value = "FTA") Then
            If Not LFTS.Exists(.Cells(X, 4).Value) And (Cel.Value <> "") Then LFTS.Add .Cells(X, 4).Value, .Cells(X, 4).Value
        End Sub
    Next
End With

[Passepartout007]

Bonjour à tous,

Que dire sinon WOOAAWW, j'ai compris mon erreur et vous remercie de votre aide à tous. Il est sur que je ne la referais plus .

Merci de m'avoir également aidez à s'simplifier mon code.
Je marque le sujet comme résolu.
Cordialement,
Passepartout

[Menhir]

Quelques petites corrections dans le code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Dim LFTS As Dictionary
Dim Cel As Range
Set LFTS = CreateObject("Scripting.Dictionary")
'On rend le dictionnaire insenssible à la case (plus besoin ds UCase()
LFTS.CompareMode = TextCompare
 
'on tient copte du classeur sur lequel on travail en plus de la feuille
'Ici ThisWorkbook est adapté car il représente le classeur où est contenu le code qui s'execute
With ThisWorkbook.Sheets("A")
    For Each Cel In .Range("C2", .Cells(.Rows.Count, "C").End(xlUp))
        If Cel.Value = "FTS" Or Cel.Value = "FTA" Then
            If Not LFTS.Exists(Cel.Offset(0, 1).Value) Then LFTS.Add UCase(Cel.Offset(0, 1).Value), UCase(Cel.Offset(0, 1).Value)
        End If
    Next Cel
End With

[Qwazerty]

Merci Menhir, j'avais oublié de reprendre l'intérieur de la boucle