Ré-écriture de code "IF" avec 3 variables ?

**Duqueine01** · 07/02/2018, 17h14

Bonjour,

Quelqu'un aurait-il une solution pour réécrire ce code de manière plus courte ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
If BOX_MOIS.Value = "Décembre" And BOX_DEFAUT.Value = "ADMINISTRATIF - Identification" And BOX_STATUT.Value = "REBUT" Then
Sheets("Décembre").Activate
Total = Range("E198").Value + TextBox1.Value
Range("E198") = Total
End If
If BOX_MOIS.Value = "Décembre" And BOX_DEFAUT.Value = "ADMINISTRATIF - Identification" And BOX_STATUT.Value = "REBUT D'UNE AUTRE FNC" Then
Sheets("Décembre").Activate
Total = Range("h198").Value + TextBox1.Value
Range("H198") = Total
End If
If BOX_MOIS.Value = "Décembre" And BOX_DEFAUT.Value = "ADMINISTRATIF - Identification" And BOX_STATUT.Value = "RETOUCHE VALIDEE" Then
Sheets("Décembre").Activate
Total = Range("k198").Value + TextBox1.Value
Range("K198") = Total
End If
If BOX_MOIS.Value = "Décembre" And BOX_DEFAUT.Value = "ADMINISTRATIF - Identification" And BOX_STATUT.Value = "VALIDEE EN L'ETAT" Then
Sheets("Décembre").Activate
Total = Range("n198").Value + TextBox1.Value
Range("N198") = Total
End If
If BOX_MOIS.Value = "Décembre" And BOX_DEFAUT.Value = "ADMINISTRATIF - Identification" And BOX_STATUT.Value = "AUTRES" Then
Sheets("Décembre").Activate
Total = Range("q198").Value + TextBox1.Value
Range("Q198") = Total
End If

Parce que j'ai cette code 13 fois par mois... soit plus de 3500 lignes... et ça finit par planté car procédure trop longue...

Sinon je l'exploserai sur plusieurs Userform.

Merci

**Menhir** · 07/02/2018, 17h55

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
If BOX_MOIS.Value = "Décembre" Then
    Sheets("Décembre").Activate
    If BOX_DEFAUT.Value = "ADMINISTRATIF - Identification" Then
        Select Case BOX_DEFAUT.Value
        Case "REBUT"
            Range("E198") = Range("E198").Value + TextBox1.Value
        Case "REBUT D'UNE AUTRE FNC"
            Range("H198") = Range("H198").Value + TextBox1.Value
        Case "RETOUCHE VALIDEE"
            Range("K198") = Range("K198").Value + TextBox1.Value
        Case "VALIDEE EN L'ETAT"
            Range("N198") = Range("N198").Value + TextBox1.Value
        Case "AUTRES"
            Range("Q198") = Range("Q198").Value + TextBox1.Value
       End Select
   End If
End If

Mais ce n'est certainement pas ce morceau de code appliqué à quelques milliers de lignes qui faisait planter la procédure (à moins que tu l'utilises sur un PC datant des années 90).

**Marc-L** · 07/02/2018, 20h12

'soir !

Envoyé par Duqueine01

Quelqu'un aurait-il une solution pour réécrire ce code de manière plus courte ?

Oui car déjà il est inutile de répéter les deux premiers If fixes !

Un autre exemple via la fonction de feuille de calculs EQUIV (Match en VBA) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
    If BOX_MOIS.Value = "Décembre" And BOX_DEFAUT.Value = "ADMINISTRATIF - Identification" Then
        V = Application.Match(BOX_STATUT.Value, ["REBUT","REBUT D'UNE AUTRE FNC","RETOUCHE VALIDEE","VALIDEE EN L'ETAT","AUTRES"], 0)
      If IsNumeric(V) Then
        With Worksheets("Décembre").Cells(198, 2 + V * 3)
            .Value = .Value + TextBox1.Value
        End With
      End If
    End If

Avec des critères identiques, il est alors inutile de répéter le code mois par mois …

___________________________________________________________________________________________________________

Merci de cliquer sur

pour chaque message ayant aidé puis sur

pour clore cette discussion …

___________________________________________________________________________________________________________

Je suis Paris, Egypte, Nigeria, New-York, Mogadicio, Barcelone, London, Manchester, Stockholm, Istanbul, Berlin, Nice, Bruxelles, Charlie, …

**patricktoulon** · 07/02/2018, 20h56

re
bonsoir

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
Sub test()
    If BOX_MOIS.Value = "Décembre" And BOX_DEFAUT.Value = "ADMINISTRATIF - Identification" Then    ' 1 seule condition sur box mois box defaut value englobe les autre conditions
        With Sheets("Décembre")
            If BOX_STATUT.Value = "REBUT" Then
                .Activate    'pas obligé
                Set cel = .Range("E198")
                'Total = Range("E198").Value + TextBox1.Value'viré du code !!!!!!!!!!!
                'Range("E198") = Total'viré du code !!!!!!!!!!!
            End If
            If BOX_STATUT.Value = "REBUT D'UNE AUTRE FNC" Then
                .Activate    'pas obligé
                Set cel = .Range("h198")
                'Total = Range("h198").Value + TextBox1.Value 'viré du code !!!!!!!!!!!
                'Range("H198") = Total'viré du code !!!!!!!!!!!
            End If
            If BOX_STATUT.Value = "RETOUCHE VALIDEE" Then
                .Activate    'pas obligé!!!!!!!!!!!
                Set cel = .Range("k198")
                'Total = Range("k198").Value + TextBox1.Value'viré du code !!!!!!!!!!!
                'Range("K198") = Total'viré du code !!!!!!!!!!!
            End If
            If BOX_STATUT.Value = "VALIDEE EN L'ETAT" Then
                .Activate    'pas obligé
                Set cel = .Range("n198")
                'Total = Range("n198").Value + TextBox1.Value'viré du code !!!!!!!!!!!
                'Range("N198") = Total'viré du code !!!!!!!!!!!
            End If
            If BOX_STATUT.Value = "AUTRES" Then
                .Activate    'pas obligé
                Set cel = .Range("q198")
                'Total = Range("q198").Value + TextBox1.Value'viré du code !!!!!!!!!!!
                'Range("Q198") = Total'viré du code !!!!!!!!!!!
            End If
            cel.Value = cel.Value + textbox1.Value
        End With
    End If
End Sub

sinon sous la forme d'unselect case compréssé (utilisation de switch)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
 
    Dim celAdress, BsT
    If BOX_MOIS.Value = "Décembre" And BOX_DEFAUT.Value = "ADMINISTRATIF - Identification" Then    ' 1 seule condition sur box mois box defaut value englobe les autre conditions
        BsT = BOX_STATUT.Value
        celAdress = ""
        celAdress = Switch(BsT = "REBUT", "E198", BsT = "REBUT D'UNE AUTRE FNC", "h198", BsT = "RETOUCHE VALIDEE", "k198", BsT = "VALIDEE EN L'ETAT", "n198", BsT = "AUTRES", "n198")
        If celAdress <> "" Then
            With Sheets("Décembre")
                .Activate ' pas obligé !!!!!
                .Range(celAdress).Value = .Range(celAdress) + TextBox1.Value
            End With
        End If
    End If

@menhir
meme si aucune condition est remplie sauf decembre tu active un sheets toi ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
If BOX_MOIS.Value = "Décembre" Then
    Sheets("Décembre").Activate

**unparia** · 08/02/2018, 05h29

Bonjour
"et ça finit par planté car procédure trop longue..."
si tel est vraiment le message et donc la cause, ce ne sera pas le seul raccourcissement de cette partie du code qui suffira.
Il est vraisemblable que le bout de code montré ici est au sein d'une procédure (que l'on ne connait pas en entier) qui, elle, mériterait un peu de nettoyage, voire d'être "éclatée" en sous-procédures.

**Duqueine01** · 08/02/2018, 08h34

Envoyé par unparia

Bonjour
"et ça finit par planté car procédure trop longue..."
si tel est vraiment le message et donc la cause, ce ne sera pas le seul raccourcissement de cette partie du code qui suffira.
Il est vraisemblable que le bout de code montré ici est au sein d'une procédure (que l'on ne connait pas en entier) qui, elle, mériterait un peu de nettoyage, voire d'être "éclatée" en sous-procédures.

Bonjour,

Le message exacte est "Erreur de Compilation - procédure trop grande"
Ce code étant répété de nombreuses fois, je commence par le plus simple, réduire la procédure.
Mais je suspect comme toi qu'il me faille éclater ma procédure en plusieurs étapes.

Merci les gens pour vos propositions, je vais y regarder. Et je vais encore apprendre pleins de choses !!

Si quelqu'un sait m'expliqué pourquoi ne pas utilisé le .activate/.select ? J'ai déja eu ce commentaires mais je ne comprend pas pourquoi c'est "mal" de les utiliser ?

**Phil'oche** · 08/02/2018, 08h45

Bonjour,
Autre proposition, dans l'hypothèse (probable) où BOX_MOIS, BOX_DEFAUT et BOX_STATUT sont des ComboBox et qu'elles sont à valeurs fixes, tu peux utiliser leur propriété ListIndex pour remonter des valeurs associées avec un Choose :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Dim iDefaut as Integer,celAdress as String
iDefaut = BOX_DEFAUT.ListIndex + 1 ' ListIndex commence à 0 alors que Choose commence à 1 !!!
If iDefaut > 0 then celAdress = Choose(iDefaut, "E198", "h198", "k198", "n198", "n198")

et ainsi de suite pour les autres ComboBox...

**Duqueine01** · 08/02/2018, 08h55

Envoyé par Phil'oche

Bonjour,
Autre proposition, dans l'hypothèse (probable) où BOX_MOIS, BOX_DEFAUT et BOX_STATUT sont des ComboBox et qu'elles sont à valeurs fixes, tu peux utiliser leur propriété ListIndex pour remonter des valeurs associées avec un Choose :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Dim iDefaut as Integer,celAdress as String
iDefaut = BOX_DEFAUT.ListIndex + 1 ' ListIndex commence à 0 alors que Choose commence à 1 !!!
If iDefaut > 0 then celAdress = Choose(iDefaut, "E198", "h198", "k198", "n198", "n198")

et ainsi de suite pour les autres ComboBox...

Effectivement, ce sont des comboBox (listes déroulantes pour être précis).

Ré-écriture de code "IF" avec 3 variables ? [XL-2013]

Macros et VBA Excel

Vue hybride

Partager

Partager