Discussion :

[neiluj26]

Bonjour le forum,

J'ai un tableau qui fait plusieurs dizaines de milliers de lignes. Dans la colonne BD d'une des feuilles, je voudrais faire la somme des colonnes O à AA pour chaque ligne de la ligne 2 à la dernière ligne non vide (que je définis et appelle LigFinPrev).
J'ai tenté d'utiliser une variable tableau. Etant grand débutant, je me suis inspiré d'un exemple trouvé dans la FAQ.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
 
Dim Montab As Variant, cmpt1 As Long, cmpt2 As Long
Montab = WsJoursPrev.Range("BD2:BD" & LigFinPrev).Value
 
For cmpt1 = LBound(Montab, 1) To UBound(Montab, 1)
    For cmpt2 = LBound(Montab, 2) To UBound(Montab, 2)
        Montab(cmpt1, cmpt2) = WorksheetFunction.Sum(WsJoursPrev.Range("O" & cmpt1 & ":AA" & cmpt1))
    Next cmpt2
Next cmpt1
 
WsJoursPrev.Range("BD2:BD" & LigFinPrev).Value = Montab

Le problème est que la macro calcule bien les sommes mais le résultat est reporté dans la ligne du dessous. (Dans BD3, je retrouve le résultat de [O2:AA2] et ainsi de suite...

Merci de vos lumières encore une fois.

[pgz]

Bonjour.

Cmpt1 commence à 1. Tu calcules alors la cellule BD2, mais tu fais la somme O1:AA1.

PGZ

RE,

Si tu as un grand nombre de lignes, il faudrait éviter les fonctions de feuille.
Par exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Dim TabRes As Variant, TabDon As Variant
Dim nbL As Long, nbC As Long
 
TabDon = WsJoursPrev.Range("O2:AA" & LigFinPrev).Value
TabRes = WsJoursPrev.Range("BD2:BD" & LigFinPrev).Value
 
For nbL = LBound(TabDon, 1) To UBound(TabDon, 1)
    TabRes(nbL, 1) = 0
    For nbC = LBound(TabDon, 2) To UBound(TabDon, 2)
        TabRes(nbL, 1) = TabRes(nbL, 1) + TabDon(nbL, nbC)
    Next nbC
Next nbL
 
WsJoursPrev.Range("BD2:BD" & LigFinPrev).Value = TabRes
 
Erase TabDon
Erase TabRes

PGZ

[neiluj26]

Evidemment, ça fonctionne super bien. Merci.

J'avais une autre question. Dans la colonne BE de la même feuille, je voudrais diviser le résultat de BD par 65 (et l'arrondir à deux décimales). Comme je suis encore un peu perdu avec les variables tableaux, je pensais reprendre le code que tu m'as donné en l'adaptant pour la colonne BE. Mais est-ce qu'il y a plus simple?

[pgz]

Avec le calcul de BE. J'ai pris le nb de colonne "O:AA" au lieu de 65.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Dim TabRes As Variant, TabDon As Variant, TabMoy As Variant
Dim nbL As Long, nbC As Long
 
TabDon = WsJoursPrev.Range("O2:AA" & LigFinPrev).Value
TabRes = WsJoursPrev.Range("BD2:BD" & LigFinPrev).Value
TabRes = WsJoursPrev.Range("BE2:BE" & LigFinPrev).Value
 
For nbL = LBound(TabDon, 1) To UBound(TabDon, 1)
    TabRes(nbL, 1) = 0
    For nbC = LBound(TabDon, 2) To UBound(TabDon, 2)
        TabRes(nbL, 1) = TabRes(nbL, 1) + TabDon(nbL, nbC)
    Next nbC
    TabMoy(nbL, 1) = TabRes(nbL, 1) / (nbC-1)
Next nbL
 
WsJoursPrev.Range("BD2:BD" & LigFinPrev).Value = TabRes
WsJoursPrev.Range("BE2:BE" & LigFinPrev).Value = TabMoy
 
Erase TabDon
Erase TabRes
End Sub

A mettre au mpoint.

PGZ

[neiluj26]

Malheureusement, j'ai une incompatibilité de type au niveau de la ligne:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
    TabMoy(nbL, 1) = TabRes(nbL, 1) / (nbC-1)

J'avoue ne pas avoir encore bien compris le fonctionnement de ce code. Je tâche de creuser.

[pgz]

Il y a une erreur dans le code.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

TabRes = WsJoursPrev.Range("BE2:BE" & LigFinPrev).Value

Au temps pour moi :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

TabMoy = WsJoursPrev.Range("BE2:BE" & LigFinPrev).Value

COmme je n'ai pas testé, il peut y en avoir d'autres...

PGZ

[neiluj26]

C'était bien l'erreur. J'obtiens les bons résultats maintenant... il me reste plus qu'à tout décortiquer pour comprendre le fonctionnement.
A moins que tu te sentes le courage de me l'expliquer

[pgz]

Dans le principe, c'est très simple.
Tu as un tableau de données de la colonne O à AA.
Tu veux calculer en BD la somme des valeurs sur chaque ligne, et en BE la moyenne.
On crée 3 tableaux :

• TabDon représente les données de O à AA et a autant de colonnes
• TabRes représente la colonne BD, 1 colonne (somme)
• TabMoy représente la colonne BE, 1 colonne (moyenne =somme/nb colonnes de TabDon)

On charge les valeurs dans TabDon et on charge TabRes et TabMoy juste pour dimensionner ces tableaux.

Ensuite pour chaque ligne (nbl) on additionne le contenu de chaque colonne (nbC) et cela donne la somme.
On divise la somme par le nombre de colonnes.

Et voilà.

PGZ

[neiluj26]

Je crois que c'est plus clair maintenant. Merci. Je vais relire le tutoriel et voir si on peut appliquer ce code pour des recherches par exemple.