Discussion :

[MicKRub]

Bonjour,

Je cherche désespéramment à optimiser mon code.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
 
Mois = Format(MaDate.Value, "mmmm")
Set rangemois = Worksheets("2018").Rows("1:1").Find(Mois, lookat:=xlValue)
jour = Val(Format(MaDate, "dd"))
NomAmbulancier = Worksheets("2018").Range("AA25:AA183").Find(ChoixAmbu.Value, lookat:=xlValue).Row
Set plagejour = Worksheets("2018").Range(Replace(rangemois.MergeArea.Address, rangemois.MergeArea.Row, 2))
Colonnedujour = plagejour.Find(jour, lookat:=xlValue).Column
 
VarTmp = Cells(NomAmbulancier, Colonnedujour).Offset(1, 0).Text
 
If VarTmp = "" Then
    'La cellule heures supp. de la date sélectionnée est vide.
    'Alors copier le résultat du calcul et ajouter commentaire.
    Cells(NomAmbulancier, Colonnedujour).Offset(1, 0) = CopieCalcul
    Cells(NomAmbulancier, Colonnedujour).Offset(1, 0).AddComment AddCommentaire
    Cells(NomAmbulancier, Colonnedujour).Offset(1, 0).Comment.Shape.TextFrame.AutoSize = True
Else
    'La cellule heures supp. de la date sélectionnée n'est pas vide.
    'Alors additionner la valeur actuel avec le résultat du calcul et ajouter commentaire.
    CalculTmp = TimeValue(Cells(NomAmbulancier, Colonnedujour).Offset(1, 0).Text)
    ResultatTmp = CalculTmp + CopieCalcul
 
    ComCellule = Cells(NomAmbulancier, Colonnedujour).Offset(1, 0).Comment.Text
    AddCommentaire2 = ("Heures supp. du matin" & Chr(10) & ComCellule & Chr(10) & Chr(10) & "Heures supp. du soir" & Chr(10) & AddCommentaire)
 
    Cells(NomAmbulancier, Colonnedujour).Offset(1, 0).ClearContents
    Cells(NomAmbulancier, Colonnedujour).Offset(1, 0).ClearComments
    Cells(NomAmbulancier, Colonnedujour).Offset(1, 0) = ResultatTmp
    Cells(NomAmbulancier, Colonnedujour).Offset(1, 0).AddComment AddCommentaire2
    Cells(NomAmbulancier, Colonnedujour).Offset(1, 0).Comment.Shape.TextFrame.AutoSize = True
End If

Est-il possible de créer une variable qui serait égale à Cells(NomAmbulancier, Colonnedujour).Offset(1, 0) afin de d'alléger le code?

Merci à vous.

[Marc-L]

Bonjour,

oui mais pas nécessaire en utilisant un bloc With (à consulter dans l'aide VBA interne) …

___________________________________________________________________________________________________________

Je suis Paris, Mogadicio, Barcelone, London, Manchester, Egypte, Stockholm, Istanbul, Berlin, Nice, Bruxelles, Charlie, …

[Menhir]

Est-il possible de créer une variable qui serait égale à Cells(NomAmbulancier, Colonnedujour).Offset(1, 0) afin de d'alléger le code?

La solution parait si évidente qu'il est étonnant que tu n'y ais pas pensé : si tu fait +1 à ta variable NomAmbulancier sur la ligne 5, tu peux virer tous tes Offset.

Perso, je mettrais même juste après Cells(NomAmbulancier, Colonnedujour) dans une variable de type Range.
Etant donné le nombre d'utilisation que tu en fais, ce ne serait pas du luxe.

[MicKRub]

La solution parait si évidente qu'il est étonnant que tu n'y ais pas pensé : si tu fait +1 à ta variable NomAmbulancier sur la ligne 5, tu peux virer tous tes Offset.

Perso, je mettrais même juste après Cells(NomAmbulancier, Colonnedujour) dans une variable de type Range.
Etant donné le nombre d'utilisation que tu en fais, ce ne serait pas du luxe.

Merci pour l'astuce du +1. Je ne pensais pas que cela était possible si simplement.

Par contre j'ai créé une variable comme ceci,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
 
 
Dim CelluleDestination As Range
 
Mois = Format(MaDate.Value, "mmmm")
Set rangemois = Worksheets("2018").Rows("1:1").Find(Mois, lookat:=xlValue)
jour = Val(Format(MaDate, "dd"))
NomAmbulancier = Worksheets("2018").Range("AA25:AA183").Find(ChoixAmbu.Value, lookat:=xlValue).Row + 1
Set plagejour = Worksheets("2018").Range(Replace(rangemois.MergeArea.Address, rangemois.MergeArea.Row, 2))
Colonnedujour = plagejour.Find(jour, lookat:=xlValue).Column
 
CelluleDestination = Cells(NomAmbulancier, Colonnedujour)
 
CelluleDestination = CopieCalcul
CelluleDestination.AddComment AddCommentaire
CelluleDestination.Comment.Shape.TextFrame.AutoSize = True

Mais cela ne fonctionne pas. Il y a sans doute quelques chose de faux mais je ne vois pas... (oui je débute)

Merci beaucoup

[patricktoulon]

salut
tu a fini quand même par comprendre mon principe pour ton find par rapport a une plage fusionnée

bon pour le reste

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Mois = Format(MaDate.Value, "mmmm")
Set rangemois = Worksheets("2018").Rows("1:1").Find(Mois, lookat:=xlValue)
jour = Val(Format(MaDate, "dd"))
NomAmbulancier = Worksheets("2018").Range("AA25:AA183").Find(ChoixAmbu.Value, lookat:=xlValue).Row
Set plagejour = Worksheets("2018").Range(Replace(rangemois.MergeArea.Address, rangemois.MergeArea.Row, 2))
Colonnedujour = plagejour.Find(jour, lookat:=xlValue).Column
Set macel = Cells(NomAmbulancier, Colonnedujour).Offset(1, 0)
With macel
    If .Text = "" Then
        'La cellule heures supp. de la date sélectionnée est vide.
        'Alors copier le résultat du calcul et ajouter commentaire.
        .Value = CopieCalcul
        .AddComment AddCommentaire
        .Comment.Shape.TextFrame.AutoSize = True
    Else
        'La cellule heures supp. de la date sélectionnée n'est pas vide.
        'Alors additionner la valeur actuel avec le résultat du calcul et ajouter commentaire.
        CalculTmp = TimeValue(.Text)
        ResultatTmp = CalculTmp + CopieCalcul
        ComCellule = .Comment.Text
        AddCommentaire2 = ("Heures supp. du matin" & Chr(10) & ComCellule & Chr(10) & Chr(10) & "Heures supp. du soir" & Chr(10) & AddCommentaire)
        .ClearContents
        .ClearComments
        .Value = ResultatTmp
        .AddComment AddCommentaire2
        .Comment.Shape.TextFrame.AutoSize = True
    End If
End With

[MicKRub]

Oui j'ai pris mon temps mais j'y suis arrivé.

Merci pour le code.

Salutations

[Menhir]

Mais cela ne fonctionne pas. Il y a sans doute quelques chose de faux mais je ne vois pas... (oui je débute)

Pour assigner un objet à une variable, on soit utiliser un Set.
https://msdn.microsoft.com/fr-fr/VBA.../set-statement

[MicKRub]

Merci à tous pour vos aides