Discussion :

[h12enri]

Bonjour à tous,
Je vais d'abord commencer par vous souhaiter mes meilleurs voeux pour 2013, il est encore temps

Ensuite voilà où j'aurai besoin de vos conseils :

J'ai 1 cellule qui contient des chiffres et du texte que je souhaiterai manipuler en 3 cellules distinctes. Voilà un exemple plus parlant :

Colonne A ------------------------ B ---- C ---- D
1 pomme + 2 poires + 1 peches ---- 1 ---- 2 ---- 3
1 pomme ------------------------- 1 ---- 0 ---- 0
3 pommes + 5 peches ------------- 3 ---- 0 ---- 5
10 poires + 4 peches --------------0 ---- 10 ---- 4
1 poire --------------------------- 0 ---- 1 ---- 0
rien ------------------------------ 0 ---- 0 ---- 0

etc... Je pense que vous avez compris la philosophie du problème.
La colonne A étant mon panier, la B = pomme, C = poire et D = peche évidemment.
Je peux ne rien avoir dans le panier, ou juste un fruit, voire 2 ou bien 3.
Mais les fruits sont toujours donnés dans le même ordre "Pomme + Poire + Peche".

Comment, à l'aide d'une macro, puis faire en sorte que la cellule de la colonne A puisse se spliter en cellules qui ne contiennent que la valeur de chaque fruit svp ?


Merci beaucoup pour votre aide.

- Henri

[tedo01]

Bonjour,
Je te propose cette fonction publique :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Public Function Panier(strType As String, objCell As Range) As Integer
Dim intPos As Integer
Dim strReponse As String
 
    Application.Volatile
 
    intPos = InStr(objCell.Value, strType)
    If intPos = 0 Then
        strReponse = "0"
    Else
        strReponse = Mid(objCell.Value, 1, intPos - 2)
        intPos = InStrRev(strReponse, " ")
        If intPos = 0 Then
        Else
            strReponse = Mid(strReponse, intPos + 1)
        End If
    End If
    Panier = CInt(strReponse)
End Function

Il faut ensuite l'appeler par exemple en B1 avec la formule

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=Panier("pomme", A1)

[h12enri]

Bonjour tedo01,

Je serai ravi d'essayer ta proposition mais j'avoue ne pas bien comprendre. Désolé.
Je copie/colle ton code (merci ) mais je ne saisis pas quand tu me dis que pour l'appeller je fais

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

 =Panier("pomme", A1)

Que dois-je faire pour lancer la macro que tu me proposes ? Merci encore

[tedo01]

Re-bonjour,
Il s'agit d'une fonction, ça veut dire qu'une fois mise dans un module, elle apparaît dans la feuille Excel dans la liste des fonctions disponible.
La formule que je te propose de mettre dans la cellule B1 permet d'appeler le code et d'afficher le résultat dans la cellule où elle se trouve.

[Didier Gonard]

Bonjour,

le souci que tu devras gérer sera le contrôle des noms entrés

Sinon, pour éviter du code inutile, j'ai exploité le fait que l'on peut attribuer plusieurs noms à une plage (cf image), les noms n'étant pas sensibles à la casse, restait les pluriels, en mettant 2 noms par en-tête masculin + pluriel, on est bons.



dans un module ordinaire :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Option Explicit
 
Sub gogo()
 
Dim tbo As Variant
Dim cell As Range
Dim I As Long
' Pour ne pas être gêné par les noms au pluriel ou par leur casse, voir le nommage de cellules d'en-têtes spécifique
'on initialise la plage à 0
Range(Cells(2, 2), Cells(Columns(1).Find("*", , , , , xlPrevious).Row, 4)).Value = 0
For Each cell In Range(Range("A2"), Cells(Columns(1).Find("*", , , , , xlPrevious).Row, 1))
    tbo = Split(cell.Value) 'séparateur par défaut = " "
    For I = 0 To UBound(tbo)
        If IsNumeric(tbo(I)) = True Then
            Cells(cell.Row, Range(tbo(I + 1)).Column).Value = tbo(I)
        End If
    Next I
Next cell
End Sub

cordialement,

Didier

[h12enri]

C'est formidable les gars.

Je suis + partisan d'utiliser uniquement un module ordinaire proposé par Didier, mais sache tedo01 que tu m'as permis de comprendre le principe de créer cette nouvelle fonction. Merci

Vous faites parfaitement ce qui je voulais. Maintenant faut encore que je trouve le moyen de prendre en considération que parfois au lieu d'avoir "1 pomme + 2 poires + 1 peches", c'est "TN pomme + poire" (TN = Trop Nombreux).

Parce que oui, en réalité ce ne sont pas des pommes, des poires et des peches mais des microorganismes dans des boites de pétri qui sont comptés. Et je me suis dit que des fruits c'est + agréable à lire pour vous que des mots latin .

N'hésitez pas à réagir si vous avez une solution pour le "TN".
En tout cas, votre aide me sert déjà bien.

Merci
- Henri

PS: Dois-je ouvrir une nouvelle discussion pour cette nouvelle question puisque ma question initiale est très bien répondue ? ou Pouvons-nous poursuivre ici avec ma question sur le "TN" ?

[Didier Gonard]

Bonjour,

Tu ne donnes pas assez d'éléments pour éviter que ceci se transforme en question à tiroirs

Donc s'il y a TN c'est pour tout ou on peut avoir

"TN pomme + 20 poire"
"TN pomme + TN poire" etc...

Savoir aussi s'il n'y a qu'un TN s'il se trouve toujours en début de chaîne => soluce = analyser les 2 premiers caractères de la chaîne etc...

Et le TN, on en fait quoi ? Il va en lieu et place des chiffres... dans toutes les colonnes, dans les colonnes dont seuls les noms sont cités ? etc...

Bref, même sans locution y faisant référence, il y a de quoi perdre son latin

cordialement,

Didier

[tedo01]

Re-bonjour,
Je n'ai pas regardé le code de Didier mais pour ma proposition, il est très simple de traiter n'importe quelle chaîne de caractères (sans espace) à la place des nombres (par exemple le "TN").
Il suffit de remplacer le type retourné de Integer à String, ce qui ne modifie que 2 lignes

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Public Function Panier(strType As String, objCell As Range) As String
...
    Panier = strReponse
...

[h12enri]

Ok ok.
Merci beaucoup pour vos conseils!