Join sur Array multidimentionnelle

**jojo86** · 19/12/2017, 17h18

Bonsoir,
Je n'arrive pas à faire un truc tout bête.
J'utilise régulièrement la fonction Join pour transformer une array en chaine texte avec un séparateur.
Je voudrais faire la même chose avec une variable array multidimentionnelle.
Voici mon code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
 
Dim vtest(2, 2) As Variant
 
vtest(0, 0) = "NomChamp1"
vtest(0, 1) = "Valeur1"
vtest(1, 0) = "NomChamp2"
vtest(1, 1) = "Valeur2"
 
Debug.Print Join(Application.Index(vtest, 2, 2), ",")

Je n'arrive pas à faire fonctionner ça... Pouvez-vous m'aider?
Merci d'avance !

**boisgontierjacques** · 19/12/2017, 17h58

Bonsoir,

essai

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
 
Sub essai()
  Tbl = [A1:C3]
  For i = 1 To UBound(Tbl, 2)
    temp = temp & Join(Application.Index(Tbl, i), ",") & ","
  Next i
  MsgBox temp
End Sub

Boisontier

**patricktoulon** · 19/12/2017, 19h45

bonsoir
c'etait pas loin
par ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Sub test1()
'par les lignes
    Dim vtest(2, 2) As Variant
    vtest(0, 0) = "NomChamp1"
    vtest(0, 1) = "Valeur1"
    vtest(1, 0) = "NomChamp2"
    vtest(1, 1) = "Valeur2"
    For i = 1 To UBound(vtest)
        temp = temp & Join(WorksheetFunction.Index(vtest, i, 0), " ,")
    Next
    Debug.Print "ligne par ligne : " & temp
End Sub

ou par colonnes

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Sub test2()
'par les colonnes
    Dim vtest(2, 2) As Variant
    vtest(0, 0) = "NomChamp1"
    vtest(0, 1) = "Valeur1"
    vtest(1, 0) = "NomChamp2"
    vtest(1, 1) = "Valeur2"
    For i = 1 To UBound(vtest, 2)
        temp = temp & Join(Application.Transpose(WorksheetFunction.Index(vtest, 0, i)), " ,")
    Next
    Debug.Print "colonne par colonne : " & temp
End Sub

resultat

ligne par ligne : NomChamp1 ,Valeur1 ,NomChamp2 ,Valeur2 ,
colonne par colonne : NomChamp1 ,NomChamp2 ,Valeur1 ,Valeur2 ,

**unparia** · 19/12/2017, 20h17

Bonjour
Aucune réponse éclairée n'est à ce stade possible. Elle ne le sera que lorsque le demandeur aura bien voulu exposer de manière indubitable les aboutissants précis !

**patricktoulon** · 19/12/2017, 23h42

bonsoir jacques

Envoyé par jojo86

Bonsoir,
Je n'arrive pas à faire un truc tout bête.
J'utilise régulièrement la fonction Join pour transformer une array en chaine texte avec un séparateur.
Je voudrais faire la même chose avec une variable array multidimentionnelle.
Voici mon code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
 
Dim vtest(2, 2) As Variant
 
vtest(0, 0) = "NomChamp1"
vtest(0, 1) = "Valeur1"
vtest(1, 0) = "NomChamp2"
vtest(1, 1) = "Valeur2"
 
Debug.Print Join(Application.Index(vtest, 2, 2), ",")

Je n'arrive pas à faire fonctionner ça... Pouvez-vous m'aider?
Merci d'avance !

pour moi sa demande est claire

sauf que quand je vois cette ligne dans sa tentative

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Debug.Print Join(Application.Index(vtest, 2, 2), ",")

je serait amené a penser qui'il essaie de joindre toute les ligne colonnes d'un coup ce qui est impossible bien entendu car la fonction "join" ne fonctionne que sur une variable tableau a une !! dimention!!! ( un array)

je lui est donc montré comment joindre son tableau 2 dim de 2 facons differentes

le principe etant de créer des tableaux 1 dim avec les colonnes séparément ou les lignes par la fonction index et (+transpose) pour les colonnes car une seule colonne d'un tableau a 2 dim est un tableau a 2 dim donc transpose est de rigueur

je te l'accorde 2 boucles imbriquées sur ligne colonnes alimentant une variable string pourrait tres bien faire l'affaire

bref il a les moteurs a lui de savoir dans quel sens est son besoins

**pijaku** · 20/12/2017, 00h06

@patrick :
On en a parlé récemment, la fonction index est très lente par rapport à une boucle sur variable tableau...
Donc, dans ce cas, je préconise une fonction perso qui renvoie un string après une double boucle...........

**patricktoulon** · 20/12/2017, 00h14

bonsoir Franck

j'ai fait quelques tests a ce sujet il y aurais pas mal a en dire

en fait je me suis rendu compte que tout dependait des valeurs traitées et de la longueur de la chaine finaleselon les cas c'est pas la double boucle qui gagne

perso je verrait un avantage au doubles boucle si j'ai un traitement a faire dans les sub-chaines

**unparia** · 20/12/2017, 07h45

Salut Patrick
Cherche ce qu'il a de gênant dans cette expression :

pour moi sa demande est claire

Si une demande est claire :
1) elle l'est (et elle ne l'est pas "pour Pierre", "pour Paul", .....)
2) elle ne donne déjà pas lieu à deux propositions (selon que ...)

Je continue personnellement à me poser des questions quant à ce qu'il entend très exactement par ce "Join" d'un tableau à plusieurs dimensions.

PS : il est d'ailleurs assez probable que l'on y "verrait plus clair" s'il nous disait ce qu'il entend faire du résultat de ce "Join"-là, quel qu'il soit.

**jojo86** · 20/12/2017, 09h05

Envoyé par patricktoulon

bonsoir
c'etait pas loin
par ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Sub test1()
'par les lignes
    Dim vtest(2, 2) As Variant
    vtest(0, 0) = "NomChamp1"
    vtest(0, 1) = "Valeur1"
    vtest(1, 0) = "NomChamp2"
    vtest(1, 1) = "Valeur2"
    For i = 1 To UBound(vtest)
        temp = temp & Join(WorksheetFunction.Index(vtest, i, 0), " ,")
    Next
    Debug.Print "ligne par ligne : " & temp
End Sub

ou par colonnes

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Sub test2()
'par les colonnes
    Dim vtest(2, 2) As Variant
    vtest(0, 0) = "NomChamp1"
    vtest(0, 1) = "Valeur1"
    vtest(1, 0) = "NomChamp2"
    vtest(1, 1) = "Valeur2"
    For i = 1 To UBound(vtest, 2)
        temp = temp & Join(Application.Transpose(WorksheetFunction.Index(vtest, 0, i)), " ,")
    Next
    Debug.Print "colonne par colonne : " & temp
End Sub

resultat

Salut Patrick,
Tu avais bien compris ma demande. C'est le sub test2 qui m’intéresse.
Maintenant, se pose la question des performances... En attendant ta réponse, j'ai mis en place une boucle.
Ma variable ne dépassera pas les 10 à 15 lignes avec des données assez courtes (moins de 25 caractères).

Je me demande donc ce que je dois exploiter... Qu'en penses-tu? unparia semblait mitigié sur l'utilisation du "Index".

Merci d'avance,

**unparia** · 20/12/2017, 10h27

unparia semblait mitigié sur l'utilisation du "Index"

Pas du tout par cela, mais par l'utilisation du résultat obtenu (la chaîne de caractères unique résultante elle-même) !
En d'autres termes : que veux-tu exactement faire ensuite de ceci (résultat du test 2) :

NomChamp1 ,NomChamp2 ,Valeur1 ,Valeur2 ,

à quoi veux-tu l'utiliser, très précisément. Pour obtenir quoi à partir de cette chaîne ?

**patricktoulon** · 20/12/2017, 10h27

re
bonjour jojo
franchement 10 /15 lignes je me poserais meme pas la question de performence

on peut parler de choix pour la performence a partir que quelques millier de lignes sinon c'est meme pas la peine de se caser la tete

c'est mon opignion

**pijaku** · 20/12/2017, 10h35

Bonjour,

Unparia n'est pas "mitigé" sur l'emploi de Index. Unparia sait...
(Salut Jacques, mes excuses pour avoir parlé en ton nom)

C'est moi qui suit, non pas mitigé, mais contre l'utilisation d'Index selon les cas.
Avec 16 lignes tu n'auras pas de souci. Avec 16 000 ce ne sera pas la même sauce.

Si tu veux comparer, compare :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
Option Explicit
 
Sub Test()
Dim Tbl(1000, 4), res As String, t#, s$
 
    RempliTab Tbl, "Un string"
    s = ";"
 
    'pijaku : double boucle + Join
    t = Timer
    res = Join2D3(Tbl, s, 1)
    Debug.Print "Double boucle + Join ByRow : " & Len(res) & "      " & Timer - t
    res = vbNullString
 
    'PatrickToulon
    t = Timer
    res = Join2D4(Tbl, s, True)
    Debug.Print "Index (Patrick)  ByRow : " & Len(res) & "      " & Timer - t
    res = vbNullString
 
    'pijaku : double boucle + Join
    t = Timer
    res = Join2D3(Tbl, s, 2)
    Debug.Print "Double boucle + Join ByColumn : " & Len(res) & "      " & Timer - t
    res = vbNullString
 
    'PatrickToulon
    t = Timer
    res = Join2D4(Tbl, s, False)
    Debug.Print "Index (Patrick)  ByColumn : " & Len(res) & "      " & Timer - t
End Sub
 
Private Sub RempliTab(Tb, maVar As Variant)
Dim i&, j&
    For i = LBound(Tb, 1) To UBound(Tb, 1)
        For j = LBound(Tb, 2) To UBound(Tb, 2)
            Tb(i, j) = maVar
        Next
    Next
End Sub
 
Private Function Join2D3(Tbl, Sep As String, Optional Order As Integer) As String
'Tbl : la variable tableau 2 dimensions à joindre
'Sep : le séparateur à utiliser
'Order : le sens
    'ignoré : Order = 1 ==> par ligne
    'par ligne : Order = 1
    'par colonne : Order = 2
Dim i&, j&, StrTemp()
    If Order = 1 Or Order = 0 Then
        ReDim StrTemp(UBound(Tbl, 1))
        For i = LBound(Tbl, 1) To UBound(Tbl, 1)
            For j = LBound(Tbl, 2) To UBound(Tbl, 2)
                StrTemp(i) = StrTemp(i) & Tbl(i, j) & Sep
            Next
        Next
    ElseIf Order = 2 Then
        ReDim StrTemp(UBound(Tbl, 2))
        For i = LBound(Tbl, 2) To UBound(Tbl, 2)
            For j = LBound(Tbl, 1) To UBound(Tbl, 1)
                StrTemp(i) = StrTemp(i) & Tbl(j, i) & Sep
            Next
        Next
    Else
        Exit Function
    End If
        Join2D3 = Join(StrTemp, vbNullString)
End Function
 
 
Private Function Join2D4(vtest, Sep$, ByRow As Boolean) As String
'PatrickToulon
Dim temp$, i&
    If ByRow Then
        For i = LBound(vtest) To UBound(vtest)
            temp = temp & Join(WorksheetFunction.Index(vtest, i + 1, 0), Sep)
        Next
    Else
        For i = LBound(vtest, 2)  To UBound(vtest, 2)
            temp = temp & Join(Application.Transpose(WorksheetFunction.Index(vtest, 0, i + 1)), Sep)
        Next
    End If
    Join2D4 = temp
End Function

Tu y verras, notamment, un oubli dans la fonction de Patrick (salutations au passage).
Tu pourras également constater la lenteur induite par Index sur un grand nombre de lignes et presque pas de lenteur sur un plus petit nombre. (pas très français cette phrase

)

N'empêche que tu n'as pas répondu à l'essentielle question d'Unparia concernant les aboutissants de cette fonction.....

**unparia** · 20/12/2017, 11h01

Bonjour Franck
Tout-à-fait (tu as bien compris ma question).
Et les tenants également car si (en plus) les données de ce tableau dynamique sont le contenu d'une plage continue --->> nul besoin de la moindre boucle pour parvenir à cette "concaténation" (je ne veux pas utiliser ici le terme "Joining", non alors approprié)

Donc : 2 questions :
1) la question essentielle : pour en faire quoi exactement ?
2) la question subsidiaire : comment ce tableau dynamique a-t-il été alimenté, très exactement ?

**pijaku** · 20/12/2017, 11h02

Envoyé par unparia

Et les tenants également car si (en plus) les données de ce tableau dynamique sont le contenu d'une plage continue --->> nul besoin de la moindre boucle pour parvenir à cette "concaténation" (je ne veux pas utiliser ici le terme "Joining", non alors approprié)

Bonjour,

Dans l'attente de réponse à tes questions, je ne peux que te

**patricktoulon** · 20/12/2017, 11h33

re
perso ca me fait bien marrer votre theorie sur la vitesse d'execution des deux methodes

je viens de refaire le test 20 fois pour etre sur de ce que je dis

alors voila les deux methodes index et double boucle avec creation du tableau et transformation en chaine
pour 3000 items

il se trouve que quand je lance les deux sub l'une derriere l'autre dans l'ordre que vous voulez etonnament les deux font le meme temps

apres je lance la premiere celle que vous voulez
j'obtiens un temps
je rehinitialise vba je vide le debug
*et lance la 2d methode
devinez qui gagne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Sub test2_by_colonnes_in_2_boucle()
    t = Timer
    'par les colonnes
    Dim vtest(3000, 2) As Variant
    'je vais remplir  le tableau(vtest)de 3000 lignes
    For i = 0 To 3000
        vtest(i, 0) = "nomChamp" & i + 1: vtest(i, 1) = "valeur" & i+1
    Next
    For c = 0 To UBound(vtest, 2) - 1
        For i = 0 To UBound(vtest) - 1
            temp = temp & vtest(i, c) & " ,"
        Next
    Next
    Mid(temp, Len(temp), 1) = " "    'on enleve la derniere virgule a la fin
    MsgBox "   " & "en " & Timer - t & "  " & "secondes"
    Debug.Print "colonne par colonne : " & Trim(temp)
End Sub
 
Sub test2()
    t = Timer
    'par les colonnes
    Dim vtest(3000, 2) As Variant
    'je vais remplir  le tableau(vtest)de 3000 lignes
    For i = 0 To 3000
        vtest(i, 0) = "nomChamp" & i + 1: vtest(i, 1) = "valeur" & i+1
    Next
    For i = 1 To UBound(vtest, 2)
        temp = temp & Join(Application.Transpose(WorksheetFunction.Index(vtest, 0, i)), " ,")
    Next
    MsgBox "en " & Timer - t & "  " & "secondes"
    Debug.Print "colonne par colonne : " & temp
End Sub

**Marc-L** · 20/12/2017, 11h38

Bonjour !

Vite fait en passant :

Envoyé par pijaku

la fonction index est très lente par rapport à une boucle sur variable tableau...

Oui, mais seulement quand elle est mal utilisée et donc mal codée ‼
Ne jamais prendre l'intégralité d'une plage de cellules pour en extraire une ligne ou une colonne …

Quand les données sont déjà dans une variable tableau,
s'il y a du volume à traiter une boucle limite effectivement le temps d'exécution.
Mais si la source de la variable tableau est une plage de cellules,
INDEX bien utilisée en lecture directe limitée au maximum à une paire de colonnes ou de lignes n'est pas si lente !

Une variante pour jojo :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Sub Demo1()
    Dim V(), W
        V = Array(Array("NomChamp1", "Valeur1"), Array("NomChamp2", "Valeur2"))        
    For Each W in V
        Debug.Print Join(W, ",")
    Next
End Sub

___________________________________________________________________________________________________________
Je suis Paris, Egypte, Nigeria, New-York, Mogadicio, Barcelone, London, Manchester, Stockholm, Istanbul, Berlin, Nice, Bruxelles, Charlie, …

**unparia** · 20/12/2017, 13h22

Bonjour à tous

Et si je m'amusais maintenant à mettre en oeuvre la méthode de tremplin dont j'ai parlé (j'ai ouvert une discussion à ce sujet) il y a ... un mois ? deux mois ? ... je ne sais plus.
Allez, c'est l'occasion de la tenter et de comparer --->>
J'essaye et reviens, ne serait-ce que pour dire quels ont été ses résultats.
A plus

**unparia** · 20/12/2017, 13h36

Bon ... la voilà testée, cette méthode tremplin --->>

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Private Sub CommandButton2_Click()
 Dim deb As Double, p As Range, i As Long
 deb = Timer
 Dim vtest(3000, 2) As Variant
 For i = 0 To 3000
    vtest(i, 0) = "nomChamp" & i + 1: vtest(i, 1) = "valeur" & i + 1
 Next
 Set p = Range("A1:B3000")
 Application.ScreenUpdating = False
 p = vtest
 MsgBox Timer - deb & " secondes  ---> " & Join(Application.Transpose(Range("A1:A3000")), ",") & "," & Join(Application.Transpose(Range("B1:B3000")), ",")
 p.ClearContents
 Application.ScreenUpdating = True
End Sub

Résultats (loin d'être mauvais

) entre 0,015 secondes et 0.0299 secondes (selon l'état de la machine lors du lancement). A tester une 20aine de fois...

J'en profite pour dire toute l'importance qu'avait la seconde de mes questions (plus haut), à laquelle jojo n'a pas daigné répondre. On voit là une partie de la raison de cette seconde question, hein ...

Et tout cela n'enlève absolument rien à ma première question (essentielle), également laissée sans réponse de jojo : A quoi va être utilisée "utilement" une telle chaîne de caractères ?

**patricktoulon** · 20/12/2017, 13h58

@jacques

Nom : Capture.JPG
Affichages : 1801
Taille : 128,0 Ko

soit plus du double de temps qu'avec index

et encore!!!!c'est une escroquerie ton truc car ton calcul timer est fait avant que les chaines soit etablies

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

MsgBox Timer - deb & " secondes  ---> " & Join(Application.Transpose(Range("A1:A3000")), ",") & "," & Join(Application.Transpose(Range("B1:B3000")), ",")

la tu fait fort hein !!!

voila ton test réalisé honetement
c'est a dire tout ce qui est temporaire est vidé ou supprimé avant de calculer le temps

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Private Sub CommandButton2_Click()
    Dim deb As Double, p As Range, i As Long
    deb = Timer
    Dim vtest(3000, 2) As Variant
    For i = 0 To 3000
        vtest(i, 0) = "nomChamp" & i + 1: vtest(i, 1) = "valeur" & i + 1
    Next
    Set p = Range("A1:B3000")
    Application.ScreenUpdating = False
    p = vtest
    temp = Join(Application.Transpose(Range("A1:A3000")), ",") & "," & Join(Application.Transpose(Range("B1:B3000")), ",")
    p.ClearContents
    MsgBox Timer - deb & " secondes  ---> " & temp
    Application.ScreenUpdating = True
End Sub

Nom : Capture.JPG
Affichages : 1784
Taille : 113,6 Ko

tu te rends bien compte que deja créer un tableau puis le transférer sur sheets et travailler sur les colonnes du sheets(meme sans selection) est beaucoup plus long que travailler directement avec la variable tableau
tu me fait peur des fois

**pijaku** · 20/12/2017, 14h37

Soyons clair.
3 méthodes sont décrites ici.
Pour la demande actuelle, 16 lignes sur 2 colonnes, peu importe le choix, c'est de l'instantané.

Par contre, pour une autre utilisation, Patrick, les tests doivent être un peu plus poussé.
Ta méthode est très rapide lorsqu'il n'y a pas beaucoup de colonnes.
Par contre, elle devient (exponentiellement) de plus en plus lente à mesure que l'on ajoute des colonnes...

Celles (les méthodes) d'unparia et la mienne sont plus performantes sur de grandes plages de données.
Et pour cause!

Alors que dire si l'utilisateur veut une concaténation ByRow d'une variable tableau de taille (1 To 3000, 1 to 50) ?
Dans ce cas, il vaudra mieux double-boucler...

Join sur Array multidimentionnelle

Macros et VBA Excel

Discussions similaires

Partager

Partager