Discussion :

[apnw7931]

Bonjour,

J'aimerai pouvoir additionner les valeurs de ma colonne B selon que ma colonne A contient les prénoms "Manu" ou "Jean" ou "Sophie".
Voir pièce jointe.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Prénom - Points
-----------------------
Manu 2
Jean 3
Marc 4
Sophie 2
Morgane 3

Résutat souhaité : 2 + 3 + 2 = 7

Pourriez vous me dire comment ?
SOMME PROD ? SOMME SI ? SOMME SI ENS ?
J'aimerai éviter de faire la somme de 3 SOMME.SI


Merci d'avance.

[Invité]

Bonjour,

Une solution possible avec Sommeprod.


Cordialement.

[apnw7931]

Merci Eric pour cet élement de réponse.
Mais je préfererai ne pas rajouter de colonne à mon fichier, qui est déjà très volumineux.

Une autre idée??
Pour l'instant, j'ai cette formule (mais qui a mon sens est redondante...)

[Philippe Tulliez]

Bonjour,
Comme Eric que je salue au passage, je te propose une solution avec SOMMEPROD mais sur une cellule

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD( ( ( (A2:A6="Manu") + (A2:A6="Jean") + (A2:A6="Sophie") ) >0 ) * B2:B6)

En fait il faut ajouter un test logique (>0) sur l'ensemble des comparaisons logiques dont on fait la somme pour avoir 1 ou 0 que l'on multiplie par la valeur correspondante

[QuestVba]

Bonjour,

On risque d'arriver toujours à un style de formule comme la tienne. Il faudra bien additionner à un moment.

Tu peux faire avec SOMMEPROD

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD((A2:A6="Manu")*(B2:B6))+SOMMEPROD((A2:A6="Jean")*(B2:B6))+SOMMEPROD((A2:A6="Sophie")*(B2:B6))

Philippe est là !

Ou encore

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMME(SOMME.SI.ENS(B2:B6;A2:A6;"Manu");SOMME.SI.ENS(B2:B6;A2:A6;"Jean");SOMME.SI.ENS(B2:B6;A2:A6;"Sophie"))

[GerardCalc]

Bonjour,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD((A2:A6={"Manu"."Jean"."Sophie"})*B2:B6)

Le séparateur de colonne . (point) à l'intérieur de la constante de matrice dépend de la version d'Excel utilisée.
Le point si le séparateur décimal est la virgule (FR), l'anti-slash (\) ou la virgule si le séparateur décimal est le point.
A tester l'un des 3 suivant la version d'excel (2003,2007...etc ou FR/EN/Autre).

A+

[apnw7931]

Bonjour,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD((A2:A6={"Manu"."Jean"."Sophie"})*B2:B6)

Aaaah, merci, cela fonctionne comme je l'avais demandé!

Par contre, mais j'ai une (petite) demande supplémentaire..

Comment ajouter une cellule, plutôt que du texte ?
Du genre:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD((A2:A6={G6."Jean"."Sophie"})*B2:B6)

[Philippe Tulliez]

Bonjour,

Par contre, mais j'ai une (petite) demande supplémentaire..
Comment ajouter une cellule, plutôt que du texte ?

Dans ce cas là, tu peux utiliser une formule de la catégorie Base de données
Tu mets en G1 Prénom et ensuite G2:G4, les trois prénoms que tu veux avoir comme critères dans ton calcul.
La formule

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=BDSOMME(A1:B5;"Points";G1:G4)

[papouclo]

Bonjour à tous,
Mélanger des coordonnées de cellules et des constantes dans la formule semble impossible dans la formule de GerardCalc.
Si l'on en est à devoir réécrire les trois prénoms choisis dans des cellules, Philippe Tulliez a donné une piste à laquelle on ne pense pas assez souvent
avec les fonctions de la catégorie Base de données.
Mais si l'on veut employer SOMMEPROD, deux possibilités :
. Ecrire les trois prénoms choisis sur une seule ligne
par exemple en plage G6:I6 . On aura alors la réponse avec cette formule (rappelant celle de GerardCalc) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD((A2:A6=G6:I6)*B2:B6)

. Ecrire les prénoms sur une seule colonne
On prendra la précaution d'écrire les prénoms Manu, Jean, Sophie dans les cellules G6, G7 et G9 en laissant vide G8 et G10(Marc et Morgane non retenus). La formule sera :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD((A2:A6=G6:G10)*B2:B6)

Cordialement
Claude