Discussion :

[Many31]

Salut à Tous,

J'essaye d'importer dans un Fichier Excel, des données de fichier CSV.
Le soucis c'est qu'ils sont 250... Et les ouvrir un par un prend un temps important. J'ai donc essayé via les connexions ADO mais je suis bloqué

J'ai pas mal cherché sur les sites anglophone mais je ne trouve rien de concluant. Le dernier code que j'ai écrit et qui semble marcher mieux que les précédents est celui-ci:

Mais il bug sur la requête SQL =/ Set Rst = Cn.Execute(texte_SQL)
"The microsoft data base engine couldn't find the object"
Je ne sais pas quoi mettre dans texte_SQL =/ ni si quelqu'un à une autre méthode pour lire des CSV sans les ouvrir...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Sub Methode4()
    Dim Cn As ADODB.Connection
    Dim Fichier As String
    Dim NomFeuille As String, texte_SQL As String
    Dim Rst As ADODB.Recordset
    Dossier = "C:\Documents and Settings\..."
    FichierCSV = "Nomfichier.csv"
 
    Set Cn = New ADODB.Connection
    Cn = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Dossier & ";Extended Properties = text"
    Cn.Open
    '-----------------
    texte_SQL = "SELECT * FROM [" & NomFichierCSV & "$]"
    Set Rst = New ADODB.Recordset
    Set Rst = Cn.Execute(texte_SQL)
 
    Range("A2").CopyFromRecordset Rst 
    Cn.Close
    Set Cn = Nothing
End Sub

Question subsidiaire :
Cn = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Dossier & ";Extended Properties = text" --> Marche
Cn = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Dossier & ";Extended Properties = text;HDR=YES;FMT=Delimited\" --> Marche pas hors c'est la ligne recommandée =/


Merci d'avance pour votre aide

[Godzestla]

Bonjour,

2 idées, juste en passant car je ne fais pas d'ADO sur ce type de source.

1) Peut-etre que ton dossier contient des espaces et que cela fiche la muise.

2) regarde l'exemple ci-dessous sur une source AS400. Le String de connection est défini comme tel avant utilisation. Cela pourrait aider.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
Public Sub ReadFileI5Full(ByVal Input_File As String, ByVal Target_worksheet As String, ByVal Target_range As String)
'ReadFileI5Full : get I5 data from Lib.file(member) and insert that in Worksheet at désired range cell
'usage : ReadFileI5Full (File, Worksheet, Range)
' Input_File : can be either Lib.file
'                    or Lib.File(member)
' Target_Worksheet : Must be a valid Worksheet Name : if exists : cleared before fullfillment
'                                              if not exists : will be created
' Target_Range     : Must be a valid cell name : Example "A1"
 
    On Error GoTo ErrorHandler
 
    Dim cn          As New ADODB.Connection
    Dim rs          As New ADODB.Recordset
    Dim sConn       As String
    Dim SqlString   As String
    Dim FileName    As String
    Dim DSN_Name As String
    Dim ws          As String 'Results Storing Worksheet name
    Dim Rg          As String 'results Cells top left
    Dim cellule     As Range
    Dim CompA       As Integer
    Dim idx         As Long
    Dim sheet_found As Boolean
    Dim ActShName   As String
    Dim Rec_nbr     As Long   'Record Set record Count
 
 
 
 
 
    sConn = "provider=IBMDA400;Data source=xxx.xxx.xxx.xxx;USER ID=USERID;PASSWORD=PASWWORD"
    FileName = Trim(Input_File)
    ws = Trim(Target_worksheet)
    Rg = Trim(Target_range)
 
    'check target Worsksheet exists and if not build
    sheet_found = False
    For idx = 1 To Sheets.Count
        If Sheets(idx).Name = ws Then
            Application.DisplayAlerts = False
            Sheets(idx).Cells.Clear
            Application.DisplayAlerts = True
            sheet_found = True
            Exit For
        End If
    Next idx
    'Build Ws
    If Not sheet_found Then
        ActShName = ActiveSheet.Name
        Sheets.Add
        ActiveSheet.Name = ws
        Sheets(ActShName).Activate
    End If
 
    'Open Connection
    cn.ConnectionString = sConn
    cn.Open
    SqlString = "SELECT * FROM " & FileName & ""
 
    'open record Set
    rs.Open SqlString, cn
    Rec_nbr = rs.RecordCount
 
 
 
    'Paste Fields names in line 1
    Set cellule = Worksheets(ws).Range(Rg)
    For CompA = 0 To rs.Fields.Count - 1
        cellule.Offset(0, CompA).Value = rs.Fields(CompA).Name
    Next CompA
    'Paste results line above names
    Worksheets(ws).Range(Rg).Offset(1, 0).CopyFromRecordset rs
 
    rs.Close
    cn.Close
    Set cn = Nothing
    Set rs = Nothing
    'MsgBox Rec_nbr & " records imported from I5"
 
    Exit Sub
ErrorHandler:
    ' clean up
    If Not cn Is Nothing Then
        If cn.State = adstateopen Then cn.Close
    End If
    Set cn = Nothing
    If Not rs Is Nothing Then
        If rs.State = adstateopen Then rs.Close
    End If
    If Err <> 0 Then
      MsgBox Err.Source & "-->" & Err.Description, , "Error"
    End If
 
End Sub

[Many31]

J'ai mal au crane lol mais je vais essayer de regarder cette source merci

Au pire je vais essayer de changer l'extension des csv en xls et de les lires de façon classique

[Philippe Tulliez]

Bonjour,

J'essaye d'importer dans un Fichier Excel, des données de fichier CSV.
Le soucis c'est qu'ils sont 250... Et les ouvrir un par un prend un temps important. J'ai donc essayé via les connexions ADO mais je suis bloqué

Tu dis que c'est lent mais as-tu essayé de placer l'instruction ci-dessous en tête de procédure. Cela accélère l'exécution.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Application.ScreenUpdating = False

[Many31]

J'ai même tenté le

Application.visible = False...

Mais finalement j'ai trouvé pour le lien ADO vers ce CSV:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
Sub Methode4()
    Dim Cn As ADODB.Connection
    Dim Fichier As String
    Dim NomFeuille As String, texte_SQL As String
    Dim Rst As ADODB.Recordset
    On Error GoTo ADO_ERROR
    Dossier = "Lien_Dossier" 'penser à terminer par un \
    FichierCSV = "Nom_Fichier_CSV" 'penser à l'extension .csv
 
    Set Cn = New ADODB.Connection
    Cn = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Dossier & ";Extended Properties=""text;HDR=Yes;FMT=Delimited(;)"";Persist Security Info=False"
    Cn.ConnectionTimeout = 40
    Cn.Open
    '-----------------
    texte_SQL = "SELECT * FROM " & FichierCSV
 
    Set Rst = New ADODB.Recordset
    Rst.ActiveConnection = Cn
    Rst.Source = texte_SQL
    Rst.Open
 
    i = 2
    If Rst.EOF <> True Then
        While Rst.EOF = False
            'Variable() = Rst.Fields(0)
            i = i + 1
            Rst.MoveNext
        Wend
    End If
    Rst.Close
    Set Rst = Nothing
    Cn.Close
    Set Cn = Nothing
ADO_ERROR:
    If Err <> 0 Then
        Debug.Assert (Err = 0)
        MsgBox (Err.Description)
        Resume Next
    End If
End Sub

[Godzestla]

Mais finalement j'ai trouvé pour le lien ADO vers ce CSV:

Il manquait le Slash de fin ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

    Dossier = "Lien_Dossier" 'penser à terminer par un \

Si oui, nous n'aurions pu trouver.... d'où l'importance d'un code réel ou équivalent !!!

[Many31]

Oui et non... c'était un des défauts de mon premier code mais pas le seul
L'autre erreur était dans la déclaration du séparateur du csv

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

FMT=Delimited(;)

et pas

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

FMT=Delimited\

Je m'appercois également que j'ai un "." dans le nom de mon fichier csv

exemple "Nom.fichier.csv" -> et ça ca passe pas

Faut que je trouve une methode pour soit remplacer ce point par un autre caractère soit trouver pourquoi l'ADO ne voit pas l'extension CSV

[Many31]

Finalement j'ai choisi la méthode bourrin

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub Remplacement_Nom_Fichier(Chemin As String)
    Fich = Dir(Chemin & "*.csv")
    Do While Fich <> ""
            Texte = Left(Fich, Len(Fich) - 4)
            Texte = Replace(Texte, ".", "_") & ".csv"
            Name Chemin & Fich As Chemin & Texte
        Fich = Dir
    Loop
End Sub

Un grand merci pour votre aide

(j'esp que ça va marcher sur des roulettes maintenant )