Discussion :

[azzangot]

Bonjour à tous,
J'ignore si le sujet a déjà été évoqué ici, sans doute que oui, hélas n'étant pas suffisamment averti en programmation VBA, j'ai du mal à retrouver dans la FAQ l'information qui me permettrait d'atteindre mon objectif.
J'aimerais, à l'aide d'une procédure qui serait enregistrée dans un module, pouvoirs réaliser la tache suivante:

Il y a 2 tables dans ma base de données nommée Acces_Abs.accbd
La table T_Absence et la table T_Absence_Det

Dans la table T_Absence, pour chaque enregistrement, il y a une date de début et une date de fin avec un motif d'absence et le nombre de jours d'absence qui correspond à la différence entre les 2 dates.
Je souhaite copier les enregistrements de cette table vers la table T_Absence_Det, tout en les dupliquant autant de fois que le nombre de jour d'absence et en incrémentant la date de 1 en 1 à a chaque fois.

exemple sur 2 enregistrements :

T_Absence.

PIERRE ; ABSENCE 1 ; 08/03/2021 ; 10/03/2021 ; 3 jrs
PAUL; ABSENCE 4; 01/03/2021 ; 05/03/2021 ; 5 jrs


T_Absence_Det.

PIERRE ; ABSENCE 1 ; 08/03/2021
PIERRE ; ABSENCE 1 ; 09/03/2021
PIERRE ; ABSENCE 1 ; 10/03/2021
PAUL; ABSENCE 4; 01/03/2021
PAUL; ABSENCE 4; 02/03/2021
PAUL; ABSENCE 4; 03/03/2021
PAUL; ABSENCE 4; 04/03/2021
PAUL; ABSENCE 4; 05/03/2021

Vous trouverez, en pièce jointe, la BDE en question.
En vous remerciant par avance, pour l'aide que vous voudrez bien m'apporter,
cordialement,
azzangot

[f-leb]

Bonsoir,

Tu peux faire ça de façon efficace avec une table de comptage qui comporte un seul champ n et des lignes n= 0, n=1, n=2, n=3, n=4, etc.

La requête qui suit fait le boulot :

Code sql :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
SELECT [identifiant], [nom usuel], [prénom], [type absence], [début absence] + n AS date_absence
FROM T_Absence, comptage
WHERE [fin absence]-[début absence] >= n;

[azzangot]

Bonsoir f-leb et merci d'avoir répondu, même si je vois pas tres bien ce que tu entends par table de comptage ?
Sincèrement je comprends pas ton idée.
Peut être que tu peux me préciser tout ca ?

Merci,
A+

[f-leb]

Une table toute bête

Elle s'appelle comptage, et elle a un seul champ n :

[hyperion13]

Salut
Une solution en VBA. Le code se trouve dans un module de formulaire et est déclenché par un bouton de commande.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
Sub detabsence()
On Error GoTo ErrorHandler
Dim dbs As DAO.Database
Dim rstSource As DAO.Recordset, rstCible As DAO.Recordset
Dim strSqlS As String, strSqlC As String
Dim i As Integer, j As Integer
 
Set dbs = CurrentDb
 
strSqlS = "SELECT id, identifiant, nom_usuel, prenom, type_absence, debut_absence, fin_absence, nb_jours" _
        & " FROM tblAbsences"
strSqlC = "SELECT id_det, identifiant, nom_usuel, prenom, type_absence, date_absence" _
        & " FROM tblAbsencesdet"
 
Set rstSource = dbs.OpenRecordset(strSqlS, dbOpenSnapshot)
Set rstCible = dbs.OpenRecordset(strSqlC, dbOpenDynaset)
 
rstSource.MoveLast
rstSource.MoveFirst
 
Do While Not rstSource.EOF
    i = 0
    j = rstSource("nb_jours")
    Do Until i = j
        rstCible.AddNew
        rstCible!identifiant = rstSource!identifiant
        rstCible!nom_usuel = rstSource!nom_usuel
        rstCible!prenom = rstSource!prenom
        rstCible!type_absence = rstSource!type_absence
        rstCible!date_absence = rstSource!debut_absence + i
        rstCible.Update
        i = i + 1
    Loop
    rstSource.MoveNext
Loop
Exit Sub
ErrorHandler:
   MsgBox "Error #: " & Err.Number & vbCrLf & vbCrLf & Err.Description
End Sub

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub Commande0_Click()
    detabsence
End Sub

[azzangot]

Un grand MERCI Hyperion13 ! ca fonctionne nickel !
En parcourant quelques explications sur le net au sujet d'access, j'avais compris que c'etait avec l'objet Recodset que ca pouvait se faire,
mais sincèrement, je n'y serais pas parvenu. Je ne suis pas assez averti pour cela.
En lisant le code que tu m'as écrit, j'ai des questions qui me viennent à l'esprit :

Pourquoi il y a le préfixe DAO ? DAO.Database, DAO.Recodset... ?

Pourquoi ces 2 commandes s'enchainent l'une à la suite de l'autre ?
rstSource.MoveLast
rstSource.MoveFirst

Question subsidiaire !
Combien d'années d'expérience en programmation VBA as tu ?

Encore mille merci !
C'est vraiment TOP !

[hyperion13]

Vous avez des notions DAO ici
N'oubliez pas de clôturer le sujet.

[azzangot]

Un grand merci à vous !
J'irai voir les explication dans le lien que vous m'avez envoyé
et je clos mon dossier ce jour.
Merci, bonne journée !