VBA-EXCEL- TEST si fichier ouvert

**VBBBA** · 01/08/2006, 18h49

salut a tous les gars.

jais un pb trés simple(encore une fois).
je veux tester si un fichier est ouvert ou pas.

mon code ouvre directement ce fichier à la base mais parfois lorsqu'il est deja ouvert, me pose une errer du type qu'il ya un fichier deja ouvert a ce nom.
donc jai commencé à réfléchir à un test qui fait:
si fichier nommé "aaaa.xls" est ouvert on continue
sinon on ouvre ce meme fichier

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
 
 
Dim WB As Workbook
    For Each WB In Workbooks
    If WB.name = "aaaa.xls" Then
    Exit For
    Else
    Workbooks.Open Filename:=A & N, UpdateLinks:=0, ReadOnly:=True
     Exit For
    End If
Next WB

A et N sont des variables string que j'ai prédéfini au préalable pour indiquer le chemin du fichier et le nom aaaa du fichier xls.

mais ca pas lair de marcher.
il me l'ouvre a chaque fois en ecrasant l'ouvert....
jy suis pas loin alors merci de votre aide. bonne soirée

**SfJ5Rpw8** · 01/08/2006, 19h49

c'est le moment d'apprendre à ce servir de Debug.print..., cette instruction permet d'ecrire un message dans fenêtre exécution ( CTRL G..)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
 For Each WB In Workbooks
   Debug.print "Test Classeur :[" & WB.Name & "]"
    If WB.name = "aaaa.xls" Then

ainsi tu pourra voir si le classeur aaaa apparaît dans la liste des classeurs ouvert..

**VBBBA** · 01/08/2006, 22h49

je ne veux pas faire aparaitre un msgbox.
je veux que ce soit dans le procédure.ctou

**AlainTech** · 01/08/2006, 23h02

Dis, tu veux bien écouter ce qu'on te dit?

bbil n'a, nulle part, fait mention d'un MsgBox.

Et quand bien même, le but c'est que tu voies si ton nom de fichier est correct.
Quand tout fonctionne bien, tu supprimes tout ce qui sert au débuggage.

**Catbull** · 02/08/2006, 16h04

Une autre méthode pour voir si un classeur est déjà ouvert, est de tester une propriété relative au classeur. Par exemple le nom de ce classeur. Il faut intercepter l'erreur dans le cas où le classeur n'est pas ouvert. Ce qui donne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Public Function ClasseurOuvert(NomClasseur As String) As Boolean
    On Error Resume Next
 
    ClasseurOuvert = Application.Workbooks(NomClasseur).Name <> vbNullString
End Function

La fonction ClasseurOuvert renvoie True si le classeur est ouvert, False dans le cas contraire.

**VBBBA** · 08/08/2006, 16h55

et comment utiliser cette fonction dans un code?
et cette fonction peut elle tester un fichier qui est dans un autre classeur?
(on se suit a ce que je vois...)

**AlainTech** · 08/08/2006, 17h08

Bon... (Grande respiration)

Je m'énerve ou je me calme?

Si je m'énerve, je ferme cette discussion.

Par contre, même si je me calme, je ne m'empêcherai pas de dire que...

Le forum ne remplace pas les cours et tutos!

**VBBBA** · 08/08/2006, 17h12

et pourtant je ne trouve pas tout ce que jessai marche que pour des fichier dans un meme classeur
désolé. j

**AlainTech** · 08/08/2006, 17h20

Un classeur est un fichier!!!
Il est plus que temps que tu essaies d'avoir un peu plus de rigueur quand tu t'exprimes!

Dis-nous ce que tu cherches à faire précisément en essayant d'utiliser les termes corrects.

**AlainTech** · 08/08/2006, 17h24

Il est impossible de programmer sans avoir de rigueur!
Workbook n'est pas worbook, Sheets n'est pas Sheet, etc.

Autrement dit, si on n'est pas capable d'utiliser les bons termes pour exprimer ce que l'on veut, on n'y arrivera pas et il faut s'orienter vers une autre activité!

**VBBBA** · 08/08/2006, 17h32

ok.
jai une macro placé dans un fichier excel.cette macro teste si un fichier particulier est ouvert ou pas si test montre que le fichier est férmé...ca continue.sinon elle l'ouvre.

mais si notre fichier excel est ouvert dans une autre application excel que celle qui abrite notre fichier contenant notre macro, le test ne voit notre fichier meme si il est ouvert...

**Catbull** · 08/08/2006, 17h43

Dans ce cas, tu peux utiliser la méthode GetObject pour tester son existence. Mais, il faut connaitre le chemin complet du fichier et pas seulement son nom :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Public Function ClasseurOuvert(CheminClasseur As String) As Boolean
    On Error Resume Next
 
    ClasseurOuvert = GetObject(CheminClasseur).Name <> vbNullString
End Function

Comment l'utiliser? Ainsi :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Public Sub Main()
    Dim B As Workbook
 
    Set B = GetObject("E:\Mon fichier.xls")
 
    MsgBox B.Name
End Sub

Ps : le teste d'existence n'est plus nécessaire, tu peux le gérer directement dans la fonction Main en utilisant la gestion des exception (On Error...).

**VBBBA** · 09/08/2006, 20h58

ton idée est trés efficace. mais ya un hic.

mon test ne doit conserner que mon ordinateur pas ceux connéctés au lecteurs reseaux qui abritent mon fichier.
en effet. si un autre utilisateur a ouvert en lecture seule le fichier excel en question le test ressort positif. et ce qui est encore plus bizare c'est jai accées a visual vasic editor de ce fichier(dangereux! non?)
bref...moi ce que je veux c'est que le test s'applique qu'a mon ordinateur...

jai essayé toutes les idées...rien.
l'idée de bbil est trés bonne aussi .mais comme je l'ai dit, lr test ne fonctionne pas si mon fichier excel est ouvert sur une autre application excel que celle qui abrite mon fichier contenant mon fichier excel de la macro.
merci.
je continue a chercher...

**conconbrr** · 09/08/2006, 23h10

Je viens de te coder ça dis moi ça répond à tes attentes...

En plus comme je suis gentil j'ai envisagé deux cas.
Le premier cas est le plus réducteur, il suppose que tu connaisses le chemin complet de ton fichier :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
Sub Tester_StatutFichier1()
 
    Application.ScreenUpdating = False
 
    Dim stCheminFichier As String, stFichier As String
    Dim boFichierExiste As Boolean
    Dim wbClasseurActif As Workbook
 
    Set wbClasseurActif = ActiveWorkbook
 
    stCheminFichier = "C:\Documents and Settings\New\Bureau\compte.xls"
    stFichier = Right(stCheminFichier, Len(stCheminFichier) - InStrRev(stCheminFichier, "\"))
 
    If OuvertureFichier(stFichier) = True Then
        MsgBox "Votre fichier est déjà ouvert !", vbExclamation
        Exit Sub
    Else
        If ExistenceFichier1(stCheminFichier) = True Then boFichierExiste = True
    End If
 
    If boFichierExiste = True Then
        Workbooks.Open Filename:=stCheminFichier
        MsgBox "Votre fichier existe et vient d'être ouvert", vbInformation
    ElseIf boFichierExiste = False Then
        MsgBox "Le fichier que vous demandez n'existe pas!", vbCritical
    End If
 
    wbClasseurActif.Activate
 
    Application.ScreenUpdating = True
 
End Sub
Function ExistenceFichier1(CheminFichier As String) As Boolean
 
    If Dir(CheminFichier) <> "" Then ExistenceFichier1 = True
 
End Function
Function OuvertureFichier(NomFichier As String) As Boolean
 
    Dim WB As Workbook
 
    For Each WB In Workbooks
        If WB.Name = NomFichier Then
            OuvertureFichier = True
        End If
    Next
 
End Function

Les deux fonctions testent l'existence et l'ouverture du fichier en question et la procédure renvoie le résultat

Le deuxième cas est bien plus général puisqu'il suppose de connaître seulement le nom du fichier que tu cherches et une idée vague de l'endroit où il est (un répertoire quoi

), ce qui te permets par exemple de chercher dans C:\ !
Bien entendu tu l'auras compris cette deuxième méthode sera d'autant plus gourmande en temps que ton répertoire d'étude est vaste.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
Sub Tester_StatutFichier2()
 
    Application.ScreenUpdating = False
 
    Dim stCheminFichier As String, stFichier As String, stRepertoireRecherche As String
    Dim boFichierExiste As Boolean
    Dim wbClasseurActif As Workbook
 
    Set wbClasseurActif = ActiveWorkbook
 
    stFichier = "compte.xls"
    stRepertoireRecherche = "C:\"
 
    If OuvertureFichier(stFichier) = True Then
        MsgBox "Votre fichier est déjà ouvert !", vbExclamation
        Exit Sub
    Else
        If ExistenceFichier2(stFichier, stRepertoireRecherche, stCheminFichier) = True Then boFichierExiste = True
    End If
 
    If boFichierExiste = True Then
        Workbooks.Open Filename:=stCheminFichier
        MsgBox "Votre fichier existe et vient d'être ouvert", vbInformation
    ElseIf boFichierExiste = False Then
        MsgBox "Le fichier que vous demandez n'existe pas!", vbCritical
    End If
 
    wbClasseurActif.Activate
 
    Application.ScreenUpdating = True
 
End Sub
Function ExistenceFichier2(NomFichier As String, Repertoire As String, rCheminComplet As String) As Boolean
 
    Dim fsRechercheFichier As Office.FileSearch
 
    Set fsRechercheFichier = Application.FileSearch
    With fsRechercheFichier
        .NewSearch
        .LookIn = Repertoire
        .SearchSubFolders = True
        .Filename = NomFichier
        .Execute
    End With
    If fsRechercheFichier.FoundFiles.Count = 1 Then
        ExistenceFichier2 = True
        rCheminComplet = fsRechercheFichier.FoundFiles(1)
    End If
 
End Function

La fonction de vérification d'ouverture est la même que pour le premier cas.
Voilà dis moi ce que tu en penses

**AlainTech** · 10/08/2006, 05h41

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

If boFichierExiste = True Then

Peut, avantageusement, être remplacé par

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

If boFichierExiste Then

Pas besoin de mettre "= True" pour tester un booléen, If le fait déjà.

**conconbrr** · 10/08/2006, 10h04

Tout à fait d'accord c'était juste pour bien tt mettre afin que notre confrère ne loupe pas d'infos

**Catbull** · 10/08/2006, 10h21

La fonction OuvertureFichier ne fonctionne pas dans le cas de VBBBA :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Function OuvertureFichier(NomFichier As String) As Boolean
 
    Dim WB As Workbook
 
    For Each WB In Workbooks
        If WB.Name = NomFichier Then
            OuvertureFichier = True
        End If
    Next
 
End Function

Workbooks est un membre de l'objet Application. Or dans le cas de VBBBA, il y a plusieurs instances d'Excel de lancée donc plusieurs instances d'Application...

**VBBBA** · 10/08/2006, 15h08

merci pour vos reponses ....
mais mon pb persiste toujours.
si le fichier que je teste est ouvert sur une autre application excel sur mon ordi, le test ne le voit toujours pas et ouvre le fichier excel en question....
je me demande si ya pas de solution pour cette problematique en fait....

**VBBBA** · 10/08/2006, 15h12

mon test du fichier ne doit se faire que sur mon ordi et sur toutes les application excel d'ouvertes(dans le cas ou il y'en a plusieurs d'ouvertes...)

le test ne doit pas prerndre en compte l'ouverture de ce fichier par d'autres utilisateurs de connéctés au réseau.....

**conconbrr** · 10/08/2006, 22h36

Juste un truc que je pige pas bien (j'espère que vous allez éclairer ma lanterne).
Qu'est ce que vous entendez par pluisieurs instances d'Excel??
Si on ouvre deux fichiers excel, il sont tout les temps dans la même instance non?

VBA-EXCEL- TEST si fichier ouvert

Macros et VBA Excel

Discussions similaires

Partager

Partager