Discussion :

[vivevba]

Bonjour,

Je suis tout jeune développeur en vba et j'ai besoin d'un peu d'aide. Par contre, je peux pas fournir maintenant le code sur lequel je travaille, puisque je développe sur le PC de mon lieu de mon stage et j'ai pas pensé à copier mon travail... (what a looser ;-))

Je demande à mon utilisateur d'entrer une date en paramètre. J'ai envie d'imposer que celle-ci soit de format JJ/MM/AAAA et que, si ce n'est pas le cas, mon "On Error Go to" soit appelé. Je définis ma variable de mon InputBox en date. Pourtant, si je rentre un chiffre sans /, vb traduit la variable en date (genre 13/03/1905 !). Comment faire pour lui faire retourner une erreur là dessus ?

Merci de m'aider si vous avez des idées

[Pierre Fauconnier]

Bonjour

Une date étant un nombre, il est normal que si tu saisis un nombre dans la plage des nombres évalués comme des dates, tu puisses le stocker dans une variable typée Date...

A mon avis, tu dois donc typer ta variable en Texte, puis la convertir en date et:
- soit gérer l'erreur via la gestion d'erreur
- soit gérer l'erreur par code

Personnellement, j'aime bien créer des petites fonctions simples à tester.

Voici une fonction qui permet de saisir une date et qui renvoie soit la date si la saisie est valide, soit 0 si la saisie n'est pas valide.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Function DateSaisie() As Date
    Dim MaDateTexte As String
    Dim MaDate As Date
 
    On Error GoTo Fin
 
    MaDateTexte = InputBox("Veuillez saisir une date au format jj/mm/aaaa")
    MaDate = DateSerial(Right(MaDateTexte, 4), Mid(MaDateTexte, 4, 2), Left(MaDateTexte, 2))
 
Fin:
    If Err <> 0 Then
        DateSaisie = 0
        Else
        DateSaisie = MaDate
    End If
End Function

Au sein d'une procédure, il suffit de tester la valeur renvoyée par la fonction

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
 
Sub TestDate()
    If DateSaisie() = 0 Then
        MsgBox "Mauvaise date"
        Else
        MsgBox "Bonne date"
    End If
End Sub

L'intérêt de travailler avec une fonction est que tu peux utiliser des paramètres optionnels pour tester la date saisie à l'intérieur d'une plage de dates.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Function DateSaisie(Optional LimiteInferieure As Date, Optional LimiteSuperieure As Date) As Date
    Dim MaDateTexte As String
    Dim MaDate As Date
 
    On Error GoTo Fin
 
    MaDateTexte = InputBox("Veuillez saisir une date au format jj/mm/aaaa")
    MaDate = DateSerial(Right(MaDateTexte, 4), Mid(MaDateTexte, 4, 2), Left(MaDateTexte, 2))
    If MaDate < LimiteInferieure Or MaDate > LimiteSuperieure Then MaDate = 0
Fin:
    If Err <> 0 Then
        DateSaisie = 0
        Else
        DateSaisie = MaDate
    End If
End Function

et stocker ainsi ta fonction dans "ta boite à fonctions" pour réutilisation dans d'autres projets.

[ucfoutu]

Bonjour,

ou tu évites ton Goto et procèdes ainsi (par exemple) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Dim madate As String, erreur As Boolean
  erreur = True
  Do While erreur
    madate = InputBox("Veuillez saisir une date au format jj/mm/aaaa")
    If IsDate(madate) And madate Like "##/##/####" And Val(Mid(madate, 4, 2)) <= 12 Then erreur = False
    If erreur Then MsgBox "erreur de saisie" ' ce n'est à mon avis pas nécessaire, mais bon ...
  Loop

edit :

que l'on peut aussi écrire ainsi, bien sûr :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Dim madate As String, erreur As Boolean
  erreur = True
  Do While erreur
    madate = InputBox("Veuillez saisir une date au format jj/mm/aaaa")
    erreur = Not (IsDate(madate) And madate Like "##/##/####" And Val(Mid(madate, 4, 2)) <= 12)
    If erreur Then MsgBox "erreur de saisie" ' ce n'est à mon avis pas nécessaire, mais bon ...
  Loop

Et rien ne t'empêche d'en faire une fonction, si tu veux, y compris en lui passant un filtre prédéfini comme paramètre, si tu veux ...