Discussion :

[Doncorleone8712]

Salut à tous,je débute en access et j'ai des petits soucis.

J'ai une grosse base de données de plus de 150 tables et naturellement ces tables ont plusieurs champs. Il se fait que je veux faire des modifications sur 5 champs précis se retrouvant dans la plupart de toutes les tables
Donc j voudrais savoir comment on peut:
1-parcourir toutes les tables
2-ensuite parcourir chaque champ et retrouver les champs qui m'interessent
3-enfin appliquer les modifications(calculs) sur ces champs precis là .
avec du code VBA avec des requetes ou autres

Je ne sais pas si je me suis bien fait comprendre,mais en gros c'est ca la situation.

Jusqu'à present j peux retrouver et modifier ces champs la en faisant appel à une seule table. L'ideal serait un code qui fait ca pour toutes les tables d'un seul coup.

[Invité]

Bonjour

Voici un exemple de boucle qui permet de parcourir les tables et les champs :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Public Sub ParcoursTableChamp()
    'déclaration
    Dim tdf As DAO.TableDef
    Dim fld As DAO.Field
 
    For Each tdf In CurrentDb.TableDefs
        For Each fld In tdf.Fields
            MsgBox "Table : " & tdf.Name & " -  Champ : " & fld.Name
        Next fld
    Next tdf
 
End Sub

Il ne faut pas oublier de cocher la référence Microsoft DAO 3.6 Object Library.

Un excellent tuto à lire sur le sujet : Création et manipulation des données avec DAO

Philippe

[Doncorleone8712]

Mais comment tu ferais pour faire reconnaitre au code mes champs specifiques pour qu'il s'y arrete et fasse les operations demandées?
Par exemple j'ai deux champs nommes SEG_type et SEG_fonction dans plusieurs de mes tables et j voudrais que dans le parcours,mon code puisse les retrouver et appliquer une formule sur toutes les valeurs de ces champs là.
J'ai mis ce bout de code à l'intereiur de ta boucle mais¸il ya erreur de compilation

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Public Sub ParcoursTableChamp()
'déclaration
Dim tdf As DAO.TableDef
Dim fld As DAO.Field
Dim qdf As DAO.QueryDef
 
'pgm.Name <=> nom de la colonne
'fld(pgm.Name) <=> valeur de la colonne dans le champ parcouru
If Not IsNull(fld(pgm.Name)) And Left(pgm.Name, 3) = "SEG" Then 'on s’intéresse qu'au colonne commençant par les lettres SEG dont la valeur n'est pas nulle
 
val1 = (fld(pgm.Name)) * 2
 
Query = "insert into fld([SEG_type], [SEG_fonction]) values ('" & val1 & "','" & val1 & "')"
Set qdf = CurrentDb.CreateQueryDef("", Query)
qdf.Execute
End If
 
Next fld
Next tdf
 
End Sub

[f-leb]

bonjour,

il faut commencer par mettre au point une requête de mise à jour du style:

Code sql :

Sélectionner tout - Visualiser dans une fenêtre à part

UPDATE LaTable SET LeChamp=LeChamp*2 WHERE LeChamp IS NOT NULL

[Doncorleone8712]

Ton update ne marche pas dans mon code,ca maffiche des messages d'erreur de type et de compilation.
Bref j'ai reecrit un autre code de base pour tester au moins si ca marche. L'idée de depart reste la même ,à savoir que je veux modifier des valeurs numeriques dans des champs spécifiques dans une base de donnees avec une multitude de tables.
Dans ce code je recherche juste dans toutes les tables le champ SEG_type et je veux multiplier ces valeurs par 2. Le code compile sans erreur mais je ne vois aucun resulta ni changement dans mes table d'origine.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
Dim db As DAO.Database
Dim tdf As DAO.TableDef
Dim rst As DAO.Recordset
Dim fld As DAO.Field
 
 Sub ReplaceFieldValeur()
 
'On Error GoTo Err_ReplaceFieldValeur
Set db = CurrentDb
 
    For Each tdf In db.TableDefs ' on parcourt toutes les tables
 
      If tdf.Attributes <> dbSystemObject And tdf.Attributes <> dbHiddenObject Then
 
          For Each fld In tdf.Fields 'On parcourt tous les champs
 
         If fld.Name Like "*" & "SIG_type" & "*" And IsNumeric(fld) Then  'si un champ s'appelle SIG_type et est de type numerique
        Set rst = dbs.OpenRecordset(fld.Name, dbOpenDynaset) 'on ouvre le recordset
          If Not rst.EOF Then
                Do While Not rst.EOF 'tant qu'on n'a pas fini ttes les lignes du champ
 
        s_type = rst.Fields("SEG_ID").Value ' on recupere la valeur de la ligne dans la colonne SIG_type
 
        requete = " Update fld(fld.Name) As  s_type * 2 " ' on cree la requete ki va modifier l'enregistrement de la ligne sur lakel on se trouve
        db.Execute requete ' On execute la requete
 
 
        ' rst.Fields(fld.Name).Value = NewValue (un commentaire perso dans mon code)
 
                Loop
            End If
            rst.Close
            ' Set rst = Nothing
 
          End If
 
   Next fld
     End If
 
    Next tdf
 
 
    db.Close
' on reinitialise tout
Set rst = Nothing
Set fld = Nothing
Set tdf = Nothing
Set db = Nothing
 
End Sub

[f-leb]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
Dim db As DAO.Database
Dim tdf As DAO.TableDef
Dim rst As DAO.Recordset
Dim fld As DAO.Field
 
 Sub ReplaceFieldValeur()
 
'On Error GoTo Err_ReplaceFieldValeur
Set db = CurrentDb
 
    For Each tdf In db.TableDefs ' on parcourt toutes les tables
 
      If tdf.Attributes <> dbSystemObject And tdf.Attributes <> dbHiddenObject Then
 
          For Each fld In tdf.Fields 'On parcourt tous les champs
 
         If fld.Name Like "*" & "SIG_type" & "*" And IsNumeric(fld) Then  'si un champ s'appelle SIG_type et est de type numerique
 
        requete = "Update [" & tdf.Name & "] SET [" & fld.Name & "] = [" & fld.Name & "]*2;"
 
        debug.print requete ' afficher le SQL de la requete dans la console d’exécution au cas où
 
        db.Execute requete ' On execute la requete
 
            End If
 
 
   Next fld
     End If
 
    Next tdf
 
 
    db.Close
' on reinitialise tout
Set rst = Nothing
Set fld = Nothing
Set tdf = Nothing
Set db = Nothing
 
End Sub

à quelques erreurs près comme d'hab'

[tee_grandbois]

bonsoir,
en complément du code de f-leb et en remplacement des lignes 17 à 19 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
          If fld.Name Like "*" & "SIG_type" & "*" And _
            (fld.Type = dbLong Or fld.Type = dbDouble Or _
             fld.Type = dbInteger Or fld.Type = dbSingle Or _
             fld.Type = dbCurrency Or fld.Type = dbFloat Or _
             fld.Type = dbDecimal Or fld.Type = dbNumeric Or _
             fld.Type = dbBigInt) Then    'si un champ s'appelle SIG_type et est de type numerique
 
        requete = "Update [" & tdf.Name & "] SET [" & fld.Name & "] = [" & fld.Name & "]*2 Where [" & fld.Name & "] is not null;"

[Doncorleone8712]

Merci les gars ç a marché à 1ne erreur pres. Au lieu de
db.Execute requete j'ai du ecrire DoCmd.RunSQL (requete)

¸Si ça ne vous gêne pas j'aurai une autre difficulté toujjours dans le mme ordre d'idee. Supposons que pour modifier les valeurs des enregistrements du champ SIG_type il faut que j'utilise l'enregistrement d'un autre champ SIG_valeur par exemple.
Dans le style ,il faut que je fasse un calcul du genre:
Nouvelle valeur de SIG_type= (ancienne valeur de SIG_type)*2 + (ancienne valeur de SIG_valeur *10)

Je travaille sur une imbrication de boucle qui lit toute la table,parcourt les champs et reconnait les deux champs ci-dessus en parallele pour faire le calcul sur les deux valeurs recuillies mais ca ne semble pas marcher . le probleme se trouve dans le parcours parallèle et la synthaxe du update

Ca a l'air un peu flou mais en gros c'est^ça. Merci si vous avez une idee.

[Doncorleone8712]

Comment j'ecris le Where is not null pour 2 ou plusieurs variables ensemble? Merci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
 
 
Dim db As DAO.Database
Dim tdf As DAO.TableDef
Dim ttt As DAO.Field
Dim fld As DAO.Field
 
 Sub ReplaceFieldValeur()
 
'On Error GoTo Err_ReplaceFieldValeur
Set db = CurrentDb
 
    For Each tdf In db.TableDefs ' on parcourt toutes les tables
 
      If tdf.Attributes <> dbSystemObject And tdf.Attributes <> dbHiddenObject Then
 
          For Each fld In tdf.Fields 'On parcourt tous les champs
 
         If fld.Name Like "*" & "SEG_trip" & "*" And _
            (fld.Type = dbLong Or fld.Type = dbDouble Or _
             fld.Type = dbInteger Or fld.Type = dbSingle Or _
             fld.Type = dbCurrency Or fld.Type = dbFloat Or _
             fld.Type = dbDecimal Or fld.Type = dbNumeric Or _
             fld.Type = dbBigInt) Then    'si un champ s'appelle SIG_type et est de type numerique
 
             For Each ttt In tdf.Fields
              If ttt.Name <> fld.Name And ttt.Name Like "*" & "SEG_fonction" & "*" Then
 
 
 
       requete = "Update [" & tdf.Name & "] SET [" & fld.Name & "] = [" & fld.Name & "]*2  + [" & ttt.Name & "]*4 ;"  ' Where [ " & ttt.Name & "] is not null
'
'        Debug.Print rst ' afficher le SQL de la requete dans la console d'exécution au cas où
'
'       On execute la requete
 
 
       DoCmd.RunSQL (requete)
       End If
       Next ttt
 
 
'       ElseIf fld.Name Like "*" & "SEG_fonction" & "*" And _
'            (fld.Type = dbLong Or fld.Type = dbDouble Or _
'             fld.Type = dbInteger Or fld.Type = dbSingle Or _
'             fld.Type = dbCurrency Or fld.Type = dbFloat Or _
'             fld.Type = dbDecimal Or fld.Type = dbNumeric Or _
'             fld.Type = dbBigInt) Then    'si un champ s'appelle SIG_type et est de type numerique
'
'        requete = "Update [" & tdf.Name & "] SET [" & fld.Name & "] = [" & fld.Name & "]*4 Where [" & fld.Name & "] is not null;"
'
'        'Debug.Print requete ' afficher le SQL de la requete dans la console d'exécution au cas où
'
'        ' on exécute la requete
'
'       DoCmd.RunSQL (requete)
 
 
 
            End If
 
 
   Next fld
     End If
 
    Next tdf
 
 
    db.Close
' on reinitialise tout
 
Set fld = Nothing
Set tdf = Nothing
Set db = Nothing
 
End Sub

[tee_grandbois]

Bonsoir,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Where [ " & fld.Name & "] is not null and  [" & ttt.Name & "] is not null;

[tee_grandbois]

Bonjour,
J'ai corrigé ton code et il fonctionne correctement. J'ai mis des Exit For pour sortir des boucles car cela ne peut pas fonctionner si tu trouves plusieurs champs contenant tes valeurs (SIG_type et SIG_fonction) car les résultats risquent d'être faussés, surtout quand on utilise l'opérateur Like.
Par exemple :
si tu as un champ qui s'appelle SIG_type_1, un second SIG_fonction_1 et un troisième SIG_fonction_2, tu exécuteras 2 fois la requète de mise à jour car "SIG_fonction" existe 2 fois. Donc un conseil : remplace l'opérateur "Like" par "=".

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
Sub ReplaceFieldValeur()
 
Dim db As DAO.Database
Dim tdf As DAO.TableDef
Dim ttt As DAO.Field
Dim fld As DAO.Field
 
'On Error GoTo Err_ReplaceFieldValeur
Set db = CurrentDb
 
    For Each tdf In db.TableDefs ' On parcourt toutes les tables
 
        If tdf.Attributes <> dbSystemObject And tdf.Attributes <> dbHiddenObject Then
 
            For Each fld In tdf.Fields ' On parcourt tous les champs
 
 '       Condition 1 : si un champ de la table s'appelle comme SEG_type et est de type numerique
 ' Avec =    :  If fld.Name = "SEG_type" And _
 ' Avec Like :
                If fld.Name Like "*" & "SEG_type" & "*" And _
                    (fld.Type = dbLong Or fld.Type = dbDouble Or _
                     fld.Type = dbInteger Or fld.Type = dbSingle Or _
                     fld.Type = dbCurrency Or fld.Type = dbFloat Or _
                     fld.Type = dbDecimal Or fld.Type = dbNumeric Or _
                     fld.Type = dbBigInt) Then
 
                    For Each ttt In tdf.Fields
 
 '       Condition 2 : si un champ de la table s'appelle comme SEG_fonction et est de type numerique
 ' Avec  =   :          If ttt.Name <> fld.Name And ttt.Name = "SEG_fonction" And _
 ' Avec Like :
                        If ttt.Name <> fld.Name And ttt.Name Like "*" & "SEG_fonction" & "*" And _
                            (ttt.Type = dbLong Or ttt.Type = dbDouble Or _
                             ttt.Type = dbInteger Or ttt.Type = dbSingle Or _
                             ttt.Type = dbCurrency Or ttt.Type = dbFloat Or _
                             ttt.Type = dbDecimal Or ttt.Type = dbNumeric Or _
                             ttt.Type = dbBigInt) Then
 
                            requete = "Update [" & tdf.Name & "] SET [" & fld.Name & "] = [" & fld.Name & "]*2 + [" & ttt.Name & "]*4  Where [" & ttt.Name & "] is not null and [" & fld.Name & "] is not null;"
 
'                           Debug.Print requete ' afficher le SQL de la requete dans la console d'exécution au cas où
 
'       On éxecute la requète et on sort de la boucle 2 avec la condition 2
                            'DoCmd.RunSQL (requete)
                            db.Execute requete, dbFailOnError ' Cà marche et il n'y a pas de messages d'avertissement.
                            Exit For
                        End If
 
                    Next ttt
 '      On sort de la boucle 1 avec la condition 1
                    Exit For
 
                End If
 
        Next fld
     End If
 
    Next tdf
 
    db.Close
' on reinitialise tout
 
Set fld = Nothing
Set tdf = Nothing
Set ttt = Nothing
Set db = Nothing
 
End Sub

[Doncorleone8712]

C'est parfait j`'avais déjà exécuté quelque chose de similaire avec d'autres variables en plus ,mais ta remarque sur le = à la place du Like et l'utilisation de Exit For est venu tout parfaire!!. Thx pour le temps accordé

à la prochaine pour d'autres défis ,parce que je sens que je n'ai pas encore fini avec VBA lol

[Doncorleone8712]

En passan tpour exécuter mes macros j vais toujours les exécuter dans la fenetre VBA,est ce qu'il y a un moyen comme dnas excel de les joindre à un bouton automatique dans un formulaire par exemple?

[tee_grandbois]

Bonjour,
tu peux effectivement créer un formulaire avec un bouton qui exécute ton code : sur l'évènement click du bouton tu fais un call de ton Sub :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Private Sub Commande0_Click()
 
 Call ReplaceFieldValeur
 
End Sub

[Doncorleone8712]

Merci pour l'aide!!!Vraiment sympa