Discussion :

[fllyann]

Bonjour à tous


voici mon petit problème je voudrais créer une feuille dans mon classeur et la renommer.

J'arrive à créer la feuille et la renommer mais ça me recrée toujours une nouvelle feuille puis une erreur qui me fait sortir de ma macro .

Voici mon code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
 
Dim page As Variant
Dim feuilleErreur As Worksheet
'Boucle de test pour savoir si les deux projet ont le même nom
If projetA = projetD Then
    MsgBox " Il n'y a pas d'erreur."
 
Else
    MsgBox " Il y a une erreur."
  ' Je vérifie s'il y a déjà une feuille
  For Each page In Worksheets
    If page.Name = "erreurs" Then
    MsgBox "La Page est déjà crée."
    Else
    'J 'ajoute une feuille & je change le nom
    Set feuilleErreur = Sheets.Add(After:=Sheets(Sheets.Count))
    feuilleErreur.Name = "erreurs"
 
    End If
  Next page
  End If

Merci de me dire ce qui est faux et comment rattraper le coup.

bonne fin de journée à vous

[patricktoulon]

bonjour

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
 For Each page In Worksheets

traduction:
pour toute les page dans la page active ne crois tu pas qu'il y a la une erreur


essaie plutot

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
for each page in thisworkbook

traduction : pour toute les pages dans ce classeur


au plaisir

[Maxence HUBICHE]

hmmm... désolé PatrickToulon, mais, je préfère sa solution à lui...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

For each page in activeworkBook.Worksheets

"Pour chaque page dans l'ensemble des feuille de calcul du classeur actif"


sinon, fllyann, ton erreur est dans ton algorithme.
A chaque feuille de calcul, tu regardes si elle s'appelle "erreurs", et, dans le cas contraire, tu en crées une...
Donc, si tu as 2 feuilles de calcul, tu tentes 2 fois de créer une feuille "erreurs"

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
dim bFounded as Boolean
<snip>
 
For each page in ActiveWorkBook.WorkSheets
    if page.Name = "erreurs" Then
        bFounded = true
        exit For
    else
        'rien à faire
    end if
Next
 
If Not bFounded then
    'J 'ajoute une feuille & je change le nom
    Set feuilleErreur = Sheets.Add(After:=Sheets(Sheets.Count))
    feuilleErreur.Name = "erreurs"
Else
    'rien à faire puisque la page "erreur" a été trouvée
End If

[OrDonc]

Bonsoir,

puisque c'est fait, un autre style :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
 
Sub test()
  Dim feuilleErreur As Worksheet
  'Boucle de test pour savoir si les deux projets ont le même nom
    If projetA = projetD Then
    MsgBox " Il n'y a pas d'erreur."
  Else
    MsgBox " Il y a une erreur."
    ' Je vérifie s'il y a déjà une feuille
    For n = 1 To Sheets.Count
      If Sheets(n).Name = "erreurs" Then MsgBox "La Page est déjà créée.": Exit Sub
    Next
    Set feuilleErreur = Sheets.Add(After:=Sheets(Sheets.Count))
    feuilleErreur.Name = "erreurs"
  End If
End Sub

[Philippe Tulliez]

Bonsoir,
Les puristes vont peut-être hurler mais moi pour contrôler l'existence d'une feuille, je provoque une erreur.
J'ai donc écrit une fonction qui teste l'existence ou non de la feuille

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Function IsShtExist(wName As String) As Boolean
  ' Verify if a sheet exist
  ' Parameters
  '  wName : Sheet name
  ' Author : Philippe Tulliez
  ' Date   : 2004/04/14 v 1.0
  Dim wSheet As Worksheet
  On Error Resume Next
  Set wSheet = Worksheets(wName): If Err = 0 Then IsShtExist = True
  On Error GoTo 0
End Function

Donc dans le code, je ne parcours pas la collection worksheets

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
 
 If projetA = projetd Then
     MsgBox " Il n'y a pas d'erreur."
 Else
   ' Je vérifie s'il y a déjà une feuille
  If Not (IsShtExist("erreurs")) Then
    Set feuilleErreur = Sheets.Add(After:=Sheets(Sheets.Count))
    feuilleErreur.Name = "erreurs"
  End If
 End If

[fllyann]

Bonjour à tous

désolé de ne pas avoir répondu hier mais j'ai posté et je suis parti du travail.


merci pour toutes vos réponses, je vais les tester.

Maxence, je supposais bien que l'erreur venait de mon algorithme mais j'arrivais pas à comprendre exactement pourquoi merci !

Merci à vous en tout cas vos 3 solutions fonctionne très bien
bonne continuation et à la prochaine erreur !