Discussion :

[Filippo]

Bonsoir,
j'essaie de faire une macro qui vérifie que la valeur d'une variable est numérique :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
%Macro Contenu_Numeric(MyvarIn);
	%global Flag;
	%let Flag=1;
 
	%local temp;
	%let temp=%sysfunc(input(&MyVarIn,best.));
 
	%if &temp eq . %then %let Flag=0;
%Mend;

Me renvoie à l'exécution :

ERREUR: The INPUT function referenced in the %SYSFUNC or %QSYSFUNC macro function is not found.

Et :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
%Macro Contenu_Numeric(MyvarIn);
	%global Flag;
	%let Flag=1;
 
	%local temp;
	%let temp=%input(&MyVarIn,best.);
 
	%if &temp eq . %then %let Flag=0;
%Mend;

Produit à la compilation :

ERREUR: Macro keyword INPUT appears as text. A semicolon or other delimiter may be missing.

Sinon j'ai aussi essayé une autre macro :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
%Macro Contenu_Numeric(MyvarIn);
	%global Flag;
	%let Flag=1;
 
	%local l;
	%local n;
 
	%let l=%length(&MyVarIn);
	%do n=1 %to &l;
		%if %sysfunc(substr(&MyVarIn,&n,1)) not in ('0','1','2','3','4','5','6','7','8','9','.',',') %then %let flag=0;
	%end;
%Mend;

qui produit à l'éxécution, avec ou sans %sysfunc :

ERREUR: The macro CONTENU_NUMERIC will stop executing.
ERREUR: A character operand was found in the %EVAL function or %IF condition where a numeric
operand is required. The condition was: %sysfunc(substr(&MyVarIn,&n,1)) not in
('0','1','2','3','4','5','6','7','8','9','.',',')

Si quelqu'un a une idée de syntaxe pour la 1ère ou la seconde macro, je suis preneur.

Merci

[RemiBousquet]

Avec input, tu essaies de transformer le texte en valeur numérique, alors qu'une macro variable ne peut pas être numérique, c'est peut-être l'origine du problème ?

J'ai un truc qui marche avec le code suivant, mais suis pas sûr que ça réponde à ton besoin

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
%Macro Contenu_Numeric(MyvarIn);
	%global Flag; %let Flag=1;
    %local j k ;
    %let j      = %sysfunc(compress(&&&myvarin.,' 0123456789.,'));  %put j    = &j. ;
    %let k      = %sysfunc(lengthn("&j.")) ;                        %put k    = &k. ;
    %let flag   = %eval(&k. = 2 ) ;                                 %put flag = &flag. ;
%Mend;
 
%let i = 154124  ;  %contenu_numeric(i);  %put i = &i., flag = &flag. ;
%let i = 14.1421 ;  %contenu_numeric(i);  %put i = &i., flag = &flag. ;
%let i = 14.14aa ;  %contenu_numeric(i);  %put i = &i., flag = &flag. ;
%let i =         ;  %contenu_numeric(i);  %put i = &i., flag = &flag. ;

[Filippo]

Merci Rémi pour ton aide

Ton exemple fonctionne bien.

Dans mon cas j'aurais besoin de de pouvoir appeler :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

%Contenu_Numeric(Variable);

car j'appelle la macro dans une étape data par le biais d'un CALL EXECUTE et récupère la valeur de &flag dans la suite de l'étape data.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

%Contenu_Numeric('10');

produit Flag=0 dans la log.

Je vais revenir à mon idée de input mais sans macro ça sera plus simple

[RemiBousquet]

Si la valeur de la macro variable est entre simple quote, ça nécessite une petite adaptation effectivement :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
%Macro Contenu_Numeric(MyvarIn);
	%global Flag; %let Flag=1;
    %LOCAL j k ;
    %let j      = %sysfunc(compress(&&&myvarin.," 0123456789.,"));   /*%put j    = &j. ;    */ 
    %let k      = %sysfunc(lengthn(&j.)) ;                           /*%put k    = &k. ;    */ 
    %let flag   = %eval(&k. = 2 ) ;                                  /*%put flag = &flag. ; */
%Mend;
 
%let i = '10'    ;  %contenu_numeric(i);  %put i = &i., flag = &flag. ;
%let i = 'aa'    ;  %contenu_numeric(i);  %put i = &i., flag = &flag. ;

qui donne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
i = '10', flag = 1
i = 'aa', flag = 0

[Filippo]

Merci Rémi,
ton exemple fonctionne bien mais dans une étape data je récupère toujours 0.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
data _null_;
	%Contenu_Numeric('40');
	%put &flag;
run;

Me donne :

14935 data _null_;
14936 %Contenu_Numeric('40');
14937 %put &flag;
0
14938 run;

[RemiBousquet]

Si myvarin est une valeur plutôt qu'une macrovariable, alors il faut enlever le "&&&" :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
%Macro Contenu_Numeric(MyvarIn);
	%global Flag; %let Flag=1;
    %LOCAL j k ;
    %let j      = %sysfunc(compress(&myvarin.," 0123456789.,"));   /*%put j    = &j. ;    */ 
    %let k      = %sysfunc(lengthn(&j.)) ;                         /*%put k    = &k. ;    */ 
    %let flag   = %eval(&k. = 2 ) ;                                /*%put flag = &flag. ; */
%Mend;
 
DATA _null_;
	%Contenu_Numeric('40'); %put &flag;
	%Contenu_Numeric('aa'); %put &flag;
	%Contenu_Numeric('1.5'); %put &flag;
	%Contenu_Numeric('1  '); %put &flag;
	%Contenu_Numeric('11aa'); %put &flag;
run;

[Filippo]

Ca marche impeccable

Merci Rémi