Discussion :

[yayasiano]

Bonjour à tous et merci d'avance pour les réponses.

Donc voici mon problème j'ai en fait une macro qui fonctionne mais qui me pose certains soucis pour une modification, voici le code.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Sub Compacoller
 
Dim i, j As Integer
 
    Sheets("analyse").Select
    Range("A1").End(xlDown).Select
        i = ActiveCell.Value
    Sheets("FI").Select
    Range("A1").End(xlDown).Select
        j = ActiveCell.Value
 
            If i >= j Then
 
            ElseIf i < j Then
            Sheets("FI SNCF").Select
            Cells.Find(what:=i).Select
            ActiveCell.Offset(1, 1 - ActiveCell.Column).Select
            Range(Selection, Selection.End(xlDown)).EntireRow.Copy
            Sheets("analyse").Select
            Range("A1").End(xlDown).Offset(1, 0).Select
            ActiveSheet.Paste
            End If
 
End Sub

En fait le soucis est déjà que lorsque i>=j alors je souhaite stopper la macro car aucune cellule n'a besoin d'etre copié dans l'autre onglet.

Si i<j alors la les cellules nouvelles se trouvant dans l'onglet "FI sont copiées puis collées dans l'onglet analyse. Or il arrive un cas ou lors de la recherche de i excel me retourne une erreur en me disant qu'il n'a pas trouvé la valeur de i dans l'onglet "FI".
Lorsque ce cas ce présente j'aimerai pouvoir faire autre chose à savoir copier toutes les lignes de l'onglet FI et les coller a la suite des lignes de l'onglet "analyse"

P.S : La recherche de i est infructueuse car kelkes fois lors de la mise à jour de l'onglet "FI" la ligne ou se trouve la valeur de i est effacée du fait justement de la mise à jour, par exemple :

1er cas, i=4858 ("analyse") j=4858 ou 4551 ("FI") arret macro (il n'a rien a faire)
2eme cas, i=4858("analyse") j=4995("FI"), recherche de i dans ("FI"), i trouvé, copie des lignes de 4858 à 4995 dans '"FI") collage dans ("analyse") à la suite des lignes présentes.
3eme cas, i=4858 ("analyse") j=5112 ("FI"), recherche de i dans ("FI"), i non trouvé, copie de toutes les lignes de ("FI"), collage dans ("analyse") à la suite des lignes présentes.

J'espère avoir été clair.

[Gorfael]

Salut yayasiano et le forum
Comprends pas l'explication, par rapport à la macro. Là, on travaille sur A. Dans le reste de ta macro on ne travaille pas forcément sur A, alors qu'on copie la ligne ??? on travaille sur "FI SNCF", mais pas dans tes explications ??

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Sub Compacoller()
Dim i As Long, j As Long
i = Sheets("analyse").Range("A1").End(xlDown).Row
j = Sheets("FI").Range("A1").End(xlDown).Row
If i >= j Then Exit Sub
'traitement de i<j
End Sub

Le début : i doit avoir aussi la dénomination du type de variable. I et J étant des lignes, il est préférable d'utiliser une variable qui ne plantera pas si le nombre de ligne dépasse les 32767 (2^15=> sur 2003 tu es limité à 65536).
A+

[yayasiano]

en fait FI et FI SNCF sont le meme onglet!!! désolé...

Et je travaille toujours sur A ceci étant la seule liaison que j'ai entre les deux onglets par contre lorsque je copie les données ce sont les lignes entières qu'il me faut.
Concernant ma variable elle dépassera sans doute les 32000 et quelques donc merci du conseil je doit changer le Integer par un koi en fait ??
Et concernant le problème tu n'a toujours pas compris ??
Voici quelques explications qui je l'espère t'aideront:

Je pense que tu as bien compris les 3 cas qui doivent être pris en compte par ma macro. Le fait est que le cas 3 qui intervient lorsque la valeur de i n'est pas trouvée dans l'onget "FI SNCF" est liée au cas 2 car dans ce cas 2 je cherche la cellule dont la valeur est identique à i. Si il ne trouve pas cette valeur le code beugue.

Merci d'avance pour ta réponse jespere.

[Gorfael]

Salut yayasiano et le forum

Concernant ma variable elle dépassera sans doute les 32000 et quelques donc merci du conseil je doit changer le Integer par un koi en fait ??

Je les ai déclarés en Long, parce que j'avais fait la macro sans l'analyser . C'est pas la ligne, mais le contenu de la dernière cellule, et la déclaration en intéger, allié à des noms qu'on attribue généralement à des lignes...

Pour définir tes variables, regarde dans l'aide à "Résumé des types de données" (ou tu surlignes integer => F1 et tu le cherche dans "voir aussi)

La macro

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Sub Compacoller()
'Déclarations -----------------------------------
Dim i As Long, j As Long
Dim F1 As Worksheet, FA As Worksheet
Dim Cel As Range
'MEI --------------------------------------------
Set F1 = Sheets("F1")
Set FA = Sheets("analyse")
' Validité --------------------------------------
i = FA.Range("A" & FA.Rows.Count).End(xlUp)
j = F1.Range("A" & F1.Rows.Count).End(xlUp)
If i >= j Then Exit Sub
'traitement de i<j ------------------------------
'Recherche de i dans F1
Set Cel = F1.Range(F1.[A1], F1.Range("A" & F1.Rows.Count).End(xlUp)).Find(i, LookIn:=xlValues)
'cel= cellule dont le contenu=i dans la plage A1:dernière de A de F1
If Cel Is Nothing Then
'Si cel est vide
    F1.Range(F1.[A1], F1.Range("A" & F1.Rows.Count).End(xlUp)).EntireRow.Copy _
                                    FA.Range("A" & FA.Rows.Count).End(xlUp)(2)
    'copier toutes les lignes de F1 de la ligne 1 à la dernière non vide en A dans la feuille
    'FA à partir de la ligne qui suit la dernière non vide en A
Else
    F1.Range(Cel.Offset(1, 0), F1.Range("A" & F1.Rows.Count).End(xlUp)).EntireRow.Copy _
                                    FA.Range("A" & FA.Rows.Count).End(xlUp)(2)
    'copier toutes les lignes de F1 de la ligne suivant la ligne contenant i en A à la dernière
     'non vide en A dans la feuille FA à partir de la ligne qui suit la dernière non vide en A
End If

J'ai mis des commentaires, mais si ça ne suffit pas demande des explications supplémentaires.
Je n'aime pas utiliser xlDown, mais tu peux adapter
.Copy n'accepte pas .Offset() pour la destination, mais End(xlUp)(2)
revient à End(xlUp).offset(1,0), et il est accepté par .copy

Je suis parti du principe que tu ne voulait pas recopier la ligne contenant l'égalité, mais sinon :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
    F1.Range(Cel.Offset(1, 0), F1.Range("A" & F1.Rows.Count).End(xlUp)).EntireRow.Copy _
                                    FA.Range("A" & FA.Rows.Count).End(xlUp)(2)

devient, en la recopiant dessus l'existante

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
    F1.Range(Cel, F1.Range("A" & F1.Rows.Count).End(xlUp)).EntireRow.Copy _
                                    FA.Range("A" & FA.Rows.Count).End(xlUp)

A+

[yayasiano]

J'ai bien compris ce que tu veux me dire mais ma macro fonctionne bien concernant mes copies de cellules.
Ce que je veux juste en fait c ke le code ne beugue pas lorsqu'il ne trouve pas la valeur de i dans l'autre onglet mais ke je puisse faire autre chose à savoir enchainer sur le 3eme cas c'est tout

[yayasiano]

Merci beaucoup en fait ta macro du haut m'a aidé vraiment à ce que je voulais cela fonctionne parfaitement tout les cas sont pris en compte encore merci.

[AlainTech]

Problème résolu?

Bouton , en bas de discussion!

Merci