Discussion :

[cocopops78]

Bonjour

Je souhaiterais enregistrer dans un fichier pdf un range de cellule.
J'ai trouvé ce code que j'ai adapté mais ça ne fait pas mon pdf à l'endroit indiqué.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
 
sRep = "C:\Temp"
sFilename = "toto"&"-"&Now&"." & "pdf"     ' Nom du fichier
 Range("B2:G16").Select
Selection.ExportAsFixedFormat _
                     Type:=xlTypePDF, _
                     Filename:=sRep & SFilename, _
                     Quality:=xlQualityStandard, _
                     IncludeDocProperties:=True, _
                     IgnorePrintAreas:=False, _
                     OpenAfterPublish:=True

Autre question, je souhaiterais que le nom du fichier porte la date + heure d'impression ( 'Now') mais visiblement ca ne plait psa à VBA:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
sFilename = "toto"&"-"&Now&"." & "pdf"

Merci de l'aide .

[Invité]

Bonjour,

Une solution possible. A vous de réorganiser la fonction si l'ordre année, mois, jour ne vous convient pas. Mais si vous avez plusieurs fichiers du même nom, la recherche en est plus facile dans un répertoire.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
 
Option Explicit
 
Function GroupeDateHeure() As String
 
Dim MaDate As Variant
Dim HeureEnCours As Variant
 
    MaDate = Split(CStr(Date), "/")
    HeureEnCours = Split(Time, ":")
    GroupeDateHeure = MaDate(2) & "-" & MaDate(1) & "-" & MaDate(0) & " H " & Join(HeureEnCours, "-")
 
End Function
 
 
Sub Essai()
 
Dim SRep As String, SFilename As String
 
'SRep = ActiveWorkbook.Path
SRep = "C:\Temp"
SFilename = "toto" & " " & GroupeDateHeure & "." & "pdf"     ' Nom du fichier
Range("B2:G16").ExportAsFixedFormat _
                     Type:=xlTypePDF, _
                     Filename:=SRep & "\" & SFilename, _
                     Quality:=xlQualityStandard, _
                     IncludeDocProperties:=True, _
                     IgnorePrintAreas:=False, _
                     OpenAfterPublish:=True
 
End Sub

[cocopops78]

Super ça marche nickel !

[cocopops78]

Super ça marche nickel !

Dans mon esprit je pensais que créer un PDF nécessitait de passer par un logiciel type PDFCREATOR; qu'il fallait donc faire une passerelle entre VBA et PDF pour générer le pdf.

[patricktoulon]

Bonsoir Eriic et cocopops78

il y a un moyen plus simple avec format

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Function GroupeDateHeure() As String
    GroupeDateHeure = Format(Now(), "yyyy-mm-dd ""H"" hh-nn-ss")
End Function
Sub test()
    MsgBox GroupeDateHeure
End Sub

le "H" a la base pour format devrait être un caractère en trop et en temps normal pris pour l'unité des heures ,alors on le met entre doublequotes c'est magique

un exemple qui va peut être mieux vous parler

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Sub tests()
MsgBox Format(78, """cocopops""00")
End Sub

pratique pour la création de référence plutôt que la concaténation de split

[clementmarcotte]

Bonjour,

Dans mon esprit je pensais que créer un PDF nécessitait de passer par un logiciel type PDFCREATOR; qu'il fallait donc faire une passerelle entre VBA et PDF pour générer le pdf.

Cela dépend de la version d'Office. Cela a été rendu possible entre Office 2007 et Office 2010. Pour Office 2007, il faut soit avoir ajouté la mise à jour, (gratuite sur le site de MS), soit avoir acheté une version qui incluait déjà la mise à jour. Pour Office 2010 et après c'est "automatique".