Discussion :

[samuelsmn]

Bonjour à tous,

Dans une macro je demande à l'utilisateur de rentrer 5 données, j'ai réalisé le code suivant pour lui permettre d'appuyer sur le bouton annuler et de sortir de la macro.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
ctrl_quai = Application.InputBox("Nombre d'erreur de préparation constatée au contrôle quai :", "Saisie de donnée", "Valeur par défaut", Type:=1)
            If ctrl_quai = False Then
                Exit Sub
            End If

Seulement voilà, il ne peut plus entrée la valeur "0" sans que ce soit considéré comme "False" et donc que cela le fasse sortir de la macro au lieu de continuer sa saisie de données.

J'ai essayer avec ce code mais cela n'a pas d'effet

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
ctrl_quai = Application.InputBox("Nombre d'erreur de préparation constatée au contrôle quai :", "Saisie de donnée", "Valeur par défaut", Type:=1)
            If ctrl_quai = vbCancel Then
                Exit Sub
            End If

Y a-t-il un moyen pour sortir de la macro avec le bouton annuler tout en gardant la possibilité d'entrée la valeur "0" ?

Merci d'avance

[joe.levrai]

Bonjour,

tu peux jouer sur le type de ta variable ctrl_quai, en le passant en String, afin de pouvoir différencier le 0 numérique du 0 Booleen

par exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub toto()
Dim ctrl_quai As String
    ctrl_quai = Application.InputBox("Nombre d'erreur de préparation constatée au contrôle quai :", "Saisie de donnée", "Valeur par défaut", Type:=1)
    If Not IsNumeric(ctrl_quai) Then
        MsgBox "annulé"
        Exit Sub
    Else
        MsgBox "La valeur entrée est : " & CInt(ctrl_quai)
    End If   
End Sub

[patricktoulon]

re
essaie de recupérer le retour de strptr

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

MsgBox StrPtr(ctrl_quai)

[samuelsmn]

Cela a le même effet avec ton code joe, quand je rentre la valeur 0 je suis sortie de la macro.

Sinon pour faire suite au message de patrick, voilà ce que la msgbox me renvoi selon ce que je rentre comme valeur

bouton annuler : 166738716
0 : 432024652
1 : 431712388

Qu'est ce que cela signifie ?

[patricktoulon]

re ou le test numeric

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Sub essai()
    Dim ctrl_quai As String,mss
    ctrl_quai = Application.InputBox("Nombre d'erreur de préparation constatée au contrôle quai :", "Saisie de donnée", "Valeur par défaut", Type:=1)
    mss = ctrl_quai
    If Not IsNumeric(ctrl_quai) Then mss = "annuler!!"
    MsgBox "l'entrée est : " & mss
End Sub

edit:
oui autant pour moi strptr est vallable qu'avec le inputbox vb pas les application.inputbox qui sont propres a excel
version avec un inputbox normal

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Sub test()
    Dim ctrl_quai As String
    ctrl_quai = InputBox("Nombre d'erreur de préparation constatée au contrôle quai :", "Saisie de donnée", "Valeur par défaut")
     If IsNumeric(ctrl_quai) And StrPtr(ctrl_quai) > 0 Then Debug.Print ctrl_quai
End Sub

[joe.levrai]

As-tu essayé mon code tel quel, sans l'adapter ?
La saisie du 0 est bien différenciée de l'appui sur le bouton "annuler"

Le type String de ctrl_quai est très important, chaque ligne de l'exemple a un rôle, il n'y a pas de décoration

D'ailleurs, la seconde proposition de Patrick utilise le même mécanisme, mais en passant par une seconde variable que je qualifie de superflue, à moins qu'une subtilité m'échappe et que Patrick va clarifier

[samuelsmn]

Au temps pour moi, j'ai réussi à intégrer le code de joe à ma macro.

En fait je l'ai testé dans un module à part pour commencer et en le recopiant dans ma macro je n'ai pas pensé à mettre "dim ctrl_quai as string" au début du code, donc c'est normal si cela ne fonctionnait pas bien.

Merci pour votre aide !