Userform textbox objet

**unparia** · 20/08/2017, 23h19

Bonjour à tous
Je vais commencer par une citation ***** --->>
http://dicocitations.lemonde.fr/cita...tion-27609.php

Venons-en maintenant au sujet : Franck sait très bien qu'une listbox éditable est parfaitement réalisable (en édition directement sur les éléments de la listbox)

Mais il ne s'agit-là que d'un exercice (il a été conduit à son terme) , certes amusant, mais sans autre intérêt réel, sauf celui ... d'alourdir ...

En remettant les pieds sur terre, on aboutit à du bien plus simple et léger :
- une textbox placée en dessous de la listbox
- au clic sur l'un des éléments de la listbox -->> le texte de cet élément est copié sur la textbox
- au change de la textbox, l'élément de la listbox prend la valeur modifiée dans la textbox
Tout cela est extrêmement facile à mettre en oeuvre et plus que largement suffisant et efficace.

EDIT explicatif du *****
Le "mieux", c'est pour le développeur
Le "bien", c'est pour l'utilisateur
Lorsque le "mieux" du développeur nécessite un manuel d'emploi, le "bien" de l'utilisateur devient une "croix" et un motif d'irritation.
La convivialité et l'intuitivité sont les maîtres-mots d'une application réussie.
L'utilisateur qui veut modifier un élément cliquera instinctivement sur cet élément. En voyant apparaître une textbox avec le texte de cet élément, il lui viendra instinctivement et très naturellement à l'idée qu'elle est là pour lui permettre de modifier. S'il hésite, il tentera et ... verra que oui.
Voilà voilà ...

**Theze** · 21/08/2017, 14h04

Bonjour,

EDIT explicatif du *****
Le "mieux", c'est pour le développeur
Le "bien", c'est pour l'utilisateur
Lorsque le "mieux" du développeur nécessite un manuel d'emploi, le "bien" de l'utilisateur devient une "croix" et un motif d'irritation.
La convivialité et l'intuitivité sont les maîtres-mots d'une application réussie.
L'utilisateur qui veut modifier un élément cliquera instinctivement sur cet élément. En voyant apparaître une textbox avec le texte de cet élément, il lui viendra instinctivement et très naturellement à l'idée qu'elle est là pour lui permettre de modifier. S'il hésite, il tentera et ... verra que oui.
Voilà voilà ...

Et comme dit l'adage, le mieux est l'ennemi du bien !

**Pierre Fauconnier** · 21/08/2017, 14h20

Salut.

Pourriez-vous rédiger une synthèse propre, bien codée et utilisable par le demandeur? Pour compléter la remarque de Jacques sur le bien et le mieux, je pense qu'il est utile que le demandeur puisse s'y retrouver à un moment donné. Libre à vous, par la suite, de développer vos solutions sur le forum Contribuez, voire en demandant l'ouverture d'un projet.

.

Mais honnêtement, sans synthèse, je ne vois pas bien ce que le demandeur va pouvoir faire de tout ceci, vu le niveau qu'il a lui-même annoncé...

**pijaku** · 21/08/2017, 16h07

Bonjour,

Voici un exemple, vite codé, tout simple d'utilisation.

1 Userform comportant :
> 5 textbox (TextBox1, TextBox2, ..., TextBox5)
> 1 CommandButton1 (caption : OK)
> 1 ListBox1 (régler la propriété Width à 345)
placés comme ceci :
Nom : userform.png
Affichages : 209
Taille : 7,5 Ko

Nom : userform.png
Affichages : 209
Taille : 7,5 Ko

Le code de l'UserForm :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
Option Explicit
 
Private EnableEvents As Boolean
 
Private Sub CommandButton1_Click()
Dim i As Byte, rep As Integer
    rep = vbNo
    If ListBox1.ListIndex <> -1 Then rep = MsgBox("Voulez-vous modifier la ligne sélectionnée?", vbYesNo + vbQuestion)
    If rep = vbNo Then
        ListBox1.AddItem TextBox1
        For i = 1 To 4
            ListBox1.List(ListBox1.ListCount - 1, i) = Me.Controls("TextBox" & i + 1)
            Me.Controls("TextBox" & i) = ""
        Next
        TextBox5 = ""
        TextBox1.SetFocus
    Else
        EnableEvents = True
        For i = 0 To 4
            ListBox1.List(ListBox1.ListIndex, i) = Me.Controls("TextBox" & i + 1)
            Me.Controls("TextBox" & i + 1) = ""
        Next
        TextBox5 = ""
        TextBox1.SetFocus
        EnableEvents = False
        ListBox1.ListIndex = -1
    End If
End Sub
 
Private Sub ListBox1_Click()
Dim i As Byte
 
    If ListBox1.ListIndex = -1 Or EnableEvents Then Exit Sub
    For i = 0 To 4
        Me.Controls("TextBox" & i + 1) = ListBox1.List(ListBox1.ListIndex, i)
    Next
End Sub
 
Private Sub ListBox1_DblClick(ByVal Cancel As MSForms.ReturnBoolean)
Dim rep As Integer
    If ListBox1.ListIndex = -1 Then Exit Sub
    rep = MsgBox("Voulez-vous supprimer la ligne sélectionnée?", vbYesNo + vbQuestion)
    If rep = vbYes Then
        ListBox1.RemoveItem (ListBox1.ListIndex)
    End If
End Sub
 
Private Sub TextBox5_Exit(ByVal Cancel As MSForms.ReturnBoolean)
    CommandButton1.SetFocus
End Sub
 
Private Sub UserForm_Activate()
Dim i&, ArrCol
    TextBox1.SetFocus
    ListBox1.ColumnCount = 5
    ListBox1.ColumnWidths = "50;50;120;40;80"
    ArrCol = Array(0, 50, 100, 220, 260)
    For i = 1 To 5
        Me.Controls("TextBox" & i).Width = Split(Replace(ListBox1.ColumnWidths, " pt", ""), ";")(i - 1)
        Me.Controls("TextBox" & i).Left = ArrCol(i - 1) + ListBox1.Left
    Next i
    ListBox1.Width = 345
    CommandButton1.Move TextBox5.Left + TextBox5.Width, TextBox5.Top
End Sub

EDIT :
On remplit les textbox,
Un clic sur le bouton :
>> si aucune ligne de la listbox n'est sélectionnée ==> ajoute une ligne et la remplit des infos contenues dans les textbox
>> si une ligne est sélectionnée ==> demande si l'utilisateur veux modifier cette ligne
===>>>> si oui : modifie la ligne et la déselectionne
===>>>> si non : ajoute une nouvelle ligne
>> Vide les textbox
>> place le focus sur le textbox1
Un clic sur la listbox ==> remplit les textbox des infos contenues dans cette ligne
Voilà...

EDIT 2 : un double clic sur une ligne de la listbox supprime cette ligne

**Pierre Fauconnier** · 21/08/2017, 16h10

Bonjour Franck,

Pas testé, mais aucun doute...

(Ca me semble tout de même plus simple et plus propre que ce qui avait été proposé par ailleurs...)

Merci pour le demandeur initial.

**pijaku** · 21/08/2017, 16h26

Bonjour Pierre,

J'ai édité mon message pour :
1- ajouter le vidage des textbox dans le CommandButton1_Click
2- ajouter un petit texte de présentation...

Merci à toi.

**manufer** · 21/08/2017, 17h40

Merci à tous et pour tout,

C'est vrai qu'avec une synthèse c'est bien plus clair.

mais effectivement vous m'avez donné un bon aperçu de ce qu'il est possible de faire avec des listbox, textbox et autre.

Merci à tous.

**pijaku** · 22/08/2017, 12h33

Bonjour,

Pour le plaisir, je me suis amusé avec une unique ComboBox.
Le résultat est moins bon qu'avec 5 TextBox et une ListBox, mais je vous le livre tout de même, pour le fun

Un UserForm avec dessus un ComboBox (ComboBox1) assez large (environ 300 points).

Le code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
Option Explicit
 
Private ColLeft() As Double
Private Ligne As Long
Private LigneEnCours As Long
Private Colonne As Byte
Private Enable_Events As Boolean
 
'*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*
Private Const COLUMN_WIDTH As String = "50 pt;50 pt; 100 pt; 50 pt; 35 pt" 'A ADAPTER
Private Const NB_LIGNES_DISPLAYED As Byte = 8                              'A ADAPTER
Private Const NB_COLONNES As Byte = 5                                      'A ADAPTER
'*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*
 
Private Sub ComboBox1_Click()
    LigneEnCours = ComboBox1.ListIndex
    If Enable_Events = False Then SendKeys "%{Down}"
End Sub
 
Private Sub ComboBox1_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
    Enable_Events = True
        With ComboBox1
            If KeyCode = 9 Then
                Colonne = Colonne + 1
                If Colonne > NB_COLONNES - 1 Then
                    Colonne = 0
                    .Text = ""
                    Ligne = Ligne + 1
                    If Ligne >= NB_LIGNES_DISPLAYED Then .AddItem
                End If
            End If
            .List(Ligne, Colonne) = .List(Ligne, Colonne) & Chr(KeyCode)
        End With
    Enable_Events = False
End Sub
 
Private Sub ComboBox1_MouseDown(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single)
Dim i As Long, rep As Integer
 
    If Button = 1 Then      'clic gauche
        For i = UBound(ColLeft) To LBound(ColLeft) Step -1
            If X >= ColLeft(i) Then
                ComboBox1.TextColumn = i + 1
                Exit For
            End If
        Next
        ComboBox1.SetFocus
        SendKeys "%{Down}"
    ElseIf Button = 2 Then  'clic droit
        rep = MsgBox("Voulez-vous supprimer cet Item?", vbYesNo + vbQuestion)
        If rep = vbYes Then ComboBox1.RemoveItem (LigneEnCours)
    End If
End Sub
 
Private Sub UserForm_Activate()
Dim i As Long, Temp
 
    Enable_Events = True
        With ComboBox1
            For i = 1 To NB_LIGNES_DISPLAYED: .AddItem: Next i
            .ColumnCount = NB_COLONNES
            .ColumnWidths = COLUMN_WIDTH
            Temp = Split(Replace(COLUMN_WIDTH, " pt", ""), ";")
            ReDim Preserve ColLeft(UBound(Temp))
            ColLeft(0) = 0
            For i = 1 To UBound(Temp)
                ColLeft(i) = ColLeft(i - 1) + Temp(i - 1)
            Next i
            .DropDown
            .ListRows = NB_LIGNES_DISPLAYED
        End With
    Enable_Events = False
End Sub

La ComboBox se remplit au fur et à mesure des saisies.
La touche TAB permet de passer d'une colonne à la suivante.
Lorsque l'on arrive au bout de la ligne, cette même touche TAB fait aller à la ligne suivante.
Un clic gauche sélectionne l'item choisi (ligne ET colonne).
Un clic droit supprime la ligne.

C'est très incomplet, il convient de travailler davantage le KeyDown et aussi de permettre de modifier.
Mais bon, comme le résultat n'est pas tip top, je le laisse en l'état...

**pijaku** · 22/08/2017, 14h25

Re-Bonjour,

Envoyé par unparia

En remettant les pieds sur terre, on aboutit à du bien plus simple et léger :
- une textbox placée en dessous de la listbox
- au clic sur l'un des éléments de la listbox -->> le texte de cet élément est copié sur la textbox
- au change de la textbox, l'élément de la listbox prend la valeur modifiée dans la textbox
Tout cela est extrêmement facile à mettre en oeuvre et plus que largement suffisant et efficace.

Jacques,
J'ai repris ton idée et fais du "un peu plus lourd que prévu", mais j'ai souhaité que :
> le nombre de colonnes soit dynamique
> toutes les infos d'une même ligne puissent être modifiées ensembles.

Mais nous voici maintenant avec un autre exemple de ListBox "modifiable".

Attention : 3 modules sont nécessaires.
1- Module de classe nommé ClasseTB :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Option Explicit
 
Public WithEvents TBox As MSForms.TextBox
 
Private Sub TBox_Change()
Dim Col&
 
    Col = Val(Split(TBox.Name, SEP)(1)) - 1
    Enable_Events = True
    maListe.List(maListe.ListIndex, Col) = TBox
    Enable_Events = False
End Sub

2- Un module standard Module1 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Option Explicit
 
Public maListe As MSForms.ListBox
Public MesTB() As ClasseTB
Public Enable_Events As Boolean
 
Public Const SEP As String = "¤"

3- le module de l'UserForm
Un Userform, avec juste dedans une listbox nommée ListBox1...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
Option Explicit
 
Private H As Double
Private H_Liste As Double
Private ListIndexEnCours As Long
Private Feuille As Worksheet
Private Rng As Range
 
Private Const NOM_TEXTBOX As String = "newTB"
 
Private Sub ListBox1_Click()
Dim i As Long
    If Enable_Events Then Exit Sub
    For i = 0 To ListBox1.ColumnCount - 1
        Me.Controls(NOM_TEXTBOX & SEP & i + 1).Text = ListBox1.List(ListBox1.ListIndex, i)
    Next i
End Sub
 
Private Sub ListBox1_DblClick(ByVal Cancel As MSForms.ReturnBoolean)
Dim rep As Integer
    rep = MsgBox("Voulez-vous supprimer cette ligne?", vbYesNo + vbQuestion)
    If ListBox1.ListIndex > -1 Then
        If rep = vbYes Then maListe.RemoveItem (ListBox1.ListIndex)
        ListBox1.ListIndex = -1
        ListBox1.Height = H_Liste
        ListIndexEnCours = ListBox1.ListIndex
    End If
End Sub
 
Private Sub ListBox1_MouseUp(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single)
    If Button = 1 Then
        If ListBox1.Height = H_Liste Then ListBox1.Height = ListBox1.Height - H
        If ListBox1.ListIndex = ListIndexEnCours Then
            ListBox1.ListIndex = -1
            ListBox1.Height = H_Liste
            ListIndexEnCours = ListBox1.ListIndex
        Else
            ListIndexEnCours = ListBox1.ListIndex
        End If
    ElseIf Button = 2 Then
        If ListBox1.Height = H_Liste Then ListBox1.Height = ListBox1.Height - H
        ListBox1.AddItem
        Enable_Events = True
        ListBox1.ListIndex = ListBox1.ListCount - 1
        Enable_Events = False
    End If
End Sub
 
Private Sub UserForm_Activate()
    With ListBox1
        .ColumnCount = 7
        .ColumnWidths = "50;50;100;60;80;50;60"
        .RowSource = "Feuil1!A1:G206"
        .Width = 490
    End With
    Add_TextBox Me.ListBox1
End Sub
 
Private Sub Add_TextBox(Liste As MSForms.ListBox)
Dim i As Long, TextB As Control, ColLeft() As Double, L#
 
    Set maListe = Liste
    H_Liste = maListe.Height
    With maListe
        If .RowSource <> "" Then Remove_RowSource
        ReDim ColLeft(.ColumnCount)
        ReDim MesTB(.ColumnCount - 1)
        ColLeft(0) = 0
        For i = 1 To .ColumnCount
            ColLeft(i) = Split(Replace(.ColumnWidths, " pt", ""), ";")(i - 1)
            Set TextB = Me.Controls.Add("forms.TextBox.1", NOM_TEXTBOX & SEP & i, True)
            Set MesTB(i - 1) = New ClasseTB
            Set MesTB(i - 1).TBox = TextB
            L = L + ColLeft(i - 1): H = TextB.Height
            TextB.Move .Left + L, .Top + .Height - TextB.Height, ColLeft(i), H
        Next i
    End With
End Sub
 
Private Sub Remove_RowSource()
Dim Source As String, L As Double
 
    Enable_Events = True
    With maListe
        L = .Width
        If InStr(.RowSource, "!") > 0 Then
            Set Feuille = Worksheets(Split(.RowSource, "!")(0))
            Source = Split(.RowSource, "!")(1)
        Else
            Source = .RowSource
        End If
        .RowSource = ""
        Set Rng = Range(Source)
        .List = Range(Source).Value
        .Width = L
    End With
    Enable_Events = False
End Sub
 
Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
'en cas de rowsource initial : on modifie le Range affecté
    If Not Rng Is Nothing Then
        If Not Feuille Is Nothing Then
            Feuille.Range(Rng.Address).Value = ListBox1.List
        Else
            Rng.Value = ListBox1.List
        End If
    End If
End Sub

Clic gauche ==> fait "apparaître" les textbox remplis
Clic gauche sur le même item ==> fait "disparaître" les textbox + désélectionne la ligne
Changement dans un textbox ==> modifie la listbox en conséquence
Double-clic ==> supprime la ligne
Clic droit ==> ajoutes une ligne

Il doit y avoir pas mal de choses à revoir, mais le début est pas trop mal...

A++
Amicalement,
Franck

**manufer** · 28/08/2017, 09h47

Salut à tous,

Petite question, dans l'userform ci-dessous j'ai donc trois textbox et une listbox de trois colonnes en dessous

Lorsque je click sur "Ajouter les élément de textbox sont transférer dans la listbox,
Nom : Userform.PNG
Affichages : 211
Taille : 7,0 Ko

Nom : Userform.PNG
Affichages : 211
Taille : 7,0 Ko

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Private Sub CommandButton1_Click()
Dim txtb As Controls
If TextBox1 <> "" Or TextBox2 <> "" Or TextBox3 <> "" Then
ListBox1.Visible = True
UserForm1.ListBox1.AddItem (TextBox1 & TextBox2 & TextBox3)
'Frame1.ScrollBars = 2
End If
        TextBox1 = Null
        TextBox2 = Null
        TextBox3 = Null
End Sub

Le code listbox

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Private Sub ListBox1_DblClick(ByVal Cancel As MSForms.ReturnBoolean)
Dim rep As Integer
    If ListBox1.ListIndex = -1 Then Exit Sub
    rep = MsgBox("Voulez-vous supprimer la ligne sélectionnée?", vbYesNo + vbQuestion)
    If rep = vbYes Then
        ListBox1.RemoveItem (ListBox1.ListIndex)
    End If
End Sub

A l'ouverture du fichier

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Private Sub UserForm_Initialize()
 ListBox1.ColumnCount = 3
 ListBox1.ColumnWidths = "50;50;50"
ListBox1.Visible = False
End Sub

Comment dois-je faire si je veux transférer chaque donnée de la listbox dans une cellule excel afin de l'éditer svp ?

Avez vous une solution svp ?

**mjpmjp** · 28/08/2017, 10h26

bonjour,
j'ai posté dans les contributions cette discussion : Form GRAPHIQUE, Liste Multi-Colonne et ScrollBar Externe
qui explique une autre façon d'utiliser un scroll
"normalement" , le scroll fait "défiler" une frame avec 100 TextBox

"l'autre façon" , le scroll fait "défiler" le contenu dans 3 TextBox

dans la discussion "Form GRAPHIQUE, Liste Multi-Colonne et ScrollBar Externe" il y a ce shéma
qui explique :

comment schématiser au plus simple le mécanisme d'une "Liste Ecran" (unique) de 33 Lignes, dans laquelle on fait glisser un Tableau de 20000 Lignes

@+JP

**manufer** · 28/08/2017, 10h38

Salut mjpmjp,

J'ai bien vu cela,

Mais ce que je souhaite faire c'est transférer les donnée de la listbox (trois colonnes) vers une feuille excel,

Aujourd'hui j'arrive à transférer cela dans une cellule, sauf que je ne sais pas comment répartir
les données de la liste box en trois colonnes sur une feuilles sur plusieurs lignes les unes en dessous des autres.

Pr contre je crois avoir une erreur, parce que dans ce code je ne suis pas sûr que les données de la textbox 1 vont dans la colonne 1 de la listbox et ainsi de suite.

Voila ce que je cherche à faire.

Vous savez si cela est possible svp ?

**manufer** · 28/08/2017, 11h26

Salut,

Voilà ce que j'ai trouvé (mais j'ai un problème avec ça):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Private Sub CommandButton1_Click()
Dim col As Integer
If TextBox1 <> "" Or TextBox2 <> "" Or TextBox3 <> "" Then
ListBox1.Visible = True
 
UserForm1.ListBox1.AddItem
ListBox1.List(col, 0) = TextBox1
ListBox1.List(col, 1) = TextBox2
ListBox1.List(col, 2) = TextBox3
 
End If
        TextBox1 = Null
        TextBox2 = Null
        TextBox3 = Null
End Sub

Le problème que je rencontre avec ce code, c'est que à chaque fois que je valide les données de textbox pour qu'elles s'insèrent dans la listbox,
Les précédentes données de listbox disparaissent et seuls les nouvelles restent.

Ce qui est étrange parce que dans le précédent code j'avais:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

UserForm1.ListBox1.AddItem (TextBox1 & TextBox2 & TextBox3)

au lieu de

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
UserForm1.ListBox1.AddItem
ListBox1.List(col, 0) = TextBox1
ListBox1.List(col, 1) = TextBox2
ListBox1.List(col, 2) = TextBox3

et les données s'ajoutaient les unes au dessous des autres.

Avez-vous une solution à ça svp ?

**manufer** · 28/08/2017, 11h34

Salut,

Je reviens encore une fois;

J'ai mit

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
UserForm1.ListBox1.AddItem
col = ListBox1.ListCount - 1
ListBox1.List(col, 0) = TextBox1
ListBox1.List(col, 1) = TextBox2
ListBox1.List(col, 2) = TextBox3

Et je crois que ça fonctionne.

Par contre je ne sais pas transférer les trois colonnes de la listbox dans trois colonnes d'une feuille excel.

Vous savez faire svp ?

**manufer** · 28/08/2017, 16h16

Salut,

Quelqu'un peut-il me dire pourquoi le cde ci-dessous ne fonctionne pas:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Sub CalculSomme()
 
  If TextBox3 = "" Or TextBox2 = "" Then
  Me.TextBox4.Value = ""
  ElseIf TextBox3 <> "" And TextBox2 <> "" Then
  Me.TextBox4.Value = (TextBox2.Value * Me.TextBox3.Value)
    End If
End Sub

Pourtant je met bien

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub TextBox4_Change()
CalculSomme
End Sub

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub TextBox3_Change()
CalculSomme
End Sub

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub TextBox2_Change()
CalculSomme
End Sub

Je ne comprend pas ce qui manque, avez vous une piste svp ?

**mjpmjp** · 28/08/2017, 17h02

bonjour,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
 
Sub CalculSomme()
    If Me.TextBox3.Value <> "" And Me.TextBox2.Value <> "" Then
        Me.TextBox4.Value = (Val(Me.TextBox2.Value) * Val(Me.TextBox3.Value))
    Else
        Me.TextBox4.Value = ""
    End If
End Sub

pour la personne qui met des -1 (qui ne doit pas tout comprendre) voila une belle image

Nom : Capture.JPG
Affichages : 170
Taille : 16,3 Ko

@+JP

**manufer** · 29/08/2017, 09h43

Génial ça fonctionne.

Merci.

**manufer** · 29/08/2017, 16h01

Petite question,

est-il possible de faire apparaitre le résultat sans avoir besoin de cliquer sur "commandboutton1" ?

Que la Textbox 4 affiche le résultat au fur et à mesure que l'on saisisse les textbox 2 et 3 ?

J'ai essayé de mettre le résultat dans un "UserForm_Initialize" mais ça ne fonctionne pas.

Savez vous par quoi je doit passer svp ?

**mjpmjp** · 29/08/2017, 17h56

bonjour,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
 
Private Sub TextBox2_Exit(ByVal Cancel As MSForms.ReturnBoolean)
    If Me.TextBox3.Value = "" Then
        Me.TextBox3.SetFocus
    Else
        Call CalculSomme
    End If
End Sub
Private Sub TextBox3_Exit(ByVal Cancel As MSForms.ReturnBoolean)
    If Me.TextBox2.Value = "" Then
        Me.TextBox2.SetFocus
    Else
        Call CalculSomme
    End If
End Sub

si ok clique résolue

@+JP

**manufer** · 29/08/2017, 22h16

Merci pour tout.

Userform textbox objet

Macros et VBA Excel

Discussions similaires

Partager

Partager