Discussion :

[betauser]

Bonjour,

Mes recherches sur ce forum et sur internet ne me permettent pas de comprendre pourquoi la macro me renvoie ce message :
"la méthode select" de la classe range a échoué".

Je précise que je suis néophyte et que je crée mes macros sur la base des exemples récoltés au fur et à mesure de mes recherches (bref, le code est sans doute perfectible).
Vous trouverez en pièce jointe le code et les variables associées.

En synthèse: dans l'onglet "ADI", le double clic sur une cellule doit renvoyer sur l'onglet "GP", sur la cellule de même valeur que la cellule double-cliquée.
La Macro:

1. récupère la valeur double-cliquée: ok (cf exemple ="identifier et traiter les risques")
2. cherche bien la cellule de l'onglet "GP" : ok
3. trouve l'adresse de la cellule à atteindre : ok (cf exemple = "$B$9").
4. refuse de se positionner dessus : KO

A quoi est due cette erreur?
Merci par avance pour tout éclairage.

Bonne réception.

[patricktoulon]

bonsoir

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub test()
    Dim Trouve As Range, PlaDeRecherche As Range, Valeur_Cherchee As String, AdresseTrouvee As String
    With Sheets("GP")
 
        'Valeur_Cherchee = ActiveCell.FormulaR1C1 '??????????
        Valeur_Cherchee = ActiveCell.Value
 
        'Set plagederecherche = .Columns(2) '?????????
        Set plagederecherche = .Range(.Cells(1, 2), .Cells(Rows.Count, 2).End(xlUp))
 
        Set Trouve = plagederecherche(what:=Valeur_Cherchee)'tu pourrais voir ici les argument lookat,lookin et autres ;aide VBA touche F1 dans VBE
 
        If Trouve Is Nothing Then .Activate: Trouve.Select on active le sheets si on trouve sinon on peut pas selectionner 
    End With
End Sub

[betauser]

Bonsoir Patrick,

Merci pour votre réactivité.
J'ai repris votre code.

Dim Trouve As Range, PlaDeRecherche As Range, Valeur_Cherchee As String, AdresseTrouvee As String

Je corrige « PlageDeRecherche », c'est bien cela?

initialement : Set PlageDeRecherche = Sheets("GP").Columns(2)
Votre proposition : Set plagederecherche = .Range(.Cells(1, 2), .Cells(Rows.Count, 2).End(xlUp))

En testant ma solution initiale, cela me permettait de rechercher l'adresse de la cellule à atteindre (cf mon exemple et la pièce jointe).
En quoi est-ce différent?
Est-ce que la 2nde démarche explique le message d'erreur que j’avais?

Set Trouve = PlageDeRecherche(what:=Valeur_Cherchee) 'tu pourrais voir ici les argument lookat,lookin et autres ;aide VBA touche F1 dans VBE

Je suppose qu'il faut ajouter ".Find" avant "(what:=...), n'est-ce pas?
Effectivement, j'ai vu que la fonction Find peut préciser des arguments sur la façon de chercher mais ces arguments sont facultatifs.
Dans mon cas, la recherche se fait bien (cf exemple et PJ) --> je ne précise pas les éléments facultatifs.

If Trouve Is Nothing Then .Activate: Trouve.Select 'on active le sheets si on trouve sinon on ne peut pas sélectionner

Ici, j’ajoute NOT --> IF NOT Trouve … car je pense que c'est ce que vous souhaitez compte-tenu de votre commentaire.

Après réalisé ces quelques ajustements, la macro me semble répondre à mes attentes, comme je le souhaitais. Je teste mais déjà un grand merci!

Egalement, j’aurai aimé comprendre pourquoi la 1ère méthode de ne fonctionnait pas pour ne pas refaire l'erreur plus tard.
L’adresse était bien récupérée mais je suppose que l’instruction Range(AdresseTrouvee).Select n’est pas correcte sans que je comprenne pourquoi.
Dans votre démarche, je ne comprends pas pourquoi il est inutile de récupérer l'adresse.

Cordialement,

[patricktoulon]

Re

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub test()
    Dim Trouve As Range, PlageDeRecherche As Range, Valeur_Cherchee As String, AdresseTrouvee As String
    With Sheets("GP")
 
        'Valeur_Cherchee = ActiveCell.FormulaR1C1 '??????????
        Valeur_Cherchee = ActiveCell.Value
 
        'Set plagederecherche = .Columns(2) '?????????
        Set PlageDeRecherche = .Range(.Cells(1, 2), .Cells(Rows.Count, 2).End(xlUp))
 
        Set Trouve = PlageDeRecherche(what:=Valeur_Cherchee)
 
        If Not Trouve Is Nothing Then .Activate: Trouve.Select
    End With
End Sub

je faisait la meme erreur que toi
Valeur_Cherchee = .ActiveCell.Value

[Pierre Fauconnier]

Salut.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
  Dim Trouve As Range, PlageDeRecherche As Range
  Dim ValeurCherchee As String
 
  ValeurCherchee = ActiveCell.Value
  Set PlageDeRecherche = Sheets("GP").Columns(2)
  Set Trouve = PlageDeRecherche.Find(what:=ValeurCherchee)
  If Not Trouve Is Nothing Then
    Sheets("gp").Select
    Trouve.Select
  End If
End Sub

Le problème que tu rencontres provient du fait qu'au moment du Range(AdresseTrouvee).Select, tu es toujours dans l'évènement DoubleClick de la feuille ADI. Dès lors, Range(AdresseTrouvee).Select "veut dire" Worksheets("ADI").Range(AdresseTrouvee).Select. Or tu ne peux sélectionner des cellules que sur la feuille sélectionnée qui est déjà GP => plantage...

Avec le code que je donne, Trouve EST sur GP => pas de plantage

[betauser]

Bonjour,

Merci pour le code est les explications.

Pourtant, quand je reprends mon code, je cherchais également dans l'onglet "GP", et plus dans l'onglet "ADI" (cf capture en pièce jointe de mon 1er billet).

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
AdresseTrouvee = Trouve.Adresse
sheets("GP").select
range(AdresseTrouvee).select

En tous cas encore merci.
Le code marche, c'est très bien.
C'est juste que j'ai l'impression de ne pas aller au bout de mon erreur.

Bonne réception.

[Pierre Fauconnier]

Je vais essayer de t'aider à aller au bout...

On croit trop souvent, à tort, que ne pas préfixer un Range force VBA à aller le chercher sur la feuille active, mais ce n'est pas aussi simple ni automatique que cela.

Ce sera le cas lorsque tu es dans un module standard ou dans un module de classe qui n'expose pas d'objet Range dans ses propriétés, comme par exemple un userform. Si le Range non préfixé est utilisé dans un module de classe qui expose un objet Range (une feuille de calcul, mais tout module de classe qui exposerait un objet Range), c'est l'objet de ce module de classe qui est le parent du Range.

Or, le code que tu utilises se trouve dans un module de classe qui expose une propriété Range (tu es dans le code de la feuille ADI), donc VBA associe le Range non préfixé que tu utilises à cet objet-là, c'est-à-dire la feuille ADI. En fait, lorsque tu utilises range(AdresseTrouvee).select dans un module de feuille de calcul, c'est comme si tu utilisais Me.range(AdresseTrouvee).select, Me. voulant dire "le module de classe dans lequel se trouve le code que tu utilises".

Pour observer cela, dans un nouveau classeur, place le code suivant dans le module de Feuil1 ET dans un module standard

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Public Sub Test()
  MsgBox "Parent of Range(ActiveCell.Address): " & Range(ActiveCell.Address).Parent.Name & vbCrLf & _
    "Parent of ActiveCell: " & ActiveCell.Parent.Name
End Sub

Dans le module d'une autre feuille de calcul, ici Feuil2, place le code évènementiel suivant

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
  Feuil1.Test
  Test
End Sub

Le premier msgbox, appelé de Feuil1Test, montre bien que Range(ActiveCell.Address) pointe vers Feuil1, puisque Test est dans le module de Feuil1, donc VBA comprend le Range non préfixé comme Me.Range(Activecell.Address) et Me=Feuil1, et que ActiveCell est bien dans Feuil2 puisque c'est la feuille active.





Le second msgbox, appelé d'un module standard, considère que Range(...) non préfixé est sur la feuille Active, soit Feuil2





J'espère que ces explications t'auront éclairé sur le pourquoi du comment...

[betauser]

Merci pour le complément d’information.

Je clos la demande.

Bonne réception