Discussion :

[hyacintheCARA]

Bonjour,
je veux développer sur VBA un programme qui permettra à l'utilisateur de choisir les feuilles d'un classeur et les colonnes qu'il veut sur une feuille output.
La première phase, je veux que le programme puisse récupérer l'ensemble des informations (nom de chaque feuille, entête des colonnes) du classeur et les positionner sur un tableau de la feuille active.
Mon code ne fonctionne pas et je sollicite votre expertise pour savoir ce qui ne va pas et aussi des propositions.

Voici le code.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub essai1()
Dim i, j As Integer
Dim Nom_feuille As Worksheet
 
ThisWorkbook.Activate
For j = 2 To Workbooks("Fichier_choisi.xlsx ").Worksheets.Count
Worksheets("Feul1 ").Cells(j, 1).Value = Workbooks(" Fichier choisi.xlsx ").Worksheets(j - 1).Name
         If Worksheets(" Feuil1 ").Cells(j, 1).Value <> " " Then
            Nom_feuille = Worksheets("Feuil1").Cells(j, 1).Value
        Do While Cells(1, i).Value <> ""
       ThisWorksheet.Cells((j + 1), 3).End(xlDown).Row.Value = Workbooks("Fichier_choisi.xlsx").Worksheets("Nom_feuille").Cells(1, i).Value
     i = i + 1
     Loop
     End If
 
Next
End Sub

[patricktoulon]

Bonjour

1. on ne voit pas dans ton code si le fichier choisi est ouvert
2. ta boucle do loop sur i doit planter car i vaut 0 au depart
3. pour plus de clarté il faudrait variabliser tes object (classeur et workbook)
4. il y a certainement plus simple

d'autant plus que l'exemple que tu a donné ne possede qu'un sheets et comme ta boucle for "J" comme a 2 c'est rapé
absolument TOUT a revoir (concept et comprehention de ton environnement)
en l'etat on sait meme pas ce que tu veux faire finalement
plus ambrouillé que ca c'est pas possible


j'aurais commencer comme ca perso et pour ton exemple de fichier
dans cet exemple Wbk1 c'est le thisworkbook
le Wbk2 c'est le fichier chois ouvert avec getopenfilename
et comme ton fichier chois n'a qu'un sheet "message" je demarre la boucle for a 1

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub essai1()
Dim i&, j&, Wbk1 As Workbook, Wbk2 As Workbook, fichier
Set Wbk1 = ThisWorkbook
fichier = Application.GetOpenFilename("xlsx Files(sans Macros) (*.xlsx), *.xlsx")
If fichier = False Then Exit Sub
Set Wbk2 = Workbooks.Open(fichier)
For j = 1 To Wbk2.Sheets.Count
Wbk1.Sheets("Feuil1").Cells(j, 1) = Wbk2.Sheets(j).Name
'...
'...
 
Next
Wbk2.Close
End Sub

je soupconne que tu veux copier les colonnes avec leur plage utilisée il y a beaucoup plus simple qu'une boucle pour faire ca
je dis bien je soupconne car c'est pas tres clair tout ca vu le code que tu a proposé dans ton exposé

il faut etre plus precis dans ces demandes sinon on peut pas deviner

[Philippe Tulliez]

Bonjour,
En découpant ton problème, tu y verra beaucoup plus clair

Fonction qui renvoie la liste des feuilles d'un classeur

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Function ListSheet(wkb As Workbook) As Variant
  ' Renvoie la liste des feuilles du classeur passé en argument
  Dim sht As Worksheet, Tbl(), Elem As Integer
  With wkb
   For Each sht In .Worksheets
    ReDim Preserve Tbl(Elem): Tbl(Elem) = sht.Name:  Elem = Elem + 1
   Next
  End With
  ListSheet = Tbl
  Set sht = Nothing
End Function

Fonction qui renvoie la liste des étiquettes d'une feuille
Dans cet exemple, on suppose que chaque feuille a une liste de données commençant en A1 et que la première ligne contient bien les titres.
A adpter

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Function ListLabel(sht As Worksheet) As Variant
  ' A adapter
  '
  ' Renvoie la liste des étiquettes de la feuille passé en argument
  ' Cela suppose que toutes les listes commencent en A1 et contient les titres
  Dim c As Range, Elem As Integer, Tbl()
  For Each c In sht.Range("A1").CurrentRegion.Rows(1).Columns
    ReDim Preserve Tbl(Elem): Tbl(Elem) = c.Value:  Elem = Elem + 1
  Next
  ListLabel = Tbl
  Set c = Nothing
End Function

Procédure qui invoque ces fonctions et qui affiche le résultat renvoyé
Pour l'exemple on suppose que le classeur à examiner est déjà ouvert
A toi de l'adapter pour placer en amont l'ouverture des classeurs (je crois déjà proposé par Patrick)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Sub T()
  Dim wkb As Workbook ' Classeur à traiter
  Dim tblSheet()
  Dim tblLabel()
  Dim Msg As String
  Dim Elem As Integer
  ' Pour l'exemple le classeur à traiter est les deuxième ouvert
  Set wkb = Workbooks(2)
  '
  ' Charge la table du nom des feuilles du classeur
  tblSheet = ListSheet(wkb)
  ' Affiche la table
  MsgBox Join(tblSheet, vbCrLf), Title:="Liste des feuilles de " & wkb.Name
  ' Boucle sur l'ensemble des feuilles du classeur
  For Elem = 0 To UBound(tblSheet)
    ' Charge les étiquettes de la feuille (suivant boucle)
    tblLabel = ListLabel(wkb.Worksheets(tblSheet(Elem)))
    ' Affiche les étiquettes de la feuille
    MsgBox Join(tblLabel, vbCrLf), Title:="Liste des étiquettes de la feuille " & tblSheet(Elem)
    '
  Next
  Set wkb = Nothing
End Sub