Discussion :

[pacolapin]

Bonjour, dans mon programme j'importe mon fichier texte et je le passe en excel mais, je suis obliger de l'ouvrir dans un nouvel excel pour avoir la bonne tabulation.
J'aimerai qu'il puisse s'ouvrir depuis l'excel déjà en fonction avec la bonne tabulation.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
 
Private Sub Importer_Click()
Dim fichier_choisi As String
 
fichier_choisi = Application.GetOpenFilename("text files(*.txt),*.txt", , "Sélectionner un ficher CSV")
 
If (LCase(fichier_choisi) <> "faux" And fichier_choisi <> "0") Then
liste_fichier.AddItem (fichier_choisi)
If Right(fichier_choisi, 3) = "xls" Then
Workbooks.Open fichier_choisi
Else
Workbooks.OpenText fichier_choisi, Tab:=True, Semicolon:=True, local:=True

Voilà e que j'ai tapé,

Pourriez vous m'aidez ?

[patricktoulon]

Bonjour
ton fichier text s'ouvre tres bien
juste le format des nombres qui a pour séparateur décimal le point et ca n'ira pas pour les éventuels calculs

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
 
Sub test()
    Dim fichier_choisi As Variant
    fichier_choisi = Application.GetOpenFilename("text files(*.txt),*.txt", , "Sélectionner un ficher CSV")
    If fichier_choisi = False Then Exit Sub
    If Right(fichier_choisi, 3) = "xls" Then    ' in ne peut pas y avoir de "xls" car tu filtre que les ".txt" dans getopenfilname
        Workbooks.Open fichier_choisi
    Else
        Workbooks.OpenText fichier_choisi, local:=True
        With ActiveSheet
             tablo = .UsedRange.Value
            .UsedRange.Clear
            .Range("B:B").NumberFormat = "h:mm;@"
            .Range("A:A").NumberFormat = "DD/MM/YYYY"
            .Cells(1, 1).Resize(UBound(tablo), UBound(tablo, 2)).Value = tablo
        End With
    End If
End Sub

edit:
format de tes cellules et de tes valeurs corrigées et exploitables en tant que date pour la colonne "A", heure pour la colonne" et nombre et standard pour les autres

[pacolapin]

Merci pour le coup de main pour la tabulation, mais ce que je n'arrive pas à faire c'est d'ouvrir le fichier texte dans mon excel import-export, je ne veux pas qu'il s'ouvre avec un nouvel excel.

Je te remercie.

[patricktoulon]

re
la chose que tu demande est impossible avec open(/text) directement il faut rapatrier les données du 2 au 1 puis fermer le 2
sinon tu a querytable, adobconnection ou open for output en mémoire

c'est pas le choix de méthode qui manque

[patricktoulon]

tiens voila

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Sub test()
    Dim fichier_choisi As Variant,Wb,tablo
    fichier_choisi = Application.GetOpenFilename("text files(*.txt),*.txt", , "Sélectionner un ficher CSV")
    If fichier_choisi = False Then Exit Sub
 
    Application.ScreenUpdating = False
    If Right(fichier_choisi, 3) = "xls" Then    ' in ne peut pas y avoir de "xls" car tu filtre que les ".txt" dans getopenfilname
        Workbooks.Open fichier_choisi
    Else
        Workbooks.OpenText fichier_choisi, local:=True
        Set wb = ActiveWorkbook
        With ActiveSheet
            tablo = .UsedRange.Value
            .UsedRange.Clear
            .Range("B:B").NumberFormat = "h:mm;@"
            .Range("A:A").NumberFormat = "DD/MM/YYYY"
            .Cells(1, 1).Resize(UBound(tablo), UBound(tablo, 2)).Value = tablo
            .UsedRange.Copy Destination:=ThisWorkbook.Sheets(1).Cells(1)    'on rapatrie sur le classeur 1
            Application.DisplayAlerts = False
            ActiveWorkbook.Close
        End With
    End If
End Sub

[patricktoulon]

pour info a ca que je t'ai dis au debut en ce qui concerne ton getopenfilename avec ta condition qui ne peut fonctionner

voici 3 exemple de syntaxe pour ouvrir différentes extensions de fichiers

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub test2()
'
'tout les fichier ".txt" et ".xls**"(tout fichier excel de 2000 a 2019 EXPLICITEMENT
fichier_choisi = Application.GetOpenFilename(FileFilter:=" txt file or  Excel Files ( *.txt;*.xlsx;*.xls;*.xlsm), ( *.txt;*.xlsx;*.xls;*.xlsm), All Files, *.*", FilterIndex:=1)
'
'
'rien que les ".txt" et ".xls"EXPLICITEMENT
'fichier_choisi = Application.GetOpenFilename(FileFilter:=" txt file or  Excel Files Under 2007 ( *.txt;*.xls), ( *.txt*.xls), All Files, *.*", FilterIndex:=1)
'
'
'tout les fichier ".txt" et ".xls**"(tout fichier excel de 2000 a 2019 les format différents Excel sont IMPLICITES PAR cette syntaxe ("*.XLS*")
fichier_choisi = Application.GetOpenFilename(FileFilter:=" txt file or  Excel Files ( *.txt;*.xls*), ( *.txt*.xls*), All Files, *.*", FilterIndex:=1)
'etc... etc ....
End Sub

bonne route

[patricktoulon]

re
et voila directement sur ton classeur avec querytable et en corrigeant les format de cellules nécessaires
quasiment instantané!!!

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
Sub testquerytable2()
    Dim fichier_choisi As Variant
    fichier_choisi = Application.GetOpenFilename(FileFilter:=" txt file or  Excel Files ( *.txt;*.xls*), ( *.txt*.xls*), All Files, *.*", FilterIndex:=1)
    If fichier_choisi = False Then Exit Sub
    If LCase(Mid(fichier_choisi, InStrRev(fichier_choisi, ".") + 1)) = "txt" Then
        With ActiveSheet.QueryTables.Add(Connection:="TEXT;" & fichier_choisi, Destination:=Range("$A$1"))
            .FieldNames = True
            .PreserveFormatting = True
            .RefreshStyle = xlInsertDeleteCells
            .SaveData = True
            .AdjustColumnWidth = True
            .RefreshPeriod = 0
            .TextFilePromptOnRefresh = False
            .TextFilePlatform = 850
            .TextFileStartRow = 1
            .TextFileParseType = xlDelimited
            .TextFileTextQualifier = xlTextQualifierDoubleQuote
            .TextFileTabDelimiter = True
            .TextFileColumnDataTypes = Array(4, 1)
            .TextFileTrailingMinusNumbers = True
            .Refresh BackgroundQuery:=False
            .Delete
        End With
        With ActiveSheet
            tablo = .UsedRange.Value
            .UsedRange.Clear
            .Range("A:A").NumberFormat = "DD/MM/YYYY"
            .Range("B:B").NumberFormat = "h:mm;@"
            .Cells(1, 1).Resize(UBound(tablo), UBound(tablo, 2)).Value = tablo
        End With
    Else
        ' faire ce qu'il faut ici si c'est un "xls" ou xlsx,xlsm,xla,etc.....
 
    End If
 
End Sub

[pacolapin]

Salut Patrick, voilà j'ai repris ton code et il fonctionne très bien, j'aimerai faire une dernière modification que j'ai cherché avec plusieurs possibilité, qui est de mettre directement mon fichier texte dans la feuille de calcul "import - export", j'essayé avec des système comme sheet("import - export") etc mais en vain et je pense que c'est la ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

With ActiveSheet.QueryTables.Add(Connection:="TEXT;" & fichier_choisi, Destination:=Range("$A$1"))

qui m’embête et plus particulièrement ActiveSheet car si je suis sur une autre page pour un graphique je ne peux pas importer un autre fichier texte et j'ai une erreur d’exécution.
Comment faire ?
Je te remercie d'avance.