Discussion :

[Tomih]

Bonjour à tous,

Je suis nouveau sur le forum et je débute en VBA. Voici ma problématique :

Je souhaite dans une plage de donnée variable supprimer les lignes dont les valeurs de la colonne C sont des chiffres(de 0 à 1 000 000) à partir de la ligne 10.
Les autres cellules de la colonne C contiennent soit du texte ou elles sont vides la plus part du temps.




Merci d'avance pour votre aide.

[QuestVba]

Salut,
Tu veux vraiment du vba ? Moi je te propose de mettre une colonne supplémentaire que tu pourras retirer après. Dans celle-ci tu indiques

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

= ISNUMBER (GAUCHE (C2) * 1)

Ainsi tu auras toutes tes cellules marquées par true ou false. Tu tries et tu effaces tes lignes.

[Tomih]

Merci pour ta réponse. Mais j'ai besoin d'une solution en VBA, c'est une procédure à mettre en place dans mon code...

[Patrice740]

Bonjour,

Merci pour ta réponse. Mais j'ai besoin d'une solution en VBA, c'est une procédure à mettre en place dans mon code...

Essaies ce code, pour des nombres, mais pas pour des chiffres (un chiffre c'est du texte qui représente un nombre) :

Code VBA :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Option Explicit
Sub Test()
Dim rngData As Range
  Set rngData = ActiveSheet.Range("C10").CurrentRegion 'à adapter éventuellement
  Call SupprimerLignesSiChiffreEnColonneC(rngData)
End Sub
Sub SupprimerLignesSiChiffreEnColonneC(rng As Range)
Dim col As Range
Dim noL As Long
  Set col = rng.Parent.Columns("C:C")
  If Intersect(rng, col) Is Nothing Then Exit Sub  'pas de colonne C dans la plage
  noL = rng.Row + rng.Rows.Count - 1
  If noL < 10 Then Exit Sub                        'pas de ligne 10 dans la plage
  Application.ScreenUpdating = False
  For noL = rng.Row + rng.Rows.Count - 1 To 10 Step -1
    If VarType(rng.Parent.Cells(noL, "C").Value) = vbDouble Then
      rng.Rows(noL - rng.Row + 1).Delete shift:=xlShiftUp
    End If
  Next noL
  Application.ScreenUpdating = True
End Sub

[Tomih]

Merci beaucoup pour ton aide ça fonctionne parfaitement !

[MarcelG]

Bonjour,

Sauf si le test de valeur numérique porte sur le type (Integer, Long..), il y a beaucoup plus simple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Option Explicit
 
Sub suppr_nombres()
 
Dim derl As Integer
 
With Worksheets(1)
    derl = .Cells(.Rows.Count, 3).End(xlUp).Row
    With .Range("C10:C" & derl)
            .SpecialCells(xlCellTypeConstants, 1).Replace What:="*", Replacement:=""
            .SpecialCells(xlCellTypeBlanks).EntireRow.Delete
    End With
End With
 
End Sub

[Patrice740]

Je souhaite dans une plage de donnée variable supprimer les lignes dont les valeurs de la colonne C sont des chiffres(de 0 à 1 000 000) à partir de la ligne 10.
Les autres cellules de la colonne C contiennent soit du texte ou elles sont vides la plus part du temps.

..., il y a beaucoup plus simple

Mais ça supprime aussi les lignes des cellules vides !

[MarcelG]

Salut Patrice,

Au temps pour moi.
Astuce : le remplacement se fera alors par une formule retournant une erreur, puis suppression des lignes où la cellule formulée retourne une erreur

Soit

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Option Explicit
 
Sub suppr_nombres()
 
Dim derl As Integer
 
With Worksheets(1)
    derl = .Cells(.Rows.Count, 3).End(xlUp).Row
    With .Range("C10:C" & derl)
            .SpecialCells(xlCellTypeConstants, 1).Replace What:="*", Replacement:="=3/0"
            .SpecialCells(xlCellTypeFormulas, xlErrors).EntireRow.Delete
    End With
End With
 
End Sub

[Patrice740]

Salut Patrice,
Astuce : le remplacement se fera alors par une formule retournant une erreur, puis suppression des lignes où la cellule formulée retourne une erreur

Quand on est parti avec une idée, c'est difficile de la quitter ...
Mais si une erreur dans une cellule est peu probable, il n'est pas improbable !

Pourquoi pas tout simplement et directement :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Option Explicit
Sub suppr_nombres()
Dim derl As Integer
  With Worksheets(1)
    derl = .Cells(.Rows.Count, "C").End(xlUp).Row
    .Range("C10:C" & derl).SpecialCells(xlCellTypeConstants, 1).EntireRow.Delete
  End With
End Sub

[MarcelG]

Tout à fait Patrice. Je voulais corriger mon premier post.

Mon message était que la suppression de lignes basée sur une valeur de cellule peut dans nombre de cas être gérée par les cellules spéciales.
Pour ma part, je le fais en 2 temps: un remplacement par une erreur ou un vide puis suppression des lignes correspondant aux cellules spéciales.

Autre point, on oublie souvent, moi le premier, qu'il peut y avoir un 2ème argument à la propriété SpecialCells.