Discussion :

[Mickamax]

Bonjour à tous,

Voici mon problème: J'ai créé un bout de macro tel quel:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
For N = 2 To DligneNA
If IsError(Cells(N, 10)) Then MsgBox ("Le Code société " & Cells(N, 7) & " ne correspond pas dans le référentiel !")
Next N

ça fonctionne sans soucis.
En N7= des codes 5 digits.
En N10= parfois des #N/A

Cependant, il est fréquent que le code en N7 soit le même pour plusieurs lignes de ma boucle, ce qui occasionne le même Msgbox. Je souhaiterais ainsi ne recevoir ce code qu'une seule fois.

Ce à quoi j'ai pensé :

Stocker le code à part, puis faire à nouveau une boucle sur ces codes stockés et supprimer les doublons pour faire à nouveau un msgbox sur ces codes triés.


Ca fonctionnerait, mais je pense qu'il existe une méthode plus simple et je m'en remet aux experts de ce forum. Si il n'y a pas plus simple, je garderait cette méthode;


J'espère m'être fait comprendre !

Bonne journée,
Mickamax

[Menhir]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Dim CC As String
CC = ""
For N = 2 To DligneNA
    If IsError(Cells(N, 10)) Then CC =  CC & Chr(13) &Cells(N, 7)
Next N
If Len(CC) > 0 Then MsgBox ("Le(s) Code(s) société(s) suivant(s) ne correspond(ent) pas dans le référentiel !" & CC)

[MarcelG]

Salut,

Mickamax,

Il ne faut pas confondre Cells(N, 7) et N7.

Menhir,

Dis-moi si je me trompe.
Dans ton message, unique certes, seront reportés plusieurs fois les mêmes codes.

Personnellement, j'aurais créé un dictionnaire sur les codes dont la formule dépendante est en erreur.
Plus précisément, j'aurais balayé les cellules spéciales de formules en erreur en colonne 10

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

SpecialCells(xlCellTypeFormulas, xlErrors)

et alimenté le dictionnaire des codes reportés dans la colonne 7.
Et dans le message,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Join(dico.Keys, "-")

[OrDonc]

Bonsoir…

J’en étais resté là

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Sub e()
    Dim Zone As Range, R As Range, S As String
    Set Zone = Range("J2", Cells(Rows.Count, 10).End(xlUp))
    For Each R In Zone
        If IsError(R) Then S = S & R.Address & vbLf
    Next
    If S <> "" Then MsgBox S, , "Code absent en"
End Sub

Remarque : dans le code de Menhir, on peut se dispenser de la deuxième ligne (la variable est initialisée dès sa déclaration).

De Marcel
Dis-moi si je me trompe.
Dans ton message, unique certes, seront reportés plusieurs fois les mêmes codes.

Je ne comprends pas cela par contre ton code est le bienvenu (voir ci-dessous).

Une solution MFC serait acceptable ?

[MarcelG]

Bonjour à vous, Bonjour au Forum,

Le test s'effectue sur les formules en erreur.
Au demeurant, ce sont les dépendants de celles-ci, donc les codes, qui alimentent le dictionnaire.

ACTIVER LA REFERENCE MICROSOFT SCRIPTING.RUNTIME
(Menu Outils\Références de l'éditeur VBE)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Option Explicit
 
Public Sub dico_erreurs()
 
Dim dernl As Long
Dim c As Range
 
Dim dico As Scripting.dictionary
 
Set dico = CreateObject("Scripting.Dictionary")
 
With ThisWorkbook.Worksheets("lawks")
        dernl = .Cells(.Rows.Count, 7).End(xlUp).Row
        For Each c In .Range("J2:J" & dernl).SpecialCells(xlCellTypeFormulas, xlErrors)
                With c.Offset(0, -3)
                        If Not dico.Exists(.Value) Then dico.Add .Value, .Value
                End With
        Next c
End With
 
MsgBox _
        Prompt:="Les codes suivants sont en erreur." & Chr(13) _
                                    & Join(dico.Keys, " - "), _
        Buttons:=vbCritical, _
        Title:="Codes en erreur."
 
Set dico = Nothing
 
End Sub

A noter:
1 - La déclaration du dictionnaire peut être formulées de plusieurs façons.
La méthode utilisée ici permet une saisie facilitée des propriétés et méthodes.
Elle nécessite néanmoins l'activation de la Référence Microsoft Scripting.Runtime
2 - Le 2ème paramètre xlErrors de la méthode SpecialCells permet une sélection plus fine
3 - l'argument "séparateur" de la méthode Join est ici précisé.
A défaut, celui-ci est un espace.

[Menhir]

Remarque : dans le code de Menhir, on peut se dispenser de la deuxième ligne (la variable est initialisée dès sa déclaration).

Ne sachant pas ce qui, dans ton code, précède les lignes données, j'ai préféré prendre des précautions qui, de toute façon, n'entravent pas l'exécution.