Discussion :

[tommy.bezeau]

Bonjour,

J'aimerais mettre en place un formulaire de recherche me permettant de trouver rapidement des informations de ma base de données. Pour le moment j'essaye que lorsque j'entre le numéro de PO dans ma textBOx et que je click sur rechercher, que les informations relatives au po soit afficher. Néanmoins mon code ne fonctionne pas pour le moment, pourreiz vous m'aider?

[patricktoulon]

bonsoir
le code c'est pas en image qu'il nous le faut

cela dit rien qu'avec la capture
on distingue bien la méprise sur les Object

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

if trim(bd.cells(i,2)=trim(bd.text)

dis moi un peu c'est quoi "bd" comme object ??????

et c'est pas la seule erreur dans le peu de ligne que ta capture montre

colle moi ton code entre balise code(bouton #)
qu'on puisse avoir une vue d'ensemble

une autre erreur tout du moins un e autre méprise qui va en déclencher une autre
if textbox0="" then
msgbpx".......
end if

sauf qu'après le message quand tu l'aura fermé(OK) la macro continuera et donc va chercher du vide dans ta BDD
et de deux

[tommy.bezeau]

[...]

dis moi un peu c'est quoi "bd" comme object ??????[...]

Bd est le nom de la page Base de Donnés

[tommy.bezeau]

Relance des transport ArcelorMittal.xlsm

Je ne suis pas certains de bien faire les choses j'ai essayer de faire les modifications que vous m'avez proposées mais mon VBA à continuer de bugger. Je sais que ça doit être simple pour vous mais je ne réussit pas à faire la modification. En somme, tout ce que je veux c'est lorsque je me log sur le Userform ChercherModifier, que si j'inscrit un numéro de PO Valide les informations soit inscrite. Et que je puisse modifier la 2eme et 3 eme relance. Je ne sais pas si vous seriez en mesure de m'aider car je me considère débutant et j'ai de la difficulté a bien tout amalgamer ensemble.

Je sais pas si vous êtes capable de m'aider car je ne réussit pas à compléter cette fonction. Néanmoins, ma fonction ajouter un nouveau po fonction à 100 % Merci d'avance pour votre aide.

[Pierre Fauconnier]

Salut.

Tu aurais intérêt à travailler avec des tables de données (tableaux structurés : Mon tuto sur le sujet).



Voici un code du userform qui réalise cela, sur base d'un tableau d'exemple appelé T_BO, et d'un userform muni des textbox tboPO, tboCustomer et tboDate. Au clic sur le bouton BtnSearch, on recherche le PO grâce à Evaluate qui permet d'évaluer en VBA une formule Excel (exprimée en Excel international). Si la valeur est trouvée, on travaille avec la plage de la ligne de la table et on récupère les données pour les pousser dans les textbox. Ici, je me sers du nom des colonnes plutôt que de leur place pour faciliter la maintenance en cas d'insertion de colonnes dans la table.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Option Explicit
 
Private Sub btnSearch_Click()
  If Not tboPO.Value = "" Then
    If SearchAndComplete(tboPO.Value) = False Then
      MsgBox "PO non trouvé"
    End If
  Else
    MsgBox "Veuillez compléter le PO"
  End If
End Sub
 
Function SearchAndComplete(POValue As String) As Boolean
  Dim Formula As String
  Dim RowIndex As Long
  Dim PORow As ListRow
 
  Formula = "iferror(match(""" & POValue & """,t_PO[PO],0),0)"
  RowIndex = Evaluate(Formula)
  If RowIndex > 0 Then
    Set PORow = Range("t_PO").ListObject.ListRows(RowIndex)
    tboCustomer.Value = PORow.Range(Range("t_PO").ListObject.ListColumns("Client").Index)
    tboDate.Value = Format(PORow.Range(Range("t_PO").ListObject.ListColumns("Date").Index), "dd/mm/yyyy")
    SearchAndComplete = True
  End If
End Function

Ici, pour l'exemple, il y a peu de colonnes, mais idéalement, on travaillerait avec un array de mappage entre les noms des colonnes et les contrôles du useform pour réaliser le transfert en une boucle plutôt qu'en x lignes.

Voici le code du userform modifié. J'y ai déclaré une propriété publique autoimplémentée Map qui reçoit la table de mappage au chargement. Le code de la fonction de transfert a été modifié pour travailler avec une boucle.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
Option Explicit
 
Public Map
 
Private Sub btnSearch_Click()
  If Not tboPO.Value = "" Then
    If SearchAndComplete(tboPO.Value) = False Then
      MsgBox "PO non trouvé"
    End If
  Else
    MsgBox "Veuillez compléter le PO"
  End If
End Sub
 
Function SearchAndComplete(POValue As String) As Boolean
  Dim Formula As String
  Dim RowIndex As Long
  Dim PORow As ListRow
  Dim Counter As Long
 
  Formula = "iferror(match(""" & POValue & """,t_PO[PO],0),0)"
  RowIndex = Evaluate(Formula)
  If RowIndex > 0 Then
    Set PORow = Range("t_PO").ListObject.ListRows(RowIndex)
    For Counter = LBound(Map) To UBound(Map) Step 3
      Select Case Map(Counter + 2)
        Case "String"
          Controls(Map(Counter + 1)).Value = PORow.Range(PORow.Parent.ListColumns(Map(Counter)).Index)
        Case "Date"
          Controls(Map(Counter + 1)).Value = Format(PORow.Range(PORow.Parent.ListColumns(Map(Counter)).Index), "dd/mm/yy")
      End Select
    Next
    SearchAndComplete = True
  End If
End Function

Le userform est chargé et affiché grâce à une procédure d'un module standard

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Sub Test()
  With usrPO
    .Map = VBA.Array("Client", "tboCustomer", "String", "Date", "tboDate", "Date")
    .Show
  End With
  Unload usrPO
End Sub