Discussion :

[otric]

Bonjour,

Un peu novice sur EXCEL, j'essaye de rendre dynamique l'affichage de Logo dans l'entête d'une page EXCEL.
C'est pour avoir une seule matrice de devis pour plusieurs sociétés.

Je sais afficher un logo différent si je passe par des fichiers externes :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
ActiveSheet.PageSetup.RightHeaderPicture.Filename = "C:\IDEX.jpg" 
ActiveSheet.PageSetup.RightHeader = "&G"

Mais mes logos sont stockés dans le fichier EXCEL.

J'imagine que le code devrait être du style :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
ActiveSheet.PageSetup.RightHeaderPicture.Filename = Sheets("Feuil1").Shapes("Image 1")
ActiveSheet.PageSetup.RightHeader = "&G"

J'ai essayé de passer par une variable :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

MonImage = Sheets("Feuil1").Shapes("Image 1")

, mais j'ai une erreur 438 : Propriété ou Méthode non gérée par cet objet

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ActiveSheet.PageSetup.RightHeaderPicture.Filename = MonImage

Bref vous l'aurez compris, je ne maîtrise pas les syntaxes EXCEL, si une bonne âme pouvait m'aider.

[78chris]

Bonjour

J'ai fait cela il y a quelques années mais je pense que cela n'a pas changé : l'image ne pouvait être que sur le disque.

[otric]

Merci de votre réponse rapide, je ne peux pas me permettre d'avoir les images sur le disque malheureusement.

Mais j'ai peut-être une idée :
Est-il pensable de prendre l'image, de la copier temporairement de la feuille EXCEL vers un répertoire du C:\ par exemple de faire le :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ActiveSheet.PageSetup.RightHeaderPicture.Filename = "C:\IDEX.jpg"

qui lui fonctionne et de détruire le fichier IDEX.jpg ensuite ?

Ma question est l'entête gardera-t-il mon image ou est-ce juste un lien dynamique vers le C:\ (et dans ce cas, je n'ai plus d'image dans mon entête) ?

[patricktoulon]

Merci de votre réponse rapide, je ne peux pas me permettre d'avoir les images sur le disque malheureusement

bon ben voila encore un exemple un nouveau qui n'a pas trouver le bouton rechercher

dans la faq les contrib vba excel tu fait une recherche exporter un graph en gif
tu trouvera aussi comment exporter de la même façon un shapes une image, etc.....
le reste de l'idée tu la vois?????

allez je te laisse faire tes recherches

[78chris]

Bonjour

Pour compléter la réponse de Patrick Toulon que je salue : oui l'image ensuite est intégrée dans l'en-tête et tu peux effacer le fichier.

[patricktoulon]

Bonjour
allez un exemple je trouvais l'exercice intéressant

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
 
Sub appercu_avec_image_du_sheet_en_logo()
    Dim logotemp As String, mylogo As Object
 
    logotemp = ThisWorkbook.Path & "\logotemp.jpg"
    With Sheets(1) ' adapte ton sheets
        Set mylogo = .Shapes("logodvp")    ' adapte le nom de ta shape ici
        mylogo.Copy
        With .ChartObjects.Add(0, 0, mylogo.Width, mylogo.Height).Chart
            .Paste    'colle l'image dans un graphique temporaire
            .Export logotemp, "JPG"    'enregistre  l'image temporaire (logotemp.jpg)  dans le même répertoire que ce classeur.
            .Parent.Delete    'on supprime le chart temporaire
        End With
        .PageSetup.RightHeaderPicture.Filename = logotemp
        .PageSetup.RightHeader = "&G"
        .PrintPreview    'printout pour imprimer directement
    End With
    Kill logotemp    ' on suprime le fichier logotemp.jpg
End Sub

Edit:
Ps: voila en vba pour rendre ton shape non imprimable en dessous

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

mylogo.Copy

met ceci:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

mylogo.ControlFormat.PrintObject = False

j'aurais appris quelque chose aujourd'hui