Discussion :

[Malick]

Bonjour,

Comment pourrais-je adapter cette formule pour lui dire de faire le cumul pour les comptes commençant pas 62 ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD((Tableau1[COMPTE]=62250000)*(Tableau1[MONTANT]))

quelque chose comme ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD((Tableau1[COMPTE]=62*)*(Tableau1[MONTANT]))

Merci d'avance

[78chris]

Bonjour

A tester

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD((Gauche(Tableau1[COMPTE];2)="62")*(Tableau1[MONTANT]))

[Malick]

Salut 78chris,

Super

Pour rendre dynamique, si je met le contenu de la condition dans une cellule D4, la formule retourne 0:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD((GAUCHE(Tableau1[COMPTE];2)="D4")*(Tableau1[MONTANT]))

[78chris]

RE

D4 est une adresse pas un texte donc enlève les ""

Éventuellement D4&""

[Malick]

RE

D4 est une adresse pas un texte donc enlève les ""

En enlevant seulement les "", la fonction retourne 0

Éventuellement D4&""

Avec cela, elle fonctionne très bien

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD((GAUCHE(Tableau1[COMPTE];2)=D4&"")*(Tableau1[MONTANT]))

Juste que je ne comprends pas la concaréation et son rôle, mais cela fonctionne très bien.

Merci beaucoup, je passe en

[ARTURO83]

Bonjour,

Si la condition est en cellule D4, il faut que dans la formule, vous convertissiez la valeur numérique en texte et sans décimales, ce qui donne:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD((GAUCHE(Tableau1[COMPTE];2)=CTXT($D$4;0))*(Tableau1[MONTANT]))

Cdlt

[78chris]

Bonjour

C'est effectivement lié au type de données

Dans ma formule en concaténant le contenu de D4, sans doute numérique, avec une chaîne vide on en change le type pour comparer avec le texte renvoyé par la fonction GAUCHE
Si les numéros de comptes sont en numérique cela ne gêne pas car la fonction GAUCHE va les assimiler à du texte.

La concaténation pourrait être évitée si D4 était en format texte avant la saisie d'où mon Éventuellement D4&""

CTXT est une autre solution pour convertir D4 en texte

[Pierre Fauconnier]

Salut Tout le monde,

@Malick, si tes comptes sont sur 8 chiffres, tu peux tester la plage numérique, ici avec SOMME.SI.ENS, mais ce serait la même logique avec SOMMEPROD: =SOMME.SI.ENS(Tableau1[Valeur];Tableau1[Compte];">="&62000000;Tableau1[Compte];"<"&63000000)

Cela dit, si tu ramènes tes données par Power Query, ce pourrait être une bonne chose de transformer la colonne en texte, puisque les numéros de compte ne sont en fait pas des valeurs numériques (on ne réalise normalement pas d'opérations arithmétiques dessus). Ca te permettrait par exemple de recréer les classes et les rubriques pour une exploitation plus fine, que ce soit par regroupement en PQ ou par TCD en Excel.

[Malick]

Merci Pierre