Discussion :

[DavidCsame]

Bonjour,

J'ai un soucis concernant une macro qui marchait sur excel 2010 mais ne marche plus sous 2013. Je l'utilise pour afficher ou non des colonnes parmi 30 en fonction de la valeur que prend la quatrième cellule de la colonne. La macro est la suivante :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Sub ModifmoyensdemaitriseASS()

Set mycell = ActiveCell

ActiveCell.Select
Selection.Copy
Range("D3").Select
Selection.PasteSpecial Paste:=xlPasteValues


For col = 6 To 36
If Cells(4, col) <> "Autres (Modifier BDD)" Then Columns(col).Hidden = False
Next

For col = 6 To 36
If Cells(4, col) = "Autres (Modifier BDD)" Then Columns(col).Hidden = True
Next


End Sub

La première partie fonctionne sans souci, c'est la partie en jaune qui est remise en cause par le débogage. Ainsi que l'équivalent dans la dernière partie.

Je ne m'explique pas le dysfonctionnement, si vous pouvez éclairer ma lanterne

Merci d'avance !

[antonysansh]

Bonjour DavidCsame,

Je ne peux pas tester ton code, voici un code qui devrait fonctionner, j'ai juste précisé la feuille ou tu dois faire tes actions

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Sub ModifmoyensdemaitriseASS()
 
    Dim mycell As Range
    Dim sh As Worksheet
    Dim col As Byte
 
    Set mycell = ActiveCell
    Set sh = mycell.Parent
 
    sh.Select
    mycell.Select
 
    Selection.Copy
    Range("D3").Select
    Selection.PasteSpecial Paste:=xlPasteValues
 
    With sh
        For col = 6 To 36
            If .Cells(4, col) <> "Autres (Modifier BDD)" Then
                .Columns(col).Hidden = False
            Else
                .Columns(col).Hidden = True
            End If
        Next
    End With
 
End Sub

Si ça ne fonctionne pas, je ne sais pas quelles sont les particularités de la version 2013 qui empêche le fonctionnement de cette macro

Antony

[mercatog]

Ou simplement

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Dim Col As Integer
 
Range("D3") = ActiveCell
For Col = 6 To 36
    Columns(Col).Hidden = Cells(4, Col) = "Autres (Modifier BDD)"
Next Col

PS. Y a t-il un moyen de ne pas faire rédérence à la cellule active?

[eric4459]

Bonjour David
J'ai un peu simplifié ton code, ôté les "Select" qui ne servent à rien et supprimé la deuxième boucle en l'intégrant à la première.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub ModifmoyensdemaitriseASS()
 
Set mycell = ActiveCell
 
ActiveCell.Copy
Range("D3").PasteSpecial Paste:=xlPasteValues
 
For col = 6 To 36
If Cells(4, col) <> "Autres (Modifier BDD)" Then
Columns(col).Hidden = False
Else
Columns(col).Hidden = True
End If
Next
 
 
End Sub

Autre petit conseil, essayes systématiquement de déclarer tes variables

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

 Dim myCell As ..., Dim col as ...

et ajoute en haut de chaque module avant la première Sub Option Explicit cela t'aidera au débogage si nécessaire

Je suis moi-même sous Excel 2010 et le code fonctionne correctement, quel est le message d'erreur qui apparaît?

Eric

[DavidCsame]

Pour commencer, merci à vous trois pour votre intervention, c'est toujours un plaisir de trouver de l'aide sur un forum !

J'ai testé vos trois propositions et les trois fonctionnent (seules les colonnes que je veux voir apparaissent) MAIS le message d'erreur apparaît toujours et ouvre la fenêtre de débogage.

Le message d'erreur exact est :

Erreur d'éxecution '13':
Incompatibilité de type


Il parle de moi et d'Excel? :p

[mercatog]

En pas à pas, sur quelle ligne tu as l'erreur

[eric4459]

Et si tu essayais

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Dim col as Integer

?
L'erreur apparait-elle toujours?
Eric

[patricktoulon]

bonjour

pourquoi "activecell.select " activecell est déjà la cellule sélectionnée


ensuite pourquoi 2 boucle pour un false ou true sur le même object ????

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub ModifmoyensdemaitriseASS()
Range("D3").Value = ActiveCell.Value
For col = 6 To 36
If Cells(4, col) = "Autres (Modifier BDD)" Then
Columns(col).Hidden = True
Else
Columns(col).Hidden = False
End If
Next
End Sub

je viens de relire le post en entier et le code de mercatog devrait fonctionner (utiliser le l'erreur du égal sur la valeur de la cells en boolean )j'aime beaucoup

[antonysansh]

J'ai testé vos trois propositions et les trois fonctionnent (seules les colonnes que je veux voir apparaissent) MAIS le message d'erreur apparaît toujours et ouvre la fenêtre de débogage.

Le message d'erreur exact est :

Erreur d'éxecution '13':
Incompatibilité de type

Donc ça marche mais a un moment ça plante.

Tes variables ont quelles valeurs au moment du bug ?