Discussion :

[cwac45]

Bonjour,
Je souhaiterai que les données indiquées dans l'onglet Accompagnement Conseiller en bleu soient transférées dans l'onglet Récap. Acc. Conseiller en cliquant sur le bouton Enregistrer la fiche.
Comment puis je faire ?

[MarcelG]

Bonsoir,

Dans ton éditeur VBE, il y a une procédure prévue apparemment à cet effet.
As-tu essayé? Quelle est la difficulté? Où est l'erreur?

Le principe reste que tu essaies par tous les moyens à ta disposition, et que tu fais part ensuite des difficultés rencontrées.

[cwac45]

Et bien en fait je ne sais pas comment faire

[MarcelG]

Bonjour,

Pas de problème.

Plutôt que de passer par une variable Tableau alimentée par les données de la feuille de saisie, je te propose de copier un champ contigü de données depuis la feulle de saisie vers la feuille de synthèse.

Un développement est à envisager afin de gérer les cases à cocher (CheckBox).

Soit:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Sub Enregistrerlafiche_Marcel()
 
Dim Cel_report As Range
With Worksheets("Accompagenement Conseiller")
        'Valeur de la cellule - Report_Motif - en fonction des CheckBox
        .Range("Report_Motif").Value = IIf(.CheckBox1 = True, .[C15], "") & IIf(.CheckBox2 = True, " " & .[C16], "") & IIf((.CheckBox3 = True And Len(.[F15]) > 0), " " & .[F15], "")
        'Suppression des "blancs" éventuels en début et fin de valeur
        .Range("Report_Motif").Value = Trim(.Range("Report_Motif").Value)
        'Copie du champ nommé Report
        .Range("Report").Copy
End With
With Worksheets("Récap. Acc. Conseiller")
        'Définition de la première cellule destinataire de la copie
        Set Cel_report = .Cells(.Rows.Count, 1).End(xlUp).Offset(1, 0)
        'Collage spécial par transposition de valeurs
        Cel_report.PasteSpecial Paste:=xlPasteValues, Transpose:=True
        'Variable Cel_Report réinitialisée
        Set Cel_report = Nothing
        'Ajustement de la largeur des colonnes
        .Columns("A:L").AutoFit
End With
 
'Message de confirmation
MsgBox "La fiche a été enregistrée dans l'onglet : Récap. Acc. Conseiller, vous pouvez initialiser la fiche en cours"
 
End Sub

Le classeur ci-joint illustre les champs nommés ci-dessus.
Il te reste à affecter le bouton adéquat à cette nouvelle macro.

Reprends ce code ligne par ligne, voire mot par mot. Puis reviens si nécessaire afin de préciser les points restés obscurs.
Autrement dit, ne te contente pas d'un simple copier-coller.