Discussion :

[Tetentine]

Bonjour,

Je débute sur VBA et je souhaite simplifié le code d'un excel que j'ai créé. Malheureusement, je bloque sur une boucle if: mon objectif est si une cellule C(i) est vide, alors il faut remplacer sa valeur par C(i+1) , i.e. si C3 = "" => C3=C4.

J'ai rédigé le code suivant et rien ne se passe (pas de message d'erreur, mais pas d'action non plus sur mon classeur...).

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
 
 
Sub FILLING_CELLS(Sheet As String, Column As String)
 
Dim i As Integer
Dim j As Integer
Dim lastrow As Long
Dim ligne As Long
Dim linge1 As Long
 
 
j = i + 1
lastrow = Cells(Application.Rows.Count, 2).End(xlDown).Row
ligne = i
ligne1 = j
 
For i = 4 To lastrow
    If Worksheets(Sheet).Range(Column & ligne).Value = "" Then
        Worksheets(Sheet).Range(Column & ligne).Value = Worksheets(Sheet).Range(Column & ligne1).Value
    End If
 
Next i
 
End Sub

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
 
 
Sub TEST()
 
Call FILLING_CELLS("DATA P6 EXPLOITATION", "C")
 
End Sub

Merci pour votre aide

[MarcelG]

Bonjour et bienvenu,

Pourquoi VBA?

Si tu tiens au code

Evite de choisir des noms clés de VBA comme variable (Sheet, column)

Il y a redondance

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
ligne = i
ligne1 = j

De plus, ces égalités sont placées en tout début de code.
A cela s'ajoutent le rattachement non effectué des objets Range, les blocs With inexistants....

A comprendre puis adapter

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Sub monTEST()
 
Call FILLING_CELLS("DATA P6 EXPLOITATION", "C")
 
End Sub
 
Sub FILLING_CELLS(nomwks As String, lacolonne As String)
 
Dim lastrow As Long
Dim c As Range
 
 Application.ScreenUpdating = False
 
With Worksheets(nomwks)
 
        lastrow = .Cells(.Rows.Count, 2).End(xlUp).Row
 
        For Each c In .Range(lacolonne & "2:" & lacolonne & lastrow).SpecialCells(xlCellTypeBlanks)
 
                With c
 
                    .Value = .Offset(0, 1).Value
 
                End With
 
        Next c
 
End With
 
End Sub

Pour l'objet Range en général, et la méthode SpecialCells en particulier, tu peux consulter cet espace documentaire:

L'objet Range

[Menhir]

C'est une très mauvaise idée de donner à des variables le nom d'objets existants.

Autre problème, tu donnes à la variable j la valeur de i+1 mais tu ne donnes pas de valeur à i...

Mais ce que tu fais de travers, c'est surtout l'affectation des variable ligne.
J'ai l'impression que tu crois qu'en écrivant "ligne = i", alors dans tout le code ligne sera toujours égal à la valeur de la variable i.
Ce n'est pas le cas. Quand on écrit ça, on donne à la variable ligne la valeur de i à l'instant où l'exécution passe sur cette ligne.
Si, par la suite, la valeur de i change, la valeur de ligne restera la même.
Idem pour le j=i+1.

Autre détail : pour le calcul de lastrow, tu n'indiques pas le nom de la Worksheet concernée.

Dernière chose : pour ta procédure, il faut aller du bas vers le haut et non l'inverse.
Réfléchis : si C1="", C2="" et C3="A", si tu vas du haut vers le bas, au premier tour la macro verra que C1 est vide et y mettra la valeur de C2, c'est-à-dire un vide.

Encore un truc : dans ta recherche de la dernière ligne remplie, tu parts de la dernière ligne possible (Rows.Count) et du demande de rechercher vers le bas (xlDown). Il y a peu de chance que la macro y trouve des cellules remplies.

Donc, si je n'ai rien oublié :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Sub FILLING_CELLS(Feuille As String, Colonne As String)
Dim ligne As Long
 
With Worksheets(Feuille)
    For Ligne = .Cells(Rows.Count, Colonne).End(xlUp).Row To 4 Step -1
        With .Range(Colonne & ligne)
            If .Value = "" Then .Value = .Offset(1, 0).Value
        End With
    Next Ligne
End With
 
End Sub

Je n'ai pas testé, tu auras donc peut-être du débugage à faire.

[MarcelG]

Oui Menhir.
Nos réponses s'entrecroisent et se complètent.
Pour ma part, utiliser SpecialCells, comme je l'ai fait, est, modestement, plus performant, non?

[Menhir]

Pour ma part, utiliser SpecialCells, comme je l'ai fait, est, modestement, plus performant, non?

Le problème, c'est s'il y a deux cellules vides successives : aller de haut en bas ne suffira pas à boucher le trou.
C'est pour ça que j'ai exclu For Each qui ne sait pas aller à contre-sens. Et sans le For Each, difficile d'utiliser SpecialCells.

Cela dit, si le cas de deux cellules vides successives n'a aucune chance de se produire, c'est effectivement une bonne idée.

[MarcelG]

Je viens de tester mon code.
Il est effectif. Ce même si 2 cellules successives sont vides.
Ou quelque chose m'échappe?

[Menhir]

Si on a les ligne 4 et 5 (par exemple) qui sont vides, quelle valeur est mise à la ligne 4 ? Celle de la ligne 5 qui elle aussi est vide et n'a pas encore été touchée par le code ?
Je ne vois pas comment il serait possible que la première des deux lignes soit renseignée.

En regardant de plus près ton code, je vois que tu mets dans les cellules vide la valeur de la colonne de droite.
A priori, ce n'est pas ce qui était demandé. Il faut remplir les cellules vides avec la valeur de la ligne en dessous.