Discussion :

[jibouze]

Bonjour à tous,
voila mon pb :
je crée un formulaire dynamiquement (je lance une requete et je crée autant de controles que j'ai de resultats).
Mon problème est que, les controles étant créés dynamiquement, je ne peux pas leur associer d'évènement à l'avance.
Or, il faudrait que je détecte si on clique dessus pour pouvoir lancer une série d'instructions
J'imagine que ce pb a déjà du etre soulevé, mais si quelqu'un veut bien me dire ou je peux trouver la réponse à mon pb (à défaut de me la donner), ce serait déjà serait fantastique.
En tout cas, je vais continuer mes recherches sur ce forum qui n'est pas petit.
Merci d'avance

[Tofalu]

Désolé mais je crains qu'il n'y est pas de solution à ton problème.

Pourquoi passes tu par un formulaire dynamique ?

[FRED.G]

Désolé mais je crains qu'il n'y est pas de solution à ton problème.

Pas si sûr

Voici un emxple de code qui crée un formulaire et des contrôles (2 traits et deux boutons de commande) avec du code sur clic des boutons et sur le timer du form :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
Sub sDynamic()
 
Dim frm As Form
Dim mdl As Module
Dim lng As Long
Dim str As String
Dim ctl As Control
 
Set frm = Application.CreateForm()
With frm
  .Width = 12 * 567
  .Section(acDetail).Height = 10 * 567
  .HasModule = True
  Set mdl = .Module
 
  Set ctl = Application.CreateControl(.Name, acLine, , , , 567, 567, 0, 0)
  ctl.Name = "trtH"
  Set ctl = Application.CreateControl(.Name, acLine, , , , 567, 567, 0, 0)
  ctl.Name = "trtV"
 
  Set ctl = Application.CreateControl(.Name, acCommandButton, , , , 8 * 567, 567, 2 * 567, 567)
  ctl.Name = "btcInitialise"
  ctl.Caption = "Initialise"
  lng = mdl.CreateEventProc("Click", ctl.Name)
  str = vbTab & "trtH.Width = 0" & vbCrLf & _
        vbTab & "trtV.Height = 0" & vbCrLf & _
        vbTab & "Me.TimerInterval = 0"
  mdl.InsertLines lng + 2, str
 
  Set ctl = Application.CreateControl(.Name, acCommandButton, , , , 8 * 567, 2 * 567, 2 * 567, 567)
  ctl.Name = "btcGo"
  ctl.Caption = "Go"
  lng = mdl.CreateEventProc("Click", ctl.Name)
  str = vbTab & "Me.TimerInterval = 1"
  mdl.InsertLines lng + 1, str
 
  lng = mdl.CreateEventProc("Timer", "Form")
  str = vbTab & "Select Case trtH.Width" & vbCrLf & _
        vbTab & "  Case Is >= (6 * 567)" & vbCrLf & _
        vbTab & "    Me.TimerInterval = 0" & vbCrLf & _
        vbTab & "    Me.TimerInterval = 0" & vbCrLf & _
        vbTab & "  Case Else" & vbCrLf & _
        vbTab & "    trtH.Width = trtH.Width + 48" & vbCrLf & _
        vbTab & "End Select" & vbCrLf & _
        vbTab & "Select Case trtV.Height" & vbCrLf & _
        vbTab & "  Case Is >= (6 * 567)" & vbCrLf & _
        vbTab & "    Me.TimerInterval = 0" & vbCrLf & _
        vbTab & "  Case Else" & vbCrLf & _
        vbTab & "    trtV.Height = trtV.Height + 48" & vbCrLf & _
        vbTab & "End Select"
  mdl.InsertLines lng + 2, str
 
  DoCmd.OpenForm .Name
End With
Set ctl = Nothing
Set mdl = Nothing
Set frm = Nothing
 
End Sub

jibouze, je pense que tu sauras adapter ce code sans problème, sinon fait-nous signe

[jibouze]

Bonjour,
merci pour la solution. Je ne connaissai pas la méthode CreateEventProc. Je vais regarder de ce pas dans l'aide d'access des fois que... et je vais me servir de l'exemple que vous m'avez fourni.
Pour répondre à la question du pourquoi, et bien c'est tout simplement que si je connais bien le nombre de champs à l'avance, je ne connais pas le nombre de lignes que je vais avoir. De plus, il me faut un formattage particulier (donc pas dans une listbox) selon les lignes. En gros j'ai :
- chapitre 1
- sous-chapitre 1
-sous-sous-chapitre 1
...
Et comme je veux pouvoir ajouter des sous-sous-chapitres ou en enlever, il faut que je détecte si on clique dessus.
Je pense pouvoir m'en sortir avec ce que vous m'avez donné, mais si quelqu'un a une autre astuce du tonnerre...je suis preneur
Merci encore