Discussion :

[weetoz]

Bonjour à tous,

Mes combobox son sur la feuille "FormulaireHeure" (Feuil1), et mes données sont sur la feuille "ListeText"(Feuil3).
La partie de code qui "anime" les combobox sont donc sur Feuil1(FormulaireHeure).
Je voudrais arriver à ne plus mentionner le nom de la feuille "ListeText" en dur dans le code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
 
Private Sub CB_NumAff_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
Dim numAff As Variant, c As Range
Debug.Print "CB_NumAff.ListCount: " & Me.CB_NumAff.ListCount
    If KeyCode = 13 Then  'And Me.CB_NumAff.ListIndex >= 0
        numAff = Me.CB_NumAff.Value
 
        'Ce qui fonctionne:
        Set c = Sheets("ListeText").ListObjects("T_Affaire").DataBodyRange.Find(numAff)
 
        'Ce que je voudrais obtenir:
        Set c = ThisWorkbook.[T_Affaire].DataBodyRange.Find(numAff)
 
 
        MsgBox c.Row
        Set c = Nothing
    End If
End Sub

J'ai compris qu'un tableau structuré est un objet "ListObjets" qui appartient à la collection "ListObjet" appartenant à l'objet "WorkSheet" de la collection....
Mais je ne comprends pas le concept de collection...

Au final ma question est comment rendre l'appel d'un "listObjects" indépendamment de la feuille où il se trouve?
Je cherche à pouvoir déplacer le tableau sur une autre feuille sans à avoir à rechercher et modifier dans le code tout les ' Sheets("listeText") par le nom de la nouvelle feuille.

J'espère avoir été explcite...
Merci d'avance.

[Philippe Tulliez]

Bonjour,
Pour vous affranchir du parent de l'objet ListObjet (lWorksheet), vous pouvez utiliser l'instruction Range("Nom du Tableau") qui renvoie un objet Range qui représente la propriété DataBodyRange de l'objet ListObject

Autrement dit si le tableau structuré nommé t_MyData se trouve dans la feuille nommée maFeuille
Range("t_MyData"), c'est l'équivalent de Worksheets("maFeuille").LIstObjects("t_MyData").DataBodyRange

et pour répondre à votre question

Mais je ne comprends pas le concept de collection...

Une collection regroupe, tout objet de même nature et se caractérise dans sa syntaxe par un s final.
Worksheets(1) est un objet de type Worksheet qui représente la première feuille de la collection Worksheets

Pour en savoir plus sur l'objet ListObject, ses méthodes et propriétés, je ne peux que vous conseiller la lecture de Excel: Les tables de données en VBA

[weetoz]

Bonjour Philippe,
j'ai essayé d'appliquer votre démonstration sans succès:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Sub tatita()
Dim numAff As Variant, c As Range
        numAff = "3137"
        Set c = Range("T_Affaire").Find(numAff)
        MsgBox c.Row
        Set c = Nothing
End Sub

Le fait est que dans un module "hors feuille" cela fonctionne très bien, mais dans un module 'Feuil1(maFeuille)' Excel me renvoie une erreur 1004, erreur défini par l'application ou par l'objet.

Alors j'ai essayé ça:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Sub tatita()
Dim numAff As Variant, c As Range
        numAff = "3137"
        Set c = Worksheets.Parent.Range("T_Affaire").Find(numAff)
        MsgBox c.Row
        Set c = Nothing
End Sub

Sans succès... erreur 438 ou 424 ( avec Worksheets.Parent.Range("T_Affaire").Find(numAff) ou Worksheet.Parent.Range("T_Affaire").Find(numAff) )

Je suppose que le souci est de l'arborescence des collections et objets... Mais je n'en comprends pas les mécanismes...

[Philippe Tulliez]

Bonjour,

Le fait est que dans un module "hors feuille" cela fonctionne très bien, mais dans un module 'Feuil1(maFeuille)' Excel me renvoie une erreur 1004, erreur défini par l'application ou par l'objet.

Si vous avez écrit la procédure dans un module feuille et que le tableau ne se trouve pas dans cette feuille, c'est tout à fait normal

Vous devez alors écrire une procédure avec paramètres que vous placez dans un module standard et qui sera invoquée depuis votre procédure événementielle

[Pierre Fauconnier]

Salut.

C'est normal à partir du moment où ton range n'est pas positionné sur la feuille dont tu pilotes le module.

Normalement, un module de feuille ne devrait rien faire d'autre que de gérer la feuille dont il est le module. Si tu as besoin de code qui triture d'autres feuilles (ou des plages placées sur d'autres feuilles), tu devrais déporter ton code dans un module standard et l'appeler de la feuille que tu pilotes.

Par exemple, si tu as un listobject "t_Données" sur Feuil1 et que tu veux rechercher une donnée dans cette plage au départ de Feuil2, tu devrais utiliser une fonction dans un module standard qui renvoie la cellule trouvée et utiliser cette cellule au sein de Feuil2.

Dans le module standard:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Function getCell(Value) As Range
  Set getCell = Range("t_Données").Find(Value)
End Function

Dans Feuil2:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
  Dim r As Range
 
  Set r = getCell(Target.Value)
  If Not r Is Nothing Then MsgBox r.Address
End Sub

[Pierre Fauconnier]

[...]
J'ai compris qu'un tableau structuré est un objet "ListObjets" qui appartient à la collection "ListObjet" appartenant à l'objet "WorkSheet" de la collection....
Mais je ne comprends pas le concept de collection...[...]

C'est l'inverse: Un tableau structuré est un ListObject (sans s à la fin) qui fait partie de la collection ListObjects (avec s à la fin) d'une feuille. Une collection est simplement un ensemble d'éléments de même nature. Si tu as plusieurs tableaux structurés sur une feuille, cette feuille contient une collection ListObjects qui reprend tous les tableaux structurés de la feuille.

[weetoz]

Bonjour et merci Pierre,

c'est déjà plus clair