1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102
|
Option Compare Database
'Tout d'abord, ajouter une référence Microsoft DAO à votre projet (sous VBA, outils, références)
Public Enum Demarrage
AutoriserMenuContextuel
NomTitreApplication
AutoriserMenuComplet
AutoriserTouchesSpeciales
AfficherFenetreBD
AfficherBarreEtat
AfficherBarreOutils
AutoriserModificationBarreOutils
NomIcone
NomFormualireDemarrage
NomMenuContextuel
NomBarreMenu
End Enum
Public Sub ChangerPropriete(nom As Demarrage, Valeur)
Dim Db As DAO.Database
Set Db = CurrentDb
Dim NomProp As String
NomProp = NomPropriete(nom)
If testProperty(Db, NomProp) Then
Db.Properties(NomProp).value = Valeur
Else
Db.Properties.Append Db.CreateProperty(NomProp, TypePropriete(nom), _
Valeur, False)
End If
'Si on modifie le titre, alors prendre la modification
' en compte immédiatement
'If NomProp = 1 Then Application.RefreshTitleBar
End Sub
Private Function testProperty(Objet As Object, nom As String) As Boolean
On Error GoTo err
Dim Prop As DAO.Property
Set Prop = Objet.Properties(nom)
testProperty = True
err:
End Function
Private Function NomPropriete(Valeur As Demarrage) As String
Select Case Valeur
Case 0
NomPropriete = "AllowShortcutMenus"
Case 1
NomPropriete = "AppTitle"
Case 2
NomPropriete = "AllowFullMenu"
Case 3
NomPropriete = "AllowBypassKey"
Case 4
NomPropriete = "StartupShowDBWindow"
Case 5
NomPropriete = "StartupShowStatusBar"
Case 6
NomPropriete = "AllowBuiltInToolbars"
Case 7
NomPropriete = "AllowToolbarChanges"
Case 8
NomPropriete = "AppIcon"
Case 9
NomPropriete = "StartupForm"
Case 10
NomPropriete = "StartupShortcutMenuBar"
Case 11
NomPropriete = "StartupMenuBar"
End Select
End Function
Private Function TypePropriete(Valeur As Demarrage) As Integer
Select Case Valeur
Case 1, 8, 9, 10, 11
TypePropriete = dbText
Case Else
TypePropriete = dbBoolean
End Select
End Function
'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
'Exemple d'utilisation à placer dans la sub qui va bien
'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
''choisir l'icone
'ChangerPropriete NomIcone, "c:\fich.ico"
''Choisir la barre de menu
'ChangerPropriete NomBarreMenu, "MaBarre"
''Choisir le nom de l'application
'ChangerPropriete NomTitreApplication, "MonApplication"
''masquer le fenêtre de BD au démarrage
'ChangerPropriete AfficherFenetreBD, False
''interdire la modification des barres d'outils
'ChangerPropriete AutoriserModificationBarreOutils, False
'Même si les informations sont enregistrées à la fin de ce traitement, celles-ci _
ne prendront effet qu'au prochain démarrage de l'application. _
Exception : la modification du titre de la fenêtre Access peut _
être prise en compte immédiatement grâce à la méthode RefreshTitleBar. |
Partager