Discussion :

[MichaSarah]

Bonjour,
Je suis actuellement bloqué sur le point suivant, peut-être pourriez-vous orienter mes recherches.
J'ai une ListBox que j'alimente comme suit

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
 
Private Sub UserForm_Activate()
     Dim NumLigne As String
 
     Windows("Pamm's.xls").Activate
     Sheets("Pamms").Select
     NumLigne = 7
 
                Do While Not IsEmpty(Cells(NumLigne, 28))
                    If Cells(NumLigne, 25) <> "" Then
                         If Cells(NumLigne, 2).Value = "" Then
 
                             Me.Questions.AddItem Cells(NumLigne, 28).Value
                             Me.Questions.List(Questions.ListCount - 1, 1) = Cells(NumLigne, 14).Value
                             Me.Questions.List(Questions.ListCount - 1, 2) = Cells(NumLigne, 1).Value
                             Me.Questions.List(Questions.ListCount - 1, 3) = Cells(NumLigne, 6).Value & Cells(NumLigne, 7).Value & Cells(NumLigne, 8).Value & Cells(NumLigne, 9).Value
                             Me.Questions.List(Questions.ListCount - 1, 4) = Cells(NumLigne, 25).Value
 
                       Else:
                            Me.Questions.AddItem Cells(NumLigne, 28).Value
                            Me.Questions.List(Questions.ListCount - 1, 1) = Cells(NumLigne, 14).Value
                            Me.Questions.List(Questions.ListCount - 1, 2) = Cells(NumLigne, 2).Value
                            Me.Questions.List(Questions.ListCount - 1, 3) = Cells(NumLigne, 6).Value & Cells(NumLigne, 7).Value & Cells(NumLigne, 8).Value & Cells(NumLigne, 9).Value
                            Me.Questions.List(Questions.ListCount - 1, 4) = Cells(NumLigne, 25).Value
 
                       End If
 
                    End If
                    NumLigne = NumLigne + 1
 
                Loop
 
End Sub

Je souhaiterais qu'en descendant dans la ListBox, Le contenu de la colonne 4 s'affiche dans un TextBox. Je ne sais pas quelle synthaxe noter dans le Private Sub Questions_Change

Pouvez-vous m'aider
Merci par avance

MichaSarah

[jojo86]

Salut je ne suis pas sur de ce que tu veux faire mais essaye:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 
'code a placer dans le onchange du listbox
Textbox1.Text= NomDuListBox.text

Il faut ajouter un textbox sur ta feuil.

Est-ce ca que tu souhaite realiser?

[MichaSarah]

Bonjour jojo86,
Le TextBox est bien présent sur mon formulaire. J'utilise déja la synthaxe que tu me propose ,elle fonctionne mais unquement lorsque la ListBox fait référence à une plage de cellules d'un fichier Excel. Je n'arrive pas à la faire fonctionner lorsque j'ajoute des éléments via "Additem" dans la listBox.

Salutations
MichaSarah

[patricktoulon]

bonjour

regarde dans les propriete de ta list box a quelle collone tu a mis la propriete "text"

au plaisir

[jojo86]

Peux tu réxpliquer ton probleme? Peux tu Resumer ton code? Je pense que le probleme est minime... Mais réxplique moi stp!

[MichaSarah]

Bonjour,
Mon code est le suivant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
 
Private Sub UserForm_Activate()
     Dim NumLigne As String
 
     Windows("Pamm's.xls").Activate
     Sheets("Pamms").Select
     NumLigne = 7
 
                Do While Not IsEmpty(Cells(NumLigne, 28))
                    If Cells(NumLigne, 25) <> "" Then
                         If Cells(NumLigne, 2).Value = "" Then
 
                             Me.Questions.AddItem Cells(NumLigne, 28).Value
                             Me.Questions.List(Questions.ListCount - 1, 1) = Cells(NumLigne, 14).Value
                             Me.Questions.List(Questions.ListCount - 1, 2) = Cells(NumLigne, 1).Value
                             Me.Questions.List(Questions.ListCount - 1, 3) = Cells(NumLigne, 6).Value & Cells(NumLigne, 7).Value & Cells(NumLigne, 8).Value & Cells(NumLigne, 9).Value
                             Me.Questions.List(Questions.ListCount - 1, 4) = Cells(NumLigne, 25).Value
 
                       Else:
                            Me.Questions.AddItem Cells(NumLigne, 28).Value
                            Me.Questions.List(Questions.ListCount - 1, 1) = Cells(NumLigne, 14).Value
                            Me.Questions.List(Questions.ListCount - 1, 2) = Cells(NumLigne, 2).Value
                            Me.Questions.List(Questions.ListCount - 1, 3) = Cells(NumLigne, 6).Value & Cells(NumLigne, 7).Value & Cells(NumLigne, 8).Value & Cells(NumLigne, 9).Value
                            Me.Questions.List(Questions.ListCount - 1, 4) = Cells(NumLigne, 25).Value
 
                       End If
 
                    End If
                    NumLigne = NumLigne + 1
 
                Loop
 
End Sub

Je souhaite pouvoir afficher dans un textbox le contenu de la dernière colonne

Salutations
MichaSarah

Bonjour patricktoulon,
Dans la fenêtre propriété le paramètre Text est vide

Salutations
MichaSarah

[mercatog]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Option Explicit
 
Private Sub UserForm_Initialize()
Dim LastLig As Long, i As Long
 
With Sheets("Pamms")
    LastLig = .Cells(Rows.Count, 28).End(xlUp).Row
    For i = 7 To LastLig
        If .Cells(i, 25) <> "" Then
            Me.Questions.AddItem .Cells(i, 28).Value
            Me.Questions.List(Questions.ListCount - 1, 1) = .Cells(i, 14).Value
            Me.Questions.List(Questions.ListCount - 1, 2) = IIf(.Cells(i, 2).Value = "", .Cells(i, 1).Value, .Cells(i, 2).Value)
            Me.Questions.List(Questions.ListCount - 1, 3) = .Cells(i, 6).Value & .Cells(i, 7).Value & .Cells(i, 8).Value & .Cells(i, 9).Value
            Me.Questions.List(Questions.ListCount - 1, 4) = .Cells(i, 25).Value
        End If
    Next i
End With
End Sub
 
Private Sub Questions_Change()
Me.TextBox1 = Me.Questions.List(Questions.ListIndex, 4)
End Sub

[MichaSarah]

Bonjour mercatog,
Merci beaucoup celà fonctionne. A moi maintenant d'assimiler la différence entre "Initialize" et "Activate"

MichaSarah

Re-bonjour mercatog,
Je viens comprendre (il me semble) que ce n'est pas l'utilisation de "Initialize" ou "Activate" qui posait problème pour mon cas mais ce que je mettais dans "Change"
Peux-tu m'expliquer succintement la synthaxe de :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
Me.TextBox1 = Me.Questions.List(Questions.ListIndex, 4)

merci
MichaSarah

[mercatog]

Rien de mieux que F1

List, propriété

Renvoie ou définit la liste des entrées d'un contrôle ListBox ou ComboBox.

Syntaxe

object.List( row, column ) [= Variant]

La syntaxe de la propriété List comprend les éléments suivants :

Élément Description
object Objet valide.
row Nombre entier compris entre zéro et le nombre d'entrée dans la liste moins 1.
column Nombre entier compris entre zéro et le nombre de colonnes moins 1.
Variant Facultatif. Contenu de l'entrée spécifiée dans le contrôle ListBox ou ComboBox.

Valeurs
La numérotation des lignes et colonnes commence à zéro. C'est-à-dire, le numéro de ligne de la première ligne de la liste est zéro ; le numéro de colonne de la première colonne est zéro. Le numéro de la deuxième ligne ou colonne est 1, et ainsi de suite.

Remarques

La propriété List fonctionne avec les propriétés ListCount et ListIndex. Utilisez la propriété List pour accéder à ces éléments. Une liste est un tableau de Variants ; chaque élément de la liste a un numéro de ligne et un numéro de colonne.

ListIndex, propriété

Identifie l'élément actuellement sélectionné dans un contrôle ListBox ou ComboBox.

object.ListIndex [= Variant]

La syntaxe de la propriété ListIndex comprend les éléments suivants :

Élément Description
object Objet valide.
Variant Facultatif. Élément actuellement sélectionné dans le contrôle


Remarques

La propriété ListIndex contient un index de la ligne sélectionnée dans la liste. Les valeurs de la propriété ListIndex sont comprises entre –1 et le nombre total de lignes de la liste moins 1 (c'est-à-dire, ListCount – 1). Lorsqu'aucune ligne n'est sélectionnée, la propriété ListIndex renvoie la valeur –1. Quand l'utilisateur sélectionne une ligne d'un contrôle ListBox ou ComboBox, le système définit la valeur de la propriété ListIndex. La valeur de la propriété ListIndex de la première ligne de la liste est zéro, la valeur de la deuxième liste est 1, et ainsi de suite.