Discussion :

[Marc_Ingé]

Bonjour,

J'ai encore besoin de votre aide... J'expose mon soucis:
L'objetcif est :de remplir un formulaire dans la "ID_PROJET" de le fichier Excel. Un fois rempli tout, on fait "Enregistrer" et ces données s'ajouteront dans le tableau "BDD_Mots_clés" au fur et à mesure.
Je souhaiterai faire cela en VBA. J'ai déjà commencé à réaliser un code mais je n'y arrive toujours pas... Cela fait trois jours et je n'ai toujours pas la solution...

Voici mes éléments de la "ID_Projet":


Mon tableau (considéré comme une "base de donnée"):


Voici le code que j'ai essayé de faire:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Sub Enregistrement_Mots_clés()
'
'
Dim Chemin As String, ChampDest As Integer
Dim Nomprojet, Emplacement, Motclé1, Motclé2, Motclé3, Motclé4, Motclé5 As String
 
 
    Nomprojet = Sheets("ID_projet").Range("B3").Value
    Emplacement = Sheets("ID_projet").Range("B10").Value
    Motclé1 = Sheets("ID_projet").Range("N40").Value
    Motclé2 = Sheets("ID_projet").Range("N41").Value
    Motclé3 = Sheets("ID_projet").Range("N42").Value
    Motclé4 = Sheets("ID_projet").Range("N43").Value
    Motclé5 = Sheets("ID_projet").Range("N44").Value
 
ChampDest = ActiveWorkbook.Sheets("BDD_Mots_clés").Range("B" & Rows.Count).End(xlUp).Row + 1
 
    Sheets("BDD_Mots_clés").Range("G" & ChampDest).Value = Nomprojet
    Sheets("BDD_Mots_clés").Range("A" & ChampDest).Value = Emplacement
    Sheets("BDD_Mots_clés").Range("B" & ChampDest).Value = Motclé1
    Sheets("BDD_Mots_clés").Range("C" & ChampDest).Value = Motclé2
    Sheets("BDD_Mots_clés").Range("D" & ChampDest).Value = Motclé3
    Sheets("BDD_Mots_clés").Range("E" & ChampDest).Value = Motclé4
    Sheets("BDD_Mots_clés").Range("F" & ChampDest).Value = Motclé5
 
 
End Sub

Cependant, mon tableau ne s'incrémente pas au fur et à mesure... Il y a toujours une seule ligne

Merci d'avance pour votre aide,

Marc

[BENNASR]

bonjour
1 : définir ChampDest as long
2 : Sheets("ID_projet") est un formulaire ??

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Nomprojet = Sheets("ID_projet").Range("B3").Value
 
Sheets("BDD_Mots_clés").Range("G" & ChampDest).Value = Nomprojet

pourquoi ne pas faire simplement :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Sheets("BDD_Mots_clés").Range("G" & ChampDest).Value =Sheets("ID_projet").Range("B3").Value

[Pierre Fauconnier]

Salut

Il FAUT utiliser les tableaux structurés pour ce genre de traitements, et idéalement s'appuyer sur un formulaire dans lequel tu nommes tes cellules.

Ici, j'ai un tableau structuré nommé t_Contacts et un "formulaire" constitué de trois cellules nommées f_Nom, f_Prénom et f_DateNaissance. J'ai une fonction générique qui permet de transférer n'importe quel "formulaire" vers n'importe quel tableau structuré

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Function AddData(TableName As String, Map)
  Dim r As Long
  Dim i As Long
  Dim t As ListObject
 
  Set t = Range(TableName).ListObject
  r = t.ListRows.Add.Index
  For i = LBound(Map) To UBound(Map) Step 2
    t.ListColumns(Map(i + 1)).DataBodyRange(r).Value = Range(Map(i)).Value
  Next i
  Set t = Nothing
End Function

Avec le classeur conçu comme décrit plus haut, voici LA ligne de code pour transférer les données du formulaire vers le tableau: AddData "t_Contacts", VBA.Array("f_Nom", "Nom", "f_Prénom", "Prénom", "f_DateNaissance", "DN")
Tu remarqueras que grâce au tableau structuré et au cellules nommées, mon code est entièrement découplé des positions des cellules sur la feuille => Tu peux déplacer les cellules du formulaire ou le tableau, même sur une autre feuille, et le code continue à fonctionner. Si demain tu as un autre formulaire à transférer dans un autre tableau structuré, tu as simplement la ligne adddata ... à modifier (nom du tableau et array de mappage formulaire/table)





Si je crée un nouveau formulaire lié à un nouveau tableau structuré, j'utilise la même fonction puisqu'elle est générique. Si j'ai un formulaire de facture (ff_numéro, ff_Client, ff_Date, ff_Échéance, ff_Montant) à transférer vers un tableau f_Factures constitué des colonnes Facture, Date, Client, Montant, Echéance, j'utilise simplement LA ligne de code AddData "t_Factures", VBA.Array("ff_Client", "Client", "ff_Date", "Date", "ff_Numéro", "Facture", "ff_Montant", "Montant", "ff_Echéance", "Échéance")

En généralisant mon approche, je gagne en stabilité du code, en lignes de code, en rapidité de codage, en maintenance et en évolution. Je pourrais même passer par une table de mappage en Excel qui reprendrait toutes les paires Cellule/Colonne de tous mes paires formulaire/Tableau structuré pour avoir une approche encore plus générique.

[Pierre Fauconnier]

Pour compléter, répondre à ta question et enfoncer le clou par rapport au tableau structuré...

Si "ça ne s'incrémente pas", il faut chercher du côté de ChampDest, puisque c'est lui qui détermine la ligne sur laquelle déposer tes données. ChampDest est déterminé par rapport à la colonne B avec un "beau" mais antédiluvien End(xlUp)... Si tu n'as pas de données en B, ton indice de ligne va être faussé.

Ce problème n'apparaît pas avec le tableau structuré car le code ajoute une ligne au tableau, sans que certaines cellules vides sur la dernière ligne posent problème, et même en présence d'une ligne de total.

C'est pourquoi je pense que l'utilisation des tableaux structurés s'impose à tout qui veut écrire du code professionnel