Discussion :

[baime]

Bonjour,

J'ai un formulaire de recherche de données. Lorsque j'appuie sur rechercher il m'affiche le résultat dans le formulaire mais il se place aussi sur l'onglet ou se trouve toutes mes données.

Comment faire pour que l'onglet ou se trouve les données ne s'affiche pas. Un peu comme un ScreeUpdating

D'avance merci

[Didier Gonard]

Bonjour,

Si ça se produit, c'est qu'à un moment donné ton code le demande, peux-tu nous mettre la partie de code concernée (entre balises)

cordialement,

Didier

[baime]

Sur clic du bouton j'ai le code suivant

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
 
Private Sub Bt_Rechercher_Click()
 
onglet = "Liste des demandes"
 
    If UserForm2.TextBox1.Text = "" Then
        GoTo Erreur
    End If
 
Dim x As Long
Sheets(onglet).Activate
 
For x = 1 To Range("A65535").End(xlUp).Row
    If UCase(Range("A" & x)) Like "*" & UCase(UserForm2.TextBox1.Value) & "*" Then
        GoTo Trouve
        Exit For
    End If
Next x
 
GoTo Erreur
Exit Sub
 
Trouve: LigneActive = x
 
UserForm2.TextBox2.Value = Sheets(onglet).Cells(LigneActive, "B").Value
UserForm2.TextBox3.Value = Sheets(onglet).Cells(LigneActive, "D").Value
UserForm2.TextBox4.Value = Sheets(onglet).Cells(LigneActive, "E").Value
UserForm2.TextBox5.Value = Sheets(onglet).Cells(LigneActive, "F").Value
 
Exit Sub
 
Erreur: MsgBox ("Requête non trouvée et/ou Accents non acceptés !")
Exit Sub
 
End Sub

J'ai un Sheets(onglet).Activate mais je suis obligé de l'avoir sinon la recherche va se faire dans l'onglet d'ou se fait l'appel au UserForm de recherche.

il y a surement une autre méthode mais je ne sais pas faire;

Cordialement

[mercatog]

Essaies comme ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
with Sheets(onglet)
 
For x = 1 To .Range("A65535").End(xlUp).Row
    If UCase(.Range("A" & x)) Like "*" & UCase(UserForm2.TextBox1.Value) & "*" Then
        GoTo Trouve
        Exit For
    End If
Next x
 
GoTo Erreur
Exit Sub
 
Trouve: LigneActive = x
 
UserForm2.TextBox2.Value = .Cells(LigneActive, "B").Value
UserForm2.TextBox3.Value = .Cells(LigneActive, "D").Value
UserForm2.TextBox4.Value = .Cells(LigneActive, "E").Value
UserForm2.TextBox5.Value = .Cells(LigneActive, "F").Value
 end with

Sinon, ceci pourrait faire l'affaire (plus rapide)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Private Sub Bt_Rechercher_Click()
Dim x As Long, LigneActive As Long
Dim c As Range
Const Onglet = "Liste des demandes"
 
If UserForm2.TextBox1.Text <> "" Then
    With Sheets(Onglet)
        Set c = .Range(.Cells(1, 1), .Cells(Rows.Count, 1).End(xlUp)).Find(UserForm2.TextBox1.Value, lookat:=xlPart)
        If Not c Is Nothing Then
            LigneActive = c.Row
            UserForm2.TextBox2.Value = .Cells(LigneActive, "B").Value
            UserForm2.TextBox3.Value = .Cells(LigneActive, "D").Value
            UserForm2.TextBox4.Value = .Cells(LigneActive, "E").Value
            UserForm2.TextBox5.Value = .Cells(LigneActive, "F").Value
        Else
            MsgBox "Requête non trouvée et/ou Accents non acceptés !"
        End If
    End With
End If
End Sub

[baime]

Merci mercatog,

C'est super et en plus la 2eme solution donne un code beaucoup plus lisible

Merci pour l'optimisation

Est ce que tu saurais, je suis sur que tu sais, quel propriété de mon bouton je dois modifier pour que je ne sois pas obligé de cliquer avec la souris sur le bouton pour valider. Quand j'appuie sur "Entrée" il ne se passe rien

[mercatog]

Du moment que la propriété TabStop du bouton est à True et qu'il a le focus, Entrée agira comme le click.

[AlainTech]

Bonsoir,

C'est la propriété Default, à mettre à True.