Export au format TXT avec des "PIPE" en séparateur

**Grim971** · 28/09/2017, 17h15

Bonjour,

J'ai besoin d'exporter mes données d'une feuille excel dans un fichier txt avec des PIPE comme séparateur. J'ai mon code en VBA qui fonctionne correctement à un petit détail près, c'est que je ne souhaite pas avoir de pipe sur la dernière colonne.

Je sèche complètement, donc si vous avez des idées je suis preneur !

Merci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
    sep = "|"
        With Worksheets("Sortie")
            Set Plage = .Range("A1:V4")
        End With
 
    Open chemin & "\" & nomfichier For Output As #1
 
 
    For Each oL In Plage.Rows
 
        Tmp = ""
 
        For Each oC In oL.Cells
 
        Tmp = Tmp & CStr(oC.Text) & sep
        Next
 
        Print #1, Tmp
 
    Next
 
    Close

**Pierre Fauconnier** · 28/09/2017, 17h21

Salut.

Enlève-le juste avant le Print

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Tmp = left(Tmp, len(tmp)-1)
Print #1, tmp

**patricktoulon** · 28/09/2017, 17h22

Rê
change la ligne pour celle ci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

 Tmp = Tmp & CStr(oC.Text) & iif(oc.column<(plage.column+plage.columns.count-1),"|","")

**Grim971** · 28/09/2017, 17h27

Envoyé par patricktoulon

Rê
change la ligne pour celle ci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

 Tmp = Tmp & CStr(oC.Text) & iif(oc.column<(plage.column+plage.columns.count-1),"|","")

Super cela fonctionne parfaitement !

Un grand merci a vous deux

Invité · 29/09/2017, 07h42

Bonjour,
J'arrive un peut tard mais bon!

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Const DATAOBJECT_BINDING As String = "new:{1C3B4210-F441-11CE-B9EA-00AA006B1A69}"
Public Property Let PressePapier(Value)
With CreateObject(DATAOBJECT_BINDING)
    .SetText Value
    .PutInClipboard
 End With
End Property
 
Public Property Get PressePapier()
With CreateObject(DATAOBJECT_BINDING)
    .GetFromClipboard
    PressePapier = .GetText
End With
End Property
Sub test()
Plage.copy
Temp=replace(PressePapier,VbTab,"|")
End sub

**patricktoulon** · 29/09/2017, 08h19

re
jolie robert

je fait la même chose avec le "htmlfile" et son parent.clipboard

je l'ai ajouté dans ma contrib a se sujet " et encore une..." comme ca on retrouve le principe du clipboard au même endroit

**unparia** · 29/09/2017, 08h41

Bonjour
Juste une question : quelle est la taille moyenne (en octets) du fichier texte résultant ?

**patricktoulon** · 29/09/2017, 08h50

re
c'est vrai jacques c'est une chose a prendre en compte

dans mes test avec le htmlfile je suis allé jusqu'à 40000 lignes sur 20 colonnes

si il y a trop avec l'object "htmldocument" on a la possibilité de ne pas passer par une variable string mais directement par le le body innerhtml qui lui va beaucoup plus loin en terme de taille

puis dans l'object" freefile" :print# .body.innerhtml

Invité · 29/09/2017, 09h37

rien empêche de faire de pas de x

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

for x = 1 to 1048576 step 1000

**Marc-L** · 29/09/2017, 10h02

Bonjour,

en utilisant Join il n'y a pas de séparateur à la fin et sans besoin de boucler sur les colonnes !

___________________________________________________________________________________________________________

Je suis Paris, Barcelone, London, Manchester, Egypte, Stockholm, Istanbul, Berlin, Nice, Bruxelles, Charlie, …

**patricktoulon** · 29/09/2017, 13h29

oui c'est vrai pour le join
mais cela remet en question l'utilisation du clipboard qui nous donne une structure toute faite par les "VBtaB"

a boucler sur le texte obtenu autant boucler directement sur les ROWS et utiliser la fonction index pour récupérer la ligne dans un array 1 dim et passer par un join avec le symbole

bref possibilité y en a à foison

Invité · 29/09/2017, 13h47

Code A1:AZ1048576 :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Sub test()
Set plage = ActiveSheet.UsedRange
With CreateObject("AdoDb.Connection")
    .Open "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & ThisWorkbook.FullName & ";Extended Properties=""Excel 12.0;HDR=No;"""
    Debug.Print .Execute("Select * from [" & plage.Parent.Name & "$" & Replace(plage.Address, "$", "") & "]").getstring(, , "|", vbCrLf)
    .Close
End With
End Sub

**patricktoulon** · 29/09/2017, 13h54

tu va t'arrêter oui !!!!!

j'ai mis ta première proposition dans ma contrib si ca te dérange pas et j'ai même adapter ta forme d'écriture a ma méthode

ICI

Invité · 29/09/2017, 13h57

Désolé Patrick!

oui j'ai vue et je t'en remercie; je t'es dalleur mis +1!

moiré insuffisante à A1:BI1048576

**patricktoulon** · 29/09/2017, 14h06

j'ai testé cela chez moi a peine a l'instant

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Public Property Let pressepapier(pressepapier)
    With CreateObject("htmlfile"): pressepapier = .parentWindow.clipboardData.GetData("Text"): End With
End Property
'
Public Property Get pressepapier()
With CreateObject("htmlfile"): pressepapier = .parentWindow.clipboardData.GetData("Text"): End With
End Property
'
Sub test()
    Set plage = Range("A1:Z65535")
    'plage.Value = "aaaaa"
    plage.Copy
    temp = Replace(pressepapier, vbTab, "|")
    MsgBox temp
End Sub

ca match pour la totalité de la feuille en terme de row et 26 colonnes "Z")
débloque la ligne d'écriture "aaaa" et lance

Invité · 29/09/2017, 14h42

avec une connexion ADODB ça fonction pour A1:AZ1048576 ou A1:XFD4088

**patricktoulon** · 29/09/2017, 16h16

non chez moi avec 2007 visiblement j'ai une limite
avec 1 quart de la feuille je suis déjà trop grand

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set plage = Range("A1", Cells(Rows.Count / 2, Cells.Columns.Count / 2))

Nom : Capture.JPG
Affichages : 2169
Taille : 152,8 Ko

par contre avec

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set plage = Range("A1:z65530")

ca marche mais c'est au moins 5 fois plus long

Invité · 29/09/2017, 17h12

Oui par copié collé, ca me la fait!

Mais en tirant la poignée de la plage c'est long chiant mais on y arrive!

**patricktoulon** · 29/09/2017, 21h50

non pas par copiercoller mais avec ta méthode adob connection

avec l'object data on a une limite si je prends toutes les colonnes
avec htmlfile ca passe
avec adob on a aussi une limite

Invité · 29/09/2017, 22h54

Oui je l'avais noté au poste #16, je vais voir si je peux insérer directement via ado mais je suis celtique en csv!

ÉDITE:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
 
 
Public Sub ShemaInit(Serveur As String, Fichier As String, Delimited As String)
Dim fso, NewFichier
Set fso = CreateObject("Scripting.FileSystemObject")
Set NewFichier = fso.OpenTextFile(Serveur & "\schema.ini", 2, True)
NewFichier.Write "[" & Fichier & "]" & vbCrLf & "Format=Delimited(" & Delimited & ")"
NewFichier.Close
Set NewFichier = Nothing
Set fso = Nothing
End Sub
Sub test()
Dim Server As String, Delimited As String, Fichier As String
Server = "C:\MyRepertoire": Fichier = "toto#CSV": Delimited = "|"
Dim Plage As Range
Set Plage = ActiveSheet.UsedRange
With CreateObject("AdoDb.Connection")
'ThisWorkbook.FullName
    .Open "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & Server & ";Extended Properties=""Text;HDR=NO;"""
    On Error Resume Next: .Execute "Drop table " & Fichier: On Error GoTo 0
    ShemaInit Server, Replace(Fichier, "#", "."), Delimited
    .Execute "Select * INTO  " & Fichier & " from [" & Plage.Parent.Name & "$" & Replace(Plage.Address, "$", "") & "] in '" & Plage.Parent.Parent.FullName & "' 'Excel 12.0;HDR=Yes;'"
    .Close
End With
End Sub

Export au format TXT avec des "PIPE" en séparateur

Macros et VBA Excel

Discussions similaires

Partager

Partager