Discussion :

[unparia]

Je dépose le présent snipet à la suite d'une discussion très récente relative à la saisie (contrôlée en cours de saisie) d'une heure dans une textbox.
Ce snipet :
- impose une saisie sous la forme hh:mm
- gère le séparateur ":" en cours de saisie
- traite l'ensemble dans un seul évènement (l'évènement Change de la Textbox)
- utilise une variable statique plutôt que la propriété Tag de la Textbox, de sorte à éviter de priver le développeur de la disponibilité totale de la propriété Tag, qu'il peut donc utiliser à son gré à d'autres fins de son choix.

Dans un module standard :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Public Function sais_heure(T As MSForms.TextBox, w) As String
   '--merci de laisser ces 2 lignes de commentaires si vous utilisez ce mécanisme--
   '-- l'auteur de cette fonction est Jacques Marquès------------------------------
   Dim z As String, kk As String
   kk = IIf(Len(w) = 3, Left(w, 1), "")
   sais_heure = T.Text
   If Len(sais_heure) = 2 Then sais_heure = IIf(kk = "", sais_heure & ":", kk)
   z = sais_heure & Mid("00:00", Len(sais_heure) + 1)
   If Not z Like "##:##" Or Not IsDate(z) Then sais_heure = w: Exit Function
   w = sais_heure
End Function

et dans l'évènement de la textbox concernée

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Private Sub TextBox1_Change()
  Static a0 As String
  TextBox1.Text = sais_heure(TextBox1, a0)
End Sub

Etant entendu que l'on peut ainsi appliquer ce code à plusieurs textboxes, qu'elles soient placées sur une feuille de calcul ou sur un Userform.

[patricktoulon]

re
a oui respect il fonctionne a merveille

et si je te dis que j'ai mieux tu me crois ou pas
dans l'autre discussion avec ma variable forme"00:00" je cherchais a pouvoir mette le ":" automatique mais ca me supprimais la possibilité de me servir de la touche back
et j'ai trouvé
moins de code , seulement 2 variable utilisée
tu aura le merite de me faire reflechir autrement meme si c'est pas comme toi
tu veux voir ?
je l'ai meme simplifié en ne gardant de ton model que "Like "##:##" qui rend finalement impossible de taper autre chose que XX:XX

[pijaku]

Bonjour Jacques,

Je me suis permis une minuscule modification de ton code, pour pouvoir accepter la saisie d'heures au format "HH:MM:SS".

Qu'en penses-tu?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Private Sub TBoxHeur_Change()
'https://www.developpez.net/forums/d1861701/logiciels/microsoft-office/excel/contribuez/snipet-saisie-controlee-d-heures-textboxes/
  Static a0 As String
  TBoxHeur.Text = Saisie_heure(TBoxHeur, a0, "##:##:##")
  'ou bien :
  'TBoxHeur.Text = Saisie_heure(TBoxHeur, a0, "##:##")
End Sub
Private Function Saisie_heure(t As MSForms.TextBox, w As String, Optional mFormat As String = "##:##") As String
   '--merci de laisser ces 2 lignes de commentaires si vous utilisez ce mécanisme--
   '-- l'auteur de cette fonction est Jacques Marquès------------------------------
Dim Z As String, kk As String
   If Len(w) Mod 3 = 0 And w <> "" Then kk = Left(w, Len(w) - 2)
   Saisie_heure = t.Text
   If Len(Saisie_heure) = 2 Or Len(Saisie_heure) = 5 Then Saisie_heure = IIf(kk = "", Saisie_heure & ":", kk)
   Z = Saisie_heure & Mid(Replace(mFormat, "#", "0"), Len(Saisie_heure) + 1)
   If Not Z Like mFormat Or Not IsDate(Z) Then
      Saisie_heure = w
   Else
      w = Saisie_heure
   End If
End Function

[unparia]

Bonjour, Franck

Je n'avais pas voulu aller jusqu'aux secondes car les occasions de saisies de l'espèce (dans quelles ultra-rares circonstances avoir à saisir des secondes ) me paraissent assez drôles.
Y compris s'il s'agit de déterminer le départ d'une action (car le temps de la saisie, déjà, rend la chose assez bizarre ...)

Je plussoie toutefois ton code pour l''exercice

Amitiés