Userform textbox objet

**manufer** · 12/08/2017, 22h08

Bonjour à tous,

Voilà je cherche à générer un objet "textbox" automatiquement après avoir cliqué sur un bouton,

et cela doit se faire à l'infini sans limite.

J'ai bien trouver un tuto sur ce site:

http://silkyroad.developpez.com/VBA/VisualBasicEditor/

mais il me fait passer par un module de classe,

Alors que moi je souhaite que mon code soit contenu dans l'userform voir dans dans un module standard.

Avez-vous une idée svp ?

**unparia** · 12/08/2017, 23h45

Bonjour

Alors que moi je souhaite que mon code soit contenu dans l'userform voir dans dans un module standard

Tu peux toujours ajouter dynamiquement un contrôle activex.
En utiliser les évènements ne sera par contre pas possible comme tu l'entends (sans module de classe).

**patricktoulon** · 13/08/2017, 00h46

bonsoir
ou alors ajouter ton textbox et écrire dynamiquement le code de son évènement mais c'est un truc de fou si ca doit se répéter indéfiniment donc module classe

apres tu peut ecrire le code de ta classe en commentaire dans le code de ton userform et le réimplanter dans un module classe dynamiquement

j'avais fait cela pour un demandeur il y a pas mal de temps mais on devrait pouvoir retrouver la discussions
l'intérêt de cette méthode et d'avoir un module userform transportable

**manufer** · 16/08/2017, 12h04

J'ai trouvé un petit bout de code sur ce lien:

http://silkyroad.developpez.com/VBA/UserForm/#LIV-H

Qu'en pensez-vous ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Private Sub CommandButton1_Click()
    Dim Obj As Control
 
    Set Obj = Me.Controls.Add("forms.Textbox.1")
    With Obj
        .Name = "monTextBox"
        .Left = 140
        .Top = 30
        .Width = 50
        .Height = 20
    End With
 
    MsgBox Obj.Name & " ajouté dans l'UserForm."
End Sub

Cela ne résout pas tout le problème mais il permet d'avancer un peu non ?

Problème, j'ai l'impression qu'il crée les textbox les uns sur les autres et non au dessous dans ma combobox,

Donc à chaque fois qu'un textbox est crée, il cache le précedent.

Avez-vous une piste pour remédier à ça ?

**unparia** · 16/08/2017, 12h39

Donc à chaque fois qu'un textbox est crée, il cache le précedent.

Et tu t'en étonnes ? Vraiment ?
Rien d'étonnant puisque tu donnes les mêmes propriétés de positionnement (140, 30, 50,20) à chacun d'eux ! Ils se trouvent tous au même endroit et avec les mêmes dimensions.

Une piste pour y remédier ? --->> un compteur de positionnement, soit vertical, soit horizontal, selon ce que tu cherches à faire.

Cela ne résout pas tout le problème mais il permet d'avancer un peu non ?

Pas vraiment. Tu te retrouves avec des textboxes sans vraiment pouvoir les utiliser totalement.

**Pierre Fauconnier** · 21/08/2017, 16h10

Bonjour Franck,

Pas testé, mais aucun doute...

(Ca me semble tout de même plus simple et plus propre que ce qui avait été proposé par ailleurs...)

Merci pour le demandeur initial.

**Theze** · 16/08/2017, 12h57

Bonjour,

Voici une piste avec un module de classe pour la gestion des évènements (ici, pour l'exemple, un seul, l'évènement "Change()" ).

Le code ci-dessous est à mettre dans le module du formulaire et les variables doivent être en tête de module :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
 
Dim Txt() As New Classe1
Dim Haut As Long
Dim I As Long
 
Private Sub CommandButton1_Click()
 
    Dim Obj As Control
    Dim MargeH As Integer
    Dim MargeG As Integer
    Dim H As Integer
    Dim L As Integer
    Dim Larg As Integer
 
    MargeH = 10 'espace entre contrôles
    MargeG = ComboBox1.Left 'idem ComboBox
 
    H = ComboBox1.Height 'idem ComboBox
    L = ComboBox1.Width 'idem ComboBox
 
    'si pas encore initialisé
    If Haut = 0 Then Haut = ComboBox1.Top
 
    'céation du contrôle ActiveX
    Set Obj = Me.Controls.Add("forms.Textbox.1")
 
    'calcul du top
    Haut = Haut + H + MargeH
 
    'positionnement
    With Obj
 
        .Left = MargeG
        .Top = Haut
        .Width = L
        .Height = H
 
    End With
 
    'ajout dans le tableau pour la gestion des évènements
    I = I + 1
    ReDim Preserve Txt(1 To I)
    Set Txt(I).GroupeTxt = Obj
 
    'ajout de la barre verticale sur la Form
    Me.ScrollBars = fmScrollBarsVertical
    Me.ScrollHeight = Haut
 
End Sub

et celui-ci est à mettre dans un module de classe nommé Classe1 (nom par défaut !) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
 
Public WithEvents GroupeTxt As MSForms.TextBox
 
Private Sub GroupeTxt_Change()
 
    'ici, créer le code nécessaire pour ton utilisation...
 
    'pour le test...
    MsgBox "Le TextBox porte le nom '" & GroupeTxt.Name & "' et sa valeur est : " & GroupeTxt.Text
 
End Sub

Les TextBox que tu va créer dynamiquement vont se positionner les uns sous les autres et alignés à ton ComboBox nommé "ComboBox1" (adapter dans le code si différent !) et de même taille.
Pour l'évènement "Change()" et pour le test, quand tu vas entrer une valeur dans un des TextBox, une boite de message va apparaître et te donner le nom du TextBox et le texte qu'il contient

**manufer** · 16/08/2017, 17h53

Merci pour cette réponse mais je me rend compte que je ne peux pas utiliser de combobox,

Je voulais tout faire à l'intérieur mais c'est assez compliqué et inaproprié.

je voudrai créer 5 textbox de même taille les uns à coté des autre dans un frame

et au click d'un CommandButton1 cinq nouveau textbox se crée juste en dessous avec les mêmes dimensions que ceux du dessus.

Cela créerai plusierus étages de textbox à chaque click et je positionnerai le CommandButton1 au niveau de l'étage le plus bas.

vous avez des pistes svp pour ce truc assez complexe je pense ?

**Pierre Fauconnier** · 21/08/2017, 14h20

Salut.

Pourriez-vous rédiger une synthèse propre, bien codée et utilisable par le demandeur? Pour compléter la remarque de Jacques sur le bien et le mieux, je pense qu'il est utile que le demandeur puisse s'y retrouver à un moment donné. Libre à vous, par la suite, de développer vos solutions sur le forum Contribuez, voire en demandant l'ouverture d'un projet.

.

Mais honnêtement, sans synthèse, je ne vois pas bien ce que le demandeur va pouvoir faire de tout ceci, vu le niveau qu'il a lui-même annoncé...

**pijaku** · 21/08/2017, 16h07

Bonjour,

Voici un exemple, vite codé, tout simple d'utilisation.

1 Userform comportant :
> 5 textbox (TextBox1, TextBox2, ..., TextBox5)
> 1 CommandButton1 (caption : OK)
> 1 ListBox1 (régler la propriété Width à 345)
placés comme ceci :
Nom : userform.png
Affichages : 238
Taille : 7,5 Ko

Nom : userform.png
Affichages : 238
Taille : 7,5 Ko

Le code de l'UserForm :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
Option Explicit
 
Private EnableEvents As Boolean
 
Private Sub CommandButton1_Click()
Dim i As Byte, rep As Integer
    rep = vbNo
    If ListBox1.ListIndex <> -1 Then rep = MsgBox("Voulez-vous modifier la ligne sélectionnée?", vbYesNo + vbQuestion)
    If rep = vbNo Then
        ListBox1.AddItem TextBox1
        For i = 1 To 4
            ListBox1.List(ListBox1.ListCount - 1, i) = Me.Controls("TextBox" & i + 1)
            Me.Controls("TextBox" & i) = ""
        Next
        TextBox5 = ""
        TextBox1.SetFocus
    Else
        EnableEvents = True
        For i = 0 To 4
            ListBox1.List(ListBox1.ListIndex, i) = Me.Controls("TextBox" & i + 1)
            Me.Controls("TextBox" & i + 1) = ""
        Next
        TextBox5 = ""
        TextBox1.SetFocus
        EnableEvents = False
        ListBox1.ListIndex = -1
    End If
End Sub
 
Private Sub ListBox1_Click()
Dim i As Byte
 
    If ListBox1.ListIndex = -1 Or EnableEvents Then Exit Sub
    For i = 0 To 4
        Me.Controls("TextBox" & i + 1) = ListBox1.List(ListBox1.ListIndex, i)
    Next
End Sub
 
Private Sub ListBox1_DblClick(ByVal Cancel As MSForms.ReturnBoolean)
Dim rep As Integer
    If ListBox1.ListIndex = -1 Then Exit Sub
    rep = MsgBox("Voulez-vous supprimer la ligne sélectionnée?", vbYesNo + vbQuestion)
    If rep = vbYes Then
        ListBox1.RemoveItem (ListBox1.ListIndex)
    End If
End Sub
 
Private Sub TextBox5_Exit(ByVal Cancel As MSForms.ReturnBoolean)
    CommandButton1.SetFocus
End Sub
 
Private Sub UserForm_Activate()
Dim i&, ArrCol
    TextBox1.SetFocus
    ListBox1.ColumnCount = 5
    ListBox1.ColumnWidths = "50;50;120;40;80"
    ArrCol = Array(0, 50, 100, 220, 260)
    For i = 1 To 5
        Me.Controls("TextBox" & i).Width = Split(Replace(ListBox1.ColumnWidths, " pt", ""), ";")(i - 1)
        Me.Controls("TextBox" & i).Left = ArrCol(i - 1) + ListBox1.Left
    Next i
    ListBox1.Width = 345
    CommandButton1.Move TextBox5.Left + TextBox5.Width, TextBox5.Top
End Sub

EDIT :
On remplit les textbox,
Un clic sur le bouton :
>> si aucune ligne de la listbox n'est sélectionnée ==> ajoute une ligne et la remplit des infos contenues dans les textbox
>> si une ligne est sélectionnée ==> demande si l'utilisateur veux modifier cette ligne
===>>>> si oui : modifie la ligne et la déselectionne
===>>>> si non : ajoute une nouvelle ligne
>> Vide les textbox
>> place le focus sur le textbox1
Un clic sur la listbox ==> remplit les textbox des infos contenues dans cette ligne
Voilà...

EDIT 2 : un double clic sur une ligne de la listbox supprime cette ligne

Invité · 17/08/2017, 08h03

Bonjour

Envoyé par manufer

Voilà je cherche à générer un objet "textbox" automatiquement après avoir cliqué sur un bouton,

et cela doit se faire à l'infini sans limite.

A un moment tu vas quand même être limité par la taille de ton UserForm, je ne vois pas l'intérêt de ta démarche.

Philippe

**Theze** · 17/08/2017, 08h18

Bonjour Philippe,

Avec la ScrollBar verticale il aura accès à tous les TextBox (testé sur 100 lignes donc 500 TextBox) mais selon le nombre la gestion va être super coton !!!

**manufer** · 17/08/2017, 09h45

Salut Theze,

J'essaie ça tout de suite Merci beaucoup.

Salut Philippe,

Je pense que je vais largement dépasser le millier et cela me permet de ne pas avoir de limite définit.

Invité · 17/08/2017, 10h03

Re

Envoyé par manufer

Salut Philippe,

Je pense que je vais largement dépasser le millier et cela me permet de ne pas avoir de limite définit.

Je pense que tu devrais revoir ta stratégie et expliquer pourquoi tu veux faire cela, car avec ce nombre de contrôle et suivant ce que tu veux en faire cela risque de ramer sérieusement.

Philippe