Discussion :

[AntoineCompagnie]

J'ai fait une méthode qui prend un tableau d'objet global `arrayOReservists`, qui représente des gens, et qui affiche ses objets, c'est à dire chaque personne, dans une ListBox.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
            ' On remplit la ListBox des résultats avec les noms et prénoms des personnels
            ListBoxResults.AddItem (arrayOReservists(i).Surname & " " & arrayOReservists(i).Name)
            ' On redimensionne le tableau
            i = i + 1

Une autre méthode, `ListBoxResults_DblClick`, réagit lorsque je double-clique sur l'une des lignes de la ListBox. Elle affiche une UserForm à laquelle j'aimerais transmettre l'objet sur lequel j'ai cliqué. Cependant je ne sais pas comment y avoir accès à cet objet. J'ai l'impression que les données transmises à la ListBox par AddItem sont transformées en texte.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
    Private Sub ListBoxResults_DblClick(ByVal Cancel As MSForms.ReturnBoolean)
        Dim Msg As String
        Dim i As Integer
        Dim newInstanceOfMe As Object
 
        ' On cherche le nom et le prénom du réserviste sur lequel on a cliqué
        For i = 0 To ListBoxResults.ListCount - 1
            If ListBoxResults.Selected(i) Then
                ReservistName = ListBoxResults.List(i)
            End If
        Next i
 
        ' Prise en compte du cas où l'on clique sur la TextBox Results alors que celle-ci est vide
        If False Then
            If ReservistName <> "" Then
                Set newInstanceOfMe = UserForms.Add(Me.Name)          
                newInstanceOfMe.Caption = ReservistName
                newInstanceOfMe.Show
                Unload newInstanceOfMe
                Set newInstanceOfMe = Nothing
            End If
        End If
        ' passer le nom, le prénom à ReservistUserForm et dans le Load qui filtrer la liste à partir de ces champs en obtenant l'objet oReservist.
        ' Una vez tengas la informacion de ese usuario lo siguiente sera mapear la informacion a los textBox correspondientes.
        ReservistFormUserForm.Caption = ReservistName
        ReservistFormUserForm.Show
 
    End Sub

En effet quand j'affiche `MsgBox (ListBoxResults.List(i))` j'ai uniquement le nom et le prénom et non pas l'objet.

Par conséquent comment stocker des objets dans une ListBox vba et les récupérer lorsque nous cliquons dessus ? Cela me permettrait, par exemple, de les mettre dans une variable globale à laquelle j'aurais accès dans l'objet UserForm.

Annexe
Voici l'interface avec la ListBox si cela est plus parlant:

[Patrice740]

Bonjour,

On ne peut pas stocker des objets dans un ListBox, mais uniquement des valeurs.
Utilises une Collection pour stocker les objets et mets la liste des clés dans le ListBox.

[boisgontierjacques]

Bonjour,

Je ne suis pas sûr d'avoir compris.
Voici un exemple de ListBox avec récupération d'une ligne de ListBox pour alimenter les zones d'un formulaire.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Private Sub ListBox1_Click()
  For i = 1 To NbCol
    tmp = Me.ListBox1.Column(i - 1)
    If Not IsError(tmp) Then Me("textbox" & i) = tmp
  Next i
  Me.Enreg = Me.ListBox1.Column(NbCol)
End Sub

Boisgontier

[Pierre Fauconnier]

Salut.

En me tenant à l'intitulé de ta question, je pars sur l'idée de Patrice d'utiliser une collection de laquelle on extrait un élément en fonction du listindex de la listbox (attention, commence à 0 pour le premier élément).



Pour l'exemple, j'ai créé une classe Contact contenant deux propriétés autoimplémentées et une en lecture seule qui recompose le nom complet

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Option Explicit
 
Public FirstName As String
Public LastName As String
 
Property Get LongName() As String
  LongName = FirstName & " " & LastName
End Property

• On munit un userform usfContacts d'une propriété Contacts As Collection;
• Avant d'afficher le userform, on passe à cette collection la collection des contacts que l'on veut gérer;
• A l'activation, on lit les longName de la collection pour alimenter la listbox;
• Au clic sur un item de la listbox, on alimente les textbox via une procédure dédiée;
• Au clic sur Enregistrer, on met le contact à jour dans la collection et on rafraichit la listbox, à nouveau via une procédure dédiée;
• Au clic dur Quitter, on masque le userform et on récupère la collection des contacts mis à jour.

Voici le code du userform, qui se lit facilement. On voit que les événements appellent les procédures dédiées et ne traitent pas eux-mêmes l'information.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
Option Explicit
 
Public Choice As String
Private mContacts As Collection
 
Property Get Contacts() As Collection
  Set Contacts = mContacts
End Property
 
Property Let Contacts(Contacts As Collection)
  Set mContacts = Contacts
End Property
 
Private Sub btnQuit_Click()
  Me.Hide
End Sub
 
Private Sub btnSave_Click()
  SaveContact
End Sub
 
Private Sub lboContacts_Click()
  PrepareContact
End Sub
 
Private Sub UserForm_Activate()
  AddContactsToList
End Sub
 
Sub AddContactsToList()
  Dim s As String
  Dim c As Contact
 
  For Each c In mContacts
    lboContacts.AddItem c.LongName
  Next
End Sub
 
Sub PrepareContact()
  With mContacts(lboContacts.ListIndex + 1)
    tboFirstName.Value = .FirstName
    tboLastName.Value = .LastName
  End With
End Sub
 
Sub SaveContact()
  With mContacts(lboContacts.ListIndex + 1)
    .FirstName = tboFirstName.Value
    .LastName = tboLastName.Value
  End With
  lboContacts.List(lboContacts.ListIndex) = mContacts(lboContacts.ListIndex + 1).LongName
End Sub

Voici un exemple d'utilisation de ce userform, qui charge une collection de contacts, puis la passe à une procédure qui la reçoit en ByRef, de sorte que la procédure appelante peut l'exploiter, ici dans l'exemple pour afficher les valeurs dans la fenêtre d'exécution (Ctrl+G)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Option Explicit
 
Sub Test()
  Dim Contact As New Contact
  Dim Contacts As New Collection
 
  Contact.FirstName = "Alain"
  Contact.LastName = "Térieur"
  Contacts.Add Contact
  Set Contact = New Contact
  Contact.FirstName = "Jean"
  Contact.LastName = "Aymar"
  Contacts.Add Contact
  GetAndUpdateContacts Contacts
  For Each Contact In Contacts
    Debug.Print Contact.LongName
  Next
End Sub
 
Sub GetAndUpdateContacts(ByRef Contacts As Collection)
  With usfContacts
    .Contacts = Contacts
    .Show
    Set Contacts = .Contacts
  End With
  Unload usfContacts
End Sub