exportation donnée dans fichier excel

**popofpopof** · 05/06/2011, 17h11

Bonjour,

J'utilise une fonction pour exporte mes données dans word qui marche super bien. ( voir dessous)
Je souhaite avoir le même principe pour exporté des données sous excel dans un fichier existant. avec ces champs a renseigné
cellule B6 = nom de l'opération (1 seule fois)
cellule A12 = Numéro de lot ( a ajoute dessous l'ensemble des données)
Cellule B12 = Nom de l'entreprise ( a ajoute dessous l'ensemble des données)

voila le code pour la fonction word mais je n'arrive pas a trouve pour excel

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
 
DoCmd.SetWarnings False
 Dim DOC_WORD10 As String
DoCmd.RunSQL " DELETE Courier.* FROM Courier IN '" & Environ("USERPROFILE") & "\access_pc3d\publipostage.mdb';"
DoCmd.RunSQL "INSERT INTO Courier ( NUM_OPERATION, NOM_OPERATION ) IN '" & Environ("USERPROFILE") & "\access_pc3d\publipostage.mdb' SELECT OPERATION.NUM_OPERATION, OPERATION.NOM_OPERATION From operation WHERE (((OPERATION.NUM_OPERATION)=[Forms]![Décompte Général Définitif]![NUM_OPERATION]));"
DoCmd.SetWarnings True
' Chemin d'accès au document Word de publipostage
DOC_WORD10 = Environ("USERPROFILE") & "\access_pc3d\doc\Financier chantier\466. Pochettes dossier DGD - DOE. R4.doc"
' Variable pour gérer l'objet Word
Dim wdApp10 As Object    'ici
' Passer à la partie Publipostage
Set wdApp10 = CreateObject("Word.Application")  'ici
With wdApp10
    ' Word est visible pendant les tests
    .Visible = True
    ' Ouvrir la lettre type
    .Documents.Open DOC_WORD10
    ' Lier la lettre type à la source de données Access
    .ActiveDocument.MailMerge.OpenDataSource _
        Name:=Environ("USERPROFILE") & "\access_pc3d\publipostage.mdb", _
        SQLStatement:="SELECT * FROM [Courier]"
     ' La fusion doit se faire dans un nouveau document
    .ActiveDocument.MailMerge.destination = wdSendToNewDocument
    ' Exécuter la fusion
.ActiveDocument.MailMerge.Execute
    ' Redonner le focus à la lettre type et fermer sans enregistrer
    .Documents.Open DOC_WORD10
    .ActiveDocument.Close wdDoNotSaveChanges
    End With
Set wdApp10 = Nothing
Exit Sub

voila la requête ou l'on trouve les information nom du chantier, numéro de lot et nom de l'entreprise, dans la fonction word j'exporte les donnée dans uen base extérieure a voir si c'est utile :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
SELECT OPERATION.NOM_OPERATION, ESTIM_OPE.NUM_LOT, ENTREPRISE.NOM_ENTREPRISE
FROM (OPERATION INNER JOIN (ESTIM_OPE INNER JOIN ENTREPRISE_SOLLICITE ON (ESTIM_OPE.NUM_CORPS_ETATS = ENTREPRISE_SOLLICITE.NUM_CORPS_ETATS) AND (ESTIM_OPE.NUM_OPERATION = ENTREPRISE_SOLLICITE.NUM_OPERATION)) ON OPERATION.NUM_OPERATION = ESTIM_OPE.NUM_OPERATION) INNER JOIN ENTREPRISE ON ENTREPRISE_SOLLICITE.NUM_ENTREPRISE = ENTREPRISE.NUM_ENTREPRISE
WHERE (((OPERATION.NUM_OPERATION)=[Forms]![Décompte Général Définitif]![NUM_OPERATION]));

Merci de m'aide car je ne trouve pas de fonction pour exporte sur excel avec la fonction de garde la mise en page.

Invité · 05/06/2011, 17h23

Bonjour

Tu montres un exemple sous Word, mais as-tu utilisé la FAQ en mettant le mot Excel dans le moteur de recherche de celle-ci ? A priori non, car tu aurais trouver des exemples de codes pour piloter Excel à partir d'Access.

Philippe

**Godzestla** · 06/06/2011, 11h04

Bonjour popofPopof,

jette un coup d'oeil sur ce post qui pourrait t'aider.

Bonne journée.

**popofpopof** · 06/06/2011, 19h49

Merci pour ton lien je l'avais déjà lu, mais je n'arrive pas a l'applique a mon cas car je le trouve différent de mon cas.

et en plus je suis nul en VBA.

tu peux m'aide a le faire STP?

**LedZeppII** · 06/06/2011, 20h49

Bonsoir,

regardes cet exemple :

Décompresse les deux fichiers dans un même dossier.
Le code exemple est dans le module modExportXL (sub ExporteDsExcelAvecModele).
Il remplit un fichier modèle Excel (.xlt).
Pour un fichier Excel standard, remplacer la ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
' Crée un nouveau Classeur à partir d'un modèle
Set xlWbk = xlApp.Workbooks.Add(CurrentProject.Path & "\ModeleAR.xlt")

par

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
' Ouvre un classeur existant
Set xlWbk = xlApp.Workbooks.Open(CurrentProject.Path & "\FichierExcel.xls")

Ça devrait te donner les principes de base.

A+

**popofpopof** · 07/06/2011, 22h00

SAlut

Merci je le trouve pas mal du tout ton code le voila modifier avec mes valeurs sa marche

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
 
Sub ExporteDsExcelAvecModele()
' Variables pour manipuler Excel
Dim xlApp As Excel.Application, xlAppCreated As Boolean
Dim xlWbk As Excel.Workbook, xlSht As Excel.Worksheet
Dim lgCntLigne As Long
' Variables données sources
Dim db As DAO.Database, rs As DAO.Recordset
' Variable spécifiques à l'appli
Dim strope As String
 
 
On Error GoTo ErrH
 
Set db = CurrentDb
' Ouvre la requête
Set rs = db.OpenRecordset("SELECT [suivi DGD excel].NOM_OPERATION, [suivi DGD excel].NUM_LOT, [suivi DGD excel].NOM_ENTREPRISE FROM [suivi DGD excel] ORDER BY [suivi DGD excel].NUM_LOT")
' Si vide sortir
If rs.EOF Then GoTo ExitSub
 
' Tente de récupérer une instance d'Excel déjà créée
Set xlApp = GetObject(, "Excel.Application")
' Sinon, crée une nouvelle instance d'Excel
If xlApp Is Nothing Then
   Set xlApp = CreateObject("Excel.Application")
   xlAppCreated = True
End If
' Crée un nouveau Classeur à partir d'un modèle
Set xlWbk = xlApp.Workbooks.Add(Environ("USERPROFILE") & "\access_pc3d\doc\Financier chantier\465. Suivi DGD- DOE- PV. R4.xls")
 
' Référence la feuille active du classeur
Set xlSht = xlWbk.ActiveSheet
 
' Infos générales à mettre dans les cellules C2,C3,C5
strope = rs("NOM_OPERATION")
xlSht.Range("B6") = strope
 
 
'Détail (lignes) commence à partir de cellule B8
Do
    '1ère colonne (offset 0)
    xlSht.Range("A12").Offset(lgCntLigne, 0) = rs("NUM_LOT")
    '2ème colonne (offset 1)
    xlSht.Range("A12").Offset(lgCntLigne, 1) = rs("NOM_ENTREPRISE")
 
    rs.MoveNext
 
    ' Incrémenter n° de ligne (relatif à la ligne 8 (B8))
    lgCntLigne = lgCntLigne + 1
Loop Until rs.EOF
 
 
' Pour confirmer l'écrasement du Classeur s'il existe
xlApp.DisplayAlerts = False
' Sauvegarde du Classeur
xlWbk.SaveAs CurrentProject.Path & "\Cmde_" & strope, xlNormal
' Fermeture du Classeur
xlWbk.Close False
 
ExitSub:
' Réactive les messages d'avertissement
If Not (xlApp Is Nothing) Then xlApp.DisplayAlerts = True
 
' Libération des variables objets
Set rs = Nothing
Set db = Nothing
 
Set xlSht = Nothing
Set xlWbk = Nothing
If xlAppCreated = True And Not (xlApp Is Nothing) Then xlApp.Quit
Set xlApp = Nothing
Exit Sub
 
ErrH:
' Gestion d'erreurs
Select Case Err.Number
    Case 429
         ' Ignorer Erreur causée par GetObject(, "Excel.Application")
         Resume Next
 
    Case Else
         MsgBox "Erreur N. " & Err.Number & " : " & Err.Description
         Resume ExitSub
End Select
End Sub

Par contre actuellement il me crée un fichier excel la ou se trouve la base, je souhaite que le fichier s'ouvre et reste ouvert sans crée un fichier déjà enregistre sa sera utilisateur qui choisira de l’enregistre ou non.

Tu peux me dire ou modifier le code et comment ?

Merci encore

chef

Invité · 08/06/2011, 02h48

Bonjour

Envoyé par popofpopof

Tu peux me dire ou modifier le code et comment ?

Il est important de comprendre le code que les membres du forum vous donne, surtout que celui-ci est documenté, il faut donc agir sur cette partie en la mettant (par exemple) en commentaire :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
' Sauvegarde du Classeur
xlWbk.SaveAs CurrentProject.Path & "\Cmde_" & strope, xlNormal
' Fermeture du Classeur
xlWbk.Close False

Philippe

**popofpopof** · 08/06/2011, 21h43

j'avais compris que c'est cette ligne qui fallait modifier mais je ne trouve pas comment dire d'ouvrir le fichier excel qui viens d'être généré comme un nouveau fichier excel mais avec l'ensemble de la mise en page et des données mis a jour.

Je cherche a comprendre mais très peu de connaissance en VBA

j'ai voulu incorporé le code dans ma base principale, j'ai donc modifier la requête initial

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
SELECT OPERATION.NOM_OPERATION, ESTIM_OPE.NUM_LOT, ENTREPRISE.NOM_ENTREPRISE, ENTREPRISE_SOLLICITE.DEVIS_RETENUE
FROM ENTREPRISE INNER JOIN (ENTREPRISE_SOLLICITE INNER JOIN (ESTIM_OPE INNER JOIN OPERATION ON ESTIM_OPE.NUM_OPERATION = OPERATION.NUM_OPERATION) ON (ENTREPRISE_SOLLICITE.NUM_CORPS_ETATS = ESTIM_OPE.NUM_CORPS_ETATS) AND (ENTREPRISE_SOLLICITE.NUM_OPERATION = ESTIM_OPE.NUM_OPERATION)) ON ENTREPRISE.NUM_ENTREPRISE = ENTREPRISE_SOLLICITE.NUM_ENTREPRISE
WHERE (((OPERATION.NOM_OPERATION)="ARELLE") AND ((ENTREPRISE_SOLLICITE.DEVIS_RETENUE)=Yes))
ORDER BY ESTIM_OPE.NUM_LOT, ENTREPRISE.NOM_ENTREPRISE;

par

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
PARAMETERS [forms]![Décompte Général Définitif]![NUM_OPERATION] Long;
SELECT OPERATION.NUM_OPERATION, OPERATION.NOM_OPERATION, ESTIM_OPE.NUM_LOT, ENTREPRISE.NOM_ENTREPRISE, ENTREPRISE_SOLLICITE.DEVIS_RETENUE
FROM OPERATION INNER JOIN (ESTIM_OPE INNER JOIN (ENTREPRISE INNER JOIN ENTREPRISE_SOLLICITE ON ENTREPRISE.NUM_ENTREPRISE = ENTREPRISE_SOLLICITE.NUM_ENTREPRISE) ON (ESTIM_OPE.NUM_CORPS_ETATS = ENTREPRISE_SOLLICITE.NUM_CORPS_ETATS) AND (ESTIM_OPE.NUM_OPERATION = ENTREPRISE_SOLLICITE.NUM_OPERATION)) ON OPERATION.NUM_OPERATION = ESTIM_OPE.NUM_OPERATION
WHERE (((OPERATION.NUM_OPERATION)=[forms]![Décompte Général Définitif]![NUM_OPERATION]) AND ((ENTREPRISE_SOLLICITE.DEVIS_RETENUE)=Yes))
ORDER BY ESTIM_OPE.NUM_LOT, ENTREPRISE.NOM_ENTREPRISE;

donc remplacement du filtre sur nom_opéreration sur un filtre NUM_operation avec [forms]![Décompte Général Définitif]![NUM_OPERATION]
du coup quand je lance le code vba j'ai l'erreur "erreur N 3061 trop peu de paramètres 1 attendu"
je suis allé dans ma requete puis bouton droit parametre et j'ai ajoute [forms]![Décompte Général Définitif]![NUM_OPERATION] puis Entier.
Et j'ai modifier le code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Set db = CurrentDb
' Ouvre la requête
Set rs = db.OpenRecordset("SELECT [suivi DGD excel].NOM_OPERATION, [suivi DGD excel].NUM_LOT, [suivi DGD excel].NOM_ENTREPRISE FROM [suivi DGD excel] ORDER BY [suivi DGD excel].NUM_LOT")
' Si vide sortir
If rs.EOF Then GoTo ExitSub

par

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Set db = CurrentDb
' Ouvre la requête
Set rs = db.OpenRecordset("SELECT [suivi DGD excel].NOM_OPERATION, [suivi DGD excel].NUM_LOT, [suivi DGD excel].NOM_ENTREPRISE FROM [suivi DGD excel] ORDER BY [suivi DGD excel].NUM_LOT")
rs.Parameters(0) = Eval(rs.Parameters(0).Name)
' Si vide sortir
If rs.EOF Then GoTo ExitSub

Mais sa ne marche pas. VOus pouvez m'aide Merci

**LedZeppII** · 09/06/2011, 21h15

Bonsoir,

Envoyé par popofpopof

Par contre actuellement il me crée un fichier excel la ou se trouve la base, je souhaite que le fichier s'ouvre et reste ouvert sans crée un fichier déjà enregistre sa sera utilisateur qui choisira de l’enregistre ou non.

Il suffit de pas l'enregistrer, de ne pas le fermer, et enfin de ne pas fermer Excel à la fin du code.
Au début du code, si c'est ce dernier qui crée une instance d'Excel, il faut aussi rendre Excel visible, et empêcher qu'Excel ne se ferme une fois qu'il n'est plus référencé par la variable objet xlApp.

Pour laisser Excel ouvert :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
If xlApp Is Nothing Then
   Set xlApp = CreateObject("Excel.Application")
   xlAppCreated = True
   ' Pour qu'Excel soit visible
   xlApp.Visible = True
   ' Pour qu'Excel ne se ferme pas à la libération
   ' de la variable objet xlApp
   xlApp.UserControl = True
End If

Pour ne pas sauver et fermer le classeur, enlever ces lignes :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
' Pour confirmer l'écrasement du Classeur s'il existe
xlApp.DisplayAlerts = False
' Sauvegarde du Classeur
xlWbk.SaveAs CurrentProject.Path & "\Cmde_" & strope, xlNormal
' Fermeture du Classeur
xlWbk.Close False

Pour ne pas fermer Excel, enlever cette ligne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

If xlAppCreated = True And Not (xlApp Is Nothing) Then xlApp.Quit

A+

**popofpopof** · 09/06/2011, 23h42

Super sa marche comme je souhaité et j'ai compris le cheminement que tu ma fait faire (j'avais déjà essaye de supprime certaine ligne que tu m'a dit je commence a d’amélioré...)

Par contre j'ai toujours ce problème l'erreur "erreur N 3061 trop peu de paramètres 1 attendu"

je te joint un copier du formulaire avec dans la liste déroulante pour te faire comprend mon probléme

**LedZeppII** · 10/06/2011, 19h45

Bonjour,

Il faut passer par un objet QueryDef intermédiaire, pour fournir la valeur du paramètre.
Les références à des contrôles de formulaires sont vus comme des paramètres dans DAO.

Ajouter deux variables qdTmp et qdParam :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
' Variables données sources
Dim db As DAO.Database, rs As DAO.Recordset
Dim qdTmp As DAO.QueryDef, qdParam As DAO.Parameter

Nouveau code d'ouverture de la source de données :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Set db = CurrentDb
' Crée requête temporaire
Set qdTmp = db.CreateQueryDef("", "SELECT [suivi DGD excel].NOM_OPERATION, [suivi DGD excel].NUM_LOT, [suivi DGD excel].NOM_ENTREPRISE FROM [suivi DGD excel] ORDER BY [suivi DGD excel].NUM_LOT")
' Fournit valeurs des paramètres faisant référence à des contrôles de formulaires
For Each qdParam In qdTmp.Parameters
    If qdParam.Name Like "Forms*" Or qdParam.Name Like "[[]Forms*" Then
       qdTmp.Parameters(0).Value = Eval(qdTmp.Parameters(0).Name)
    End If
Next
' Ouvre la requête
Set rs = qdTmp.OpenRecordset()
' Si vide sortir
If rs.EOF Then GoTo ExitSub

A la fin du code ajouter une ligne pour libérer l'objet référencé par la variable qdTmp :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
' Libération des variables objets
Set rs = Nothing
Set qdTmp = Nothing
Set db = Nothing

A+

**popofpopof** · 14/06/2011, 21h04

Super merci bcp j'ai testé sur plusieurs fichier excel et c'est vraiement royal...

..

exportation donnée dans fichier excel [AC-2007]

VBA Access

Discussions similaires

Partager

Partager