Discussion :

[rakhann974]

Bonjour,

A partir de ce code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
Private Sub CheckBox1_Click()
If CheckBox1.Value Then
Label1.Caption = Sheets("feuil1").Range("B1").Value
Else
Label1.Caption = "merci de valider"
End If
End Sub
Private Sub CheckBox2_Click()
If CheckBox2.Value Then
Label2.Caption = Sheets("feuil1").Range("B1").Value
Else
Label2.Caption = "merci de valider"
End If
End Sub
Private Sub CheckBox3_Click()
If CheckBox3.Value Then
Label3.Caption = Sheets("feuil1").Range("B1").Value
Else
Label3.Caption = "merci de valider"
End If
End Sub
Private Sub CheckBox4_Click()
If CheckBox4.Value Then
Label4.Caption = Sheets("feuil1").Range("B1").Value
Else
Label4.Caption = "merci de valider"
End If
End Sub
Private Sub CheckBox5_Click()
If CheckBox5.Value Then
Label5.Caption = Sheets("feuil1").Range("B1").Value
Else
Label5.Caption = "merci de valider"
End If
End Sub

Serait-il possible de créer une boucle afin d'éviter de le répéter xfois.
Pour l’exemple j'en ai que 5, mais dans la réalité j'en des centaines.
Dans mon idée, ça serait quelque chose comme :
Si case à cocher n = true alors label n = "b1" sinon "merci de valider".
Tout se passe sur une feuille excel et non dans un Userform

Merci pour votre aide

[casefayere]

Bonjour le forum, rakhann974

A essayer :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Dim i As Integer
 
For i = 1 To 5
  With Sheets("feuil1")
      If .OLEObjects("CheckBox" & i).Object.Value Then
        .OLEObjects("Label" & i).Object.Caption = .Range("B1").Value
      Else
        .OLEObjects("Label" & i).Object.Caption = "merci de valider"
      End If
  End With
Next i

[rakhann974]

Bonjour Casefayere,

Merci beaucoup pour ce code qui fonctionne très bien, mais (ben oui sinon ca serait trop facile ) il n'est pas interactif. A moins que ça vienne de moi.
je l'ai placé dans ma feuille comme suit :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
 
Private Sub validation()
 Dim i As Integer
For i = 1 To 2
  With Sheets("feuil1")
      If .OLEObjects("CheckBox" & i).Object.Value Then
        .OLEObjects("Label" & i).Object.Caption = .Range("B1").Value
        Else
        .OLEObjects("Label" & i).Object.Caption = "merci de valider"
      End If
  End With
  Next i
End Sub

je coche mes cases mais la valeur du label ne change que si je lance la procédure à la main.
Il y a quelque chose que j'ai dû certainement louper.
j'ai pensé également passer par un module afin de pouvoir l'appeler depuis n'importe quel feuille, mais je vois pas comment faire.
Je précise que je suis un peu débutant et que jusqu'à présent je me cantonais à des fonctions basique en vba.

Merci beaucoup de ton aide.

Afin de répondre à mon problème, j'ai du le contourner comme suit :

dans un module :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Sub validation(i As Integer)
'For i = 1 To 5
  With Sheets("feuil2")
      If .OLEObjects("CheckBox" & i).Object.Value Then
        .OLEObjects("Label" & i).Object.Caption = .Range("B1").Value
      Else
        .OLEObjects("Label" & i).Object.Caption = "merci de valider"
      End If
  End With
'Next i
End Sub

Dans ma feuille ("feuil2") pour l'exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Private Sub CheckBox1_Click()
Call validation(1)
End Sub
 
Private Sub CheckBox2_Click()
Call validation(2)
End Sub
 
Private Sub CheckBox3_Click()
Call validation(3)
End Sub
 
Private Sub CheckBox4_Click()
Call validation(4)
End Sub
 
Private Sub CheckBox5_Click()
Call validation(5)
End Sub

Pourriez-vous me dire si c'est la bonne méthode, ou il y a t'il une méthode plus simple.
La valeur du "label" ne doit plus changer une fois mis à jour.
J'espère avoir été un peu plus clair dans mon explication.

Merci

[Invité]

Bonsoir,

Je n'ai pas vraiment regardé de près, mais un module de classe semble être adapté. Il vaut mieux poster en section Macro VBA.

Est-ce que cette question est toujours d'actualité ?

[rakhann974]

Bonjour,

Comme je débute, je n'ai pas encore essayé de travailler sur les modules de classe.
je regarderai ça, mais des conseils me seraient bien utiles.

Rakhann974

[Invité]

Bonjour,

OK, attendons de voir si quelqu'un te réponde.
Sinon, je pourrai peut être t'aider demain.

A+

[patricktoulon]

Bonjour

en fait ta demande n'est pas tres precises
a quel moment les checkboxs sont verifié pour modifier le label correspondant ??????


dans ce cas la une classe n'est pas forcement necessaire

soit plus precis dans ta question

Au plaisir

[rakhann974]

Bonjour,

Déjà, merci de l'attention que vous portez à mon cas.

Pour te répondre, la validation se fait à chaque fois que la checkbox est coché.

J'ai commencé à regarder les module de class sur quelques forum et je suis tombé sur un code qui pourrai correspondre à mon besoin. Mais je vais devoir l'adapter. ( du moins si c'est possible).
Je posterai bien le code d'origine, mais je voudrai le faire par moi même avant que vous donniez la solution.

Pour ça je vais passer la le tuto sur les module de class afin de bien comprendre leur fonctionnement et leur porté

Rakhann974

[Invité]

Bonjour,
Salut patricktoulon & rakhann974,

@rakhann974,
Ça fais déjà plaisir de savoir que tu ne cherche pas forcément une solution toute préfaite, mais que tu cherche à comprendre le fonctionnement. Pour ma part, je ne suis pas un As des modules de classes, mais pour ton cas, c'est sûr et certain qu'un module de classe est adapté.
Dès qu'il y a un événement, un module objet est nécessaire, très souvent, un module de classe répond à la question.
Quelques liens:
http://www.cpearson.com/excel/AppEvent.aspx
http://www.cpearson.com/excel/classes.aspx (et bien d'autres)
http://www.jkp-ads.com/Articles/ControlHandler00.asp (adapté à ton cas, à lire je pense car très rapide à faire)
et bien sûr, les liens de DVP http://excel.developpez.com/faq/?page=ModuleClasse

A+

[PMO2017]

Bonjour,

Une piste avec le code suivant basé sur une classe.

1) créez un module de classe Class1 et copiez le code suivant

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Public WithEvents CheckBoxGroup As MSForms.CheckBox
 
Private Sub CheckBoxGroup_Click()
Dim OL As OLEObject
Dim LB As MSForms.Label
Dim i&
Dim myItem$
'--- Détermine l'ID du CheckBox (les chiffres en final) ---
For i& = 1 To Len(CheckBoxGroup.Name)
  If IsNumeric(Mid(CheckBoxGroup.Name, i&, 1)) Then
    myItem$ = myItem$ & Mid(CheckBoxGroup.Name, i&, 1)
  End If
Next i&
'--- Recherche l'OLEObject correspondant  et l'affecte à une variable object MSForms.Label ---
Set OL = ActiveSheet.OLEObjects("Label" & myItem$ & "")
Set LB = OL.Object
'--- Change le caption et la couleur de fonds en fonction de la coche de la CheckBox ---
If CheckBoxGroup.Value Then
  LB.Caption = [b1]
  LB.BackColor = RGB(204, 255, 204)
Else
  LB.Caption = "Merci de valider"
  LB.BackColor = RGB(255, 204, 255)
End If
 
'--- On s'amuse avec d'autres propriétés (accessoirement) ---
LB.WordWrap = False
LB.AutoSize = True
End Sub

2) copiez le code suivant dans la fenêtre de code de ThisWorkbook

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Private Sub Workbook_Activate()
Call InitializeCheckBoxes(ThisWorkbook.Sheets("test")) 'à adapter par la feuille concernée
End Sub
 
Private Sub Workbook_Deactivate()
Set MyClass = Nothing
End Sub

3) copiez le code suivant dans un module Standard

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Public MyClass As Classe1
Public CollCheckBoxes As Collection
 
Public Sub InitializeCheckBoxes(Feuille As Worksheet)
Dim OL As OLEObject
Set MyClass = Nothing
'---
Set CollCheckBoxes = New Collection
For Each OL In Feuille.OLEObjects
  If TypeOf OL.Object Is MSForms.CheckBox Then
    Set MyClass = New Classe1
    Set MyClass.CheckBoxGroup = OL.Object
    CollCheckBoxes.Add MyClass
  End If
Next OL
End Sub

4) renommez une feuille "test", créez un ActiveX CheckBox1 et un ActiveX Label1.
Sélectionnez les 2 contrôles, copiez les et collez les plusieurs fois de suite pour en avoir une quantité conséquente.
Les contrôles sont appariés de manière qu'à chaque CheckBoxX correspond un LabelX.

5) lancez la procédure "Workbook_Activate" qui est dans ThisWorkBook pour initialiser les contrôles CheckBox

Je mets le classeur exemple en pièce jointe pour faciliter.

[rakhann974]

Bonjour PMO2017,

Ca marche nickel ton code.
J'étais pas loin de trouver une solution, même si je tournais en rond sur le module standard.
L'essentiel est que je commence tout juste à comprendre le fonctionnement et je devrais pouvoir l'adapter, comme par exemple la gestion de plusieurs feuilles.

Merci de ton aide.